Pro*Term, telecom utility (PROTERM.BAS)

Pro*Term, telecom utility by Matthew Arrington, 188 (BASIC, binary data)

Description

Pro*Term, telecom utility by Matthew Arrington, 188 (BASIC, binary data)

From the Antic disk of August 1985 (Vol. 4 No. 4).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 18.8 KB

Dialect
Atari BASIC
Lines
362
Variables
Z, DL, C1, SCRN, SAV$, X, MO, C4, WIN, T, MSG, MEMSAV, PR$, C40, C2, L$, L, LOCAL, MSTAT, M, OPM, C7, C100, GCHR, K, IL, STRP, C128, ROW, COL, C30, BMENU, SERR, DUPLEX, AMODE, C5, B, MENU, C20, C10, PMENU, ADM, CON, XFLAG, C6, C8, C50, OW, C256, TEMP$, CW, CLM, H, BUF, CAPT$, CDEV, CFIL$, FILE$, YN, XF$, A$, D, BUF$, C3, C9, A, AUTO, C70, I, CMAX, DR, N$, S, TONE, LAST, CB, F, AMT, LB, XM$, BLK, BS, XMAX, SOH, SUM, ADM$, Y, ESC, C60, LD$, LD, B$, C
BASIC listing (362 lines)
1 REM PRO*TERM  v. 1.05
2 REM BY MATTHEW ARRINGTON
3 REM (c) 1985, ANTIC PUBLISHING
10 POKE 106,160:GRAPHICS Z:POKE 710,Z:POKE 82,Z:POKE 559,Z:POKE 712,Z:GOTO 20000
15 POKE 16,112:POKE 53774,112:RETURN
20 POKE DL+C1,149:POKE 89,149:POKE 106,153
25 POKE DL+21,152:POKE DL+24,152:? "→←";:SCRN=Z:RETURN
30 POKE DL+C1,156:POKE 89,156:POKE 106,160
31 POKE DL+21,159:POKE DL+24,159:? "→←";:SCRN=C1:RETURN
35 POKE 752,C1:SAV$(23)=" ":X=USR(MO,DL+19,ADR(SAV$),22):X=USR(MO,ADR("N(└◆B♥┼▕▕▕N(└BP└N(└A◣↑"),DL+19,22)
36 POKE 661,147:POKE 660,Z:SAV$(23,23)=CHR$(PEEK(106)):POKE 703,C4:POKE 106,148:? "↰";:WIN=C1:RETURN
37 ? "↰":X=USR(MO,ADR(SAV$),DL+19,21):POKE 703,24:POKE 106,ASC(SAV$(23)):WIN=Z:RETURN
40 IF T<39424 OR (T=MSG AND MEMSAV) THEN RETURN
42 PR$=" ":PR$(C40)=PR$:PR$(C2)=PR$:PR$(C1,C40)=L$:PR$(L+C1)="♥"
45 X=USR(ADR("hh┐Uh┐Th┐Wh┐V ♥1Tp␛"♥I♥♣▕"♥╱X)▶Ia0┘8i ┴eX┌VHPa◆"),ADR(PR$),T):RETURN
50 IF LOCAL OR MSTAT THEN RETURN
54 STATUS #M,X:IF PEEK(747) THEN GET #M,X:GOTO 54
55 GOSUB OPM:POKE C7,255:? #M;"␛Z";:FOR X=C1 TO C100:NEXT X:POKE C7,Z:MSTAT=C1:RETURN :REM CLM
60 IF LOCAL THEN RETURN
65 POKE C7,255:? #M;"␛Y";:FOR X=C1 TO C100:NEXT X:? #M;"␛E";:MSTAT=Z:RETURN :REM OPM
70 IF LOCAL THEN RETURN
75 GOSUB OPM:POKE C7,255:? #M;"␛M";:POKE C7,Z:RETURN
80 ? "────────────────────────────────────────";:RETURN
90 ? "?";:GOSUB GCHR:X=X=89:IF X THEN ? " YES":RETURN
95 ? " NO":RETURN
110 L$="":L=0:POKE 752,C1
112 ? "_←";:GET #K,X:IF X=155 THEN ? " ";:L$(L+C1)="":RETURN
114 IF (X=126 OR X=156) AND  NOT L THEN 112
116 IF X=126 THEN ? " ◀◀";:L$(L)="":L=L-C1:GOTO 112
118 IF X=156 THEN L$="":FOR T=C1 TO L:? " ◀◀";:NEXT T:L=Z:GOTO 112
119 IF L=IL THEN 112
120 IF STRP=C1 THEN 122
121 X=X-128*(X>127):X=X-32*(X>96):IF (X<65 OR X>90) AND (X<42 OR X>59) THEN 112
122 ? CHR$(X);:L=L+C1:L$(L)=CHR$(X):IF L+C1>IL THEN ? "↰";
124 GOTO 112
125 GET #K,X:X=X-C128*(X>127 AND X<>155):X=X-32*(X>96 AND X<>155):RETURN
130 ROW=PEEK(84):COL=PEEK(85)
140 POP :POP :GOSUB C30:POKE 84,ROW:POKE 85,COL:POKE 752,Z:POKE 77,0
141 POKE 766,Z:? "→←";:BMENU=Z:TRAP SERR:POKE 708,144-119*LOCAL:GOSUB 15
150 GOSUB 30160:IF MEMSAV AND PEEK(C5)=Z THEN GOSUB 750
151 IF MEMSAV AND PEEK(C5)=Z THEN GOSUB 750
155 IF  NOT X THEN 180
156 IF X=255 THEN GOSUB 810:GOTO C100+C40
160 GOSUB 15:GET #K,B:B=B-C128*(B>127):B=B-32*(B>96):POKE 195,Z
161 IF MENU AND (B=155 OR B=27) THEN MENU=Z:GOTO 173
163 IF B<53 AND B>48 THEN B=B-48:GOTO 700
164 IF B=C30+C2 THEN GOSUB 750:GOTO 171
165 B=B-64:IF B>25 OR B<C1 THEN 175
170 TRAP 171:GOSUB 180+(C20*B)
171 IF PEEK(195)<>C10+C2 AND PEEK(195)>Z THEN GOTO SERR
172 TRAP SERR:IF MENU AND PMENU=Z THEN GOSUB 20120
173 IF  NOT LOCAL THEN GOTO 140+C20*MENU
175 GOTO 140+9900*(ADM=C1 AND MENU=Z)+(C20*MENU)
180 IF PEEK(CON)=C5 THEN POKE CON,C7:GOSUB 20120:MENU=C1:GOTO 160
181 IF  NOT XFLAG OR LOCAL THEN GOTO C100+C40
182 POKE CON,C7:L$="Xmodem Start":T=MSG:L=C10+C6:GOSUB C40
183 POKE CON,C8:IF PEEK(CON)<C7 THEN 183
184 FOR T=C1 TO C50:NEXT T:GOTO 1000*XFLAG
200 IF  NOT LOCAL THEN RETURN
202 DUPLEX=C2:GOSUB 500:GOSUB OW:CLOSE #M:LOCAL=Z:OPEN #M,13,0,"T"
205 POKE C7,C256-C1:? #M;"␛J␛L";:POKE C7,Z:? "    Waiting for callers carrier....":?
210 ? "▶Type a key to abort.";:FOR T=C1 TO C100*C7:STATUS #M,X
211 IF PEEK(746)>127 THEN POP :TEMP$="ANSWER MODE":GOTO 10270
215 IF PEEK(764)<255 THEN GET #K,X:T=C100*C7
217 NEXT T:GOSUB 340:GOTO CW
220 IF LOCAL THEN 3300
225 RETURN
240 IF MEMSAV THEN GOSUB 750
241 GOSUB CLM:GOSUB 35:H=PEEK(BUF+C1)*256+PEEK(BUF)-ADR(CAPT$):IF  NOT H THEN CDEV=Z
242 IF  NOT CDEV THEN ? "Save Capture buffer:":? :GOSUB 3000:CFIL$=FILE$:CLOSE #C4:OPEN #C4,C8,Z,CFIL$:CDEV=C1
244 IF  NOT H THEN GOSUB CW:GOTO OPM
245 CAPT$(H+C1)="":? "↰":? "▶    |Saving Buffer|":? #C4;CAPT$;:CLOSE #C4:CDEV=Z:GOSUB CW:GOSUB 790:GOTO OPM
260 GOSUB OW:? "Download File.":?
261 IF XFLAG=C2 THEN ? "Close upload file";:GOSUB YN:? "↑↑";:IF  NOT X THEN GOTO CW
263 GOSUB 3000:XFLAG=Z:GOSUB CLM:CLOSE #C5:OPEN #C5,C8,Z,FILE$
265 XFLAG=C1:XF$=FILE$:GOSUB OPM:GOTO CW
280 GOSUB 670:GOSUB CLM:GOSUB OW:? "Erase file(s)":? :GOSUB 3000:A$=FILE$:CLOSE #D:OPEN #D,C6,Z,FILE$:TRAP 290
281 ? "↰Type 'Y' to delete, <esc> aborts":INPUT #D;BUF$:IF ASC(BUF$)>C40+C2 THEN 290
282 BUF$=BUF$(C3):L$=BUF$(C9,C10+C1):BUF$(C9)=" ":FOR T=C1 TO C9:IF BUF$(T,T)=" " THEN BUF$(T)=".":T=C9
283 NEXT T:IF L$(C1,C1)=" " THEN L$=""
284 BUF$(LEN(BUF$)+C1)=L$:A$(C4)=BUF$:? :? A$;"?";:GOSUB GCHR:IF X=27 THEN 290
285 X=X=89:IF  NOT X THEN 281
286 ? "↑Deleting ->";A$:XIO 33,#C4,Z,Z,A$:GOTO 281
290 POKE 195,Z:TRAP SERR:GOSUB CW:CLOSE #D:GOTO OPM
300 GOSUB OW:? "Formatt Disk:":? :? "Which Drive?  Press: 1 2 3 or 4":GOSUB GCHR:IF X>52 OR X<49 THEN GOTO CW
302 A=X:? "↰Type 'Y' to Format Drive:";CHR$(A):GOSUB GCHR:IF CHR$(X)<>"Y" THEN GOTO CW
304 FILE$="D0:":FILE$(C2,C2)=CHR$(A):GOSUB CLM:CLOSE #D:XIO 254,#D,Z,Z,FILE$:GOSUB OPM:GOTO CW
340 IF MEMSAV THEN GOSUB 750
343 GOSUB 30100:POKE 708,25:T=MSG:GOSUB C40:GOSUB OPM:GOSUB C70:CLOSE #M:LOCAL=C1
344 IF DUPLEX=C2 THEN DUPLEX=C1:GOTO 500
345 IF  NOT LOCAL AND  NOT ADM THEN ? :? :GOSUB 80:? :GOTO 130
346 RETURN
380 GOSUB OW:GOSUB 670:I=Z:H=Z
385 ? "↰Copy From:":? :GOSUB 3000:? "↰Copy To:":? :CFIL$=FILE$:GOSUB 3000:GOSUB CLM:CLOSE #D:CLOSE #C4
386 IF CFIL$(C1,C2)<>FILE$(C1,C2) THEN ? "↰Copy ";CFIL$;" -->";FILE$:? :? "▶Type a Key to Abort";
387 GOSUB 405:T=39504:L=C10+C1:L$=CFIL$:A$="SORCE":GOSUB 400:IF  NOT I THEN OPEN #D,C4,Z,CFIL$:I=C1
388 CAPT$(CMAX)=" ":A=USR(DR,D,ADR(CAPT$),CMAX-C1):CAPT$(PEEK(C40+C1)*C256+PEEK(C40)+C1)=""
390 GOSUB 405:L$=FILE$:A$="DESTINATION":POKE 708,67:GOSUB 400:IF  NOT H THEN OPEN #C4,C8,Z,FILE$:H=C1
391 ? #C4;CAPT$;:POKE 708,144-119*LOCAL:IF A<>136 THEN 387
392 CLOSE #D:CLOSE #C4:GOSUB OPM:GOTO CW
400 GOSUB C40:IF FILE$(C1,C2)<>CFIL$(C1,C2) THEN RETURN
402 ? "↰Insert ";A$;" disk, type RETURN.":GET #K,X:? :IF X<>155 THEN 402
403 RETURN
405 IF PEEK(764)>C256-C2 THEN RETURN
406 POP :GET #K,X:GOTO 392
420 L$="L.D.A. ":T=MSG:L=C10+C6:LD=LD=Z:IF LD THEN L$(C8)="ON":GOTO C40
422 L$(C8)="OFF":GOTO C40
440 GOSUB OW:IF  NOT LOCAL THEN RETURN
441 GOSUB 340:OPEN #M,13,Z,"T":LOCAL=Z
442 ? "Enter number: / -Dials last num.":? :? ">";:IL=CW:GOSUB 110:IF L$="" THEN 446
443 IF L$<>"/" THEN N$=L$:TEMP$=N$
444 ? "↰Dialing: Any key aborts."
445 GOSUB 30110
446 POKE 752,C1:GOSUB CW:GOSUB OPM:CLOSE #M:LOCAL=C1:RETURN
460 GOSUB OW:IL=C30+C1:? "Rename File, Enter:  Old-FN,New-FN":? :GOSUB 3010:GOSUB CLM:CLOSE #D
465 XIO 32,#D,Z,Z,FILE$:GOSUB OPM:GOTO CW
480 T=MSG:L=C10+C6:TONE=TONE=Z:L$="Dialing:":IF TONE THEN L$(C9)="TONE":GOTO C40
485 L$(C9)="PULSE":GOTO C40
500 T=39446:L=C4:IF DUPLEX=Z THEN DUPLEX=C1:L$="HALF":GOTO C40
503 IF DUPLEX=C2 THEN L$="HOST":GOTO C40
505 DUPLEX=Z:L$="FULL":GOTO C40
520 IF LOCAL THEN RETURN
521 GOSUB OW:GOSUB 670:? "↰Send Buffer (Non Xmodem)":? :GOSUB 3000
522 ? "↰Enter Delay Rate:":? :? "0-9 (0-NON To 9 Slowest)":GET #K,X:IF X>57 OR X<48 THEN 522
523 X=X-48:A=X*C5:GOSUB CLM:CLOSE #D:OPEN #D,C4,Z,FILE$:GOSUB CW:GOSUB C30:POKE 752,Z
524 CAPT$(CMAX)=" ":H=USR(DR,D,ADR(CAPT$),CMAX-C1):CAPT$(PEEK(C40+C1)*C256+PEEK(C40)+C1)="":GOSUB OPM
526 FOR T=C1 TO LEN(CAPT$):PUT #M,ASC(CAPT$(T))
528 STATUS #M,X:IF PEEK(747) THEN GET #M,X:? CHR$(X);:GOTO 528
530 IF PEEK(764)<C256-C2 THEN GET #C3,X:GOTO 534
532 FOR X=C1 TO A+C50*(ASC(CAPT$(T))=155):NEXT X:NEXT T:IF H<>136 THEN GOSUB CLM:GOTO 524
534 GOSUB CLM:CLOSE #D:GOSUB OPM:GOTO C100+C30
540 GOSUB OW:? "Set timer, (00:00:00)  ";:IF AUTO THEN ? "Auto mode":GOTO 545
542 ? "Clock mode"
545 ? :? ">";:IL=C9:GOSUB 110:IF LEN(L$)<C8 OR LEN(L$)>C8 THEN GOTO C30+C7
547 L$(C3,C3)=":":L$(C6,C6)=":":L=C8:T=39518:GOSUB C40
550 AUTO=L$="00:00:00":POKE 1788,AUTO=Z:GOTO C30+C7
560 GOSUB CLM:CLOSE #C1:OPEN #C1,C8,Z,"P":GOSUB OW:? "Printing screen, type any key to abort.";
561 ? #C1;"␛l●";:FOR T=C1 TO 42:? #C1;"-";:NEXT T:? #C1
562 FOR T=Z TO 23:L$(C40)=" ":X=USR(MO,40000+T*C40,ADR(L$),C40)
565 X=USR(ADR("hh┐[h┐Zh┐T┐Uh(◢)♥┐\1ZI♥♣┤"♥╱\)▶*Ia0◣I@♣▕)♥*┴i ┴e\┌Z◣┴eT┐T♣▕fU@♥PM◆"),ADR(L$),C40):GOSUB 30130
566 IF PEEK(764)<255 THEN GET #K,X:GOTO 568
567 ? #C1;L$:NEXT T:? #C1:FOR T=C1 TO 42:? #C1;"-";:NEXT T:? #C1
568 ? #C1;"␛@":CLOSE #C1:GOSUB OPM:GOTO CW
580 L=C7:AMODE=AMODE=Z:IF AMODE THEN L$="ATASCII":T=39432:GOTO C40
585 L$=" Ascii ":T=39432:GOTO C40
600 GOSUB OW:? "Upload file:":?
601 IF XFLAG=C1 THEN ? "Close download file";:GOSUB YN:? "↑↑";:IF  NOT X THEN GOTO CW
602 LAST=Z:XFLAG=Z:GOSUB 3000:GOSUB CLM:CLOSE #C5:XF$=FILE$:OPEN #C5,C4,Z,XF$:GOSUB 2006:GOSUB CW:GOTO OPM
620 GOTO 3100
660 L=C10+C6:T=MSG:IF  NOT PEEK(BUF+C1)*256+PEEK(BUF)-ADR(CAPT$) THEN CB=C1:L$="Buffer Empty":GOTO C40
661 CB=Z:F=WIN:IF  NOT WIN THEN GOSUB OW
663 ? :? "Type 'Y' to clear capture buffer.";:GOSUB GCHR:? "↰"
664 IF X=89 THEN GOSUB 790:L$="Buffer Cleared":GOSUB C40:CB=C1
665 IF F THEN RETURN
666 GOTO CW
670 GOSUB 660:IF  NOT CB THEN POP :IF WIN THEN GOTO CW
675 RETURN
700 TRAP SERR:POKE 559,Z:GOSUB CLM:GOSUB C20:? "↰":PMENU=Z:POKE 559,34:BUF$="D1:*.*":BUF$(C2,C2)=STR$(B)
710 CLOSE #D:OPEN #D,C6,Z,BUF$:TRAP 730:? :? "▶     Drive ";B;" Files":? :GOSUB 80
720 INPUT #D;BUF$:T=BUF$(C1,C1)=" " OR BUF$(C1,C1)="*":IF T THEN ? BUF$;" | ";
725 IF T THEN INPUT #1;BUF$:IF BUF$(C1,C1)=" " OR BUF$(C1,C1)="*" THEN ? BUF$:GOTO 720
730 TRAP SERR:? "↓":CLOSE #D:? ,VAL(BUF$);"  Free Sectors.":GOSUB 80:? :? ,"  Type any key."
735 GET #K,X:? "↰":GOSUB OPM:GOTO 171
750 MEMSAV=MEMSAV=Z:T=39460:L=C3:IF  NOT MEMSAV THEN 780
760 L$="ON":GOSUB C40:T=MSG:L$=" 0000":X=(PEEK(AMT+1)*256+PEEK(AMT))-(PEEK(BUF+1)*256+PEEK(BUF))+48
770 L=C10+C6:L$(C6-LEN(STR$(X)))=STR$(X):MEMSAV=Z:GOSUB C40:MEMSAV=C1:RETURN
780 L$="OFF":GOSUB C40:T=MSG:L$=TEMP$:L=C10+C6:GOTO C40
790 A=MEMSAV:IF MEMSAV THEN GOSUB 750
795 CAPT$(CMAX)=" ":X=ADR(CAPT$):H=INT(X/256):LB=X-(H*256):POKE BUF+1,H:POKE BUF,LB
800 X=(X+CMAX)-48:H=INT(X/256):LB=X-(H*256):POKE AMT+C1,H:POKE AMT,LB:IF A THEN 750
805 RETURN
810 GOSUB 750:GOSUB CLM:GOSUB OW:IF CDEV THEN 830
820 ? "Save capture buffer:":? :CDEV=C2:GOSUB 3000:CDEV=Z:CFIL$=FILE$:CLOSE #C4:OPEN #C4,C8,Z,CFIL$:CDEV=C1
830 X=PEEK(BUF+C1)*256+PEEK(BUF)-ADR(CAPT$):CAPT$(X+C1)="":? "↰":? "▶    |SAVING BUFFER|":? #C4;CAPT$;
840 GOSUB CW:GOSUB 790:GOSUB 750:GOSUB OPM:? #M;"┌┌";:RETURN
1000 POKE 708,C40+C7:POKE 766,C1:POKE 752,C1:S=C20+C1:XM$="":BLK=Z:BS=Z:L=C10+C6:H=C1:TRAP 1080
1005 A$(1,53)="hh┐Lh┐K ├▘◀▕◢┤T┤U┤M)▶▔*▕)├▔↓▕" )▔▔b┘ Vd-k▕P▝-*▕Pl▔◀▕F"
1006 A$(54,106)="U◆)╲▔b┘)♥▔h┘▔i┘ Vd$M┌KH"♥ ▝▘B┘▂H┘▂I┘ Vd┴heT┐TfM♣-▂◀▕◆"
1010 T=MSG:STATUS #M,X:IF PEEK(747) THEN GET #M,A:GOTO 1010
1015 X=((BS*XMAX+(BLK-C128*BS))/128)+C1:L$="BLK:":L$(C5)=STR$(X):? :? "|Receiving Blk: ";X;"/";H:?
1017 PUT #M,S:FOR A=C1 TO C4*C100:STATUS #M,X
1018 IF PEEK(747)>Z OR PEEK(CON)<C7 THEN POKE CON,C8:GOTO 1020+60*(PEEK(CON)<C7)
1019 NEXT A:GOTO 1017
1020 POP :GET #M,SOH:SUM=SOH:IF SOH=C4 OR SOH=C20+C4 THEN 1070
1030 GET #M,B:SUM=SUM+B:GET #M,B:SUM=SUM+B:BUF$(129)=""
1031 A=USR(ADR(A$),ADR(BUF$)):SUM=SUM+A:IF A>C256 THEN S=21:GOTO 1010
1040 GET #M,B:?
1041 IF B<>ASC(CHR$(SUM)) THEN S=C20+C1:L$(LEN(L$)+C1)=" -RETRY":GOSUB C40:POKE 708,67:H=H+C1:GOTO 1010
1050 XM$(LEN(XM$)+C1)=BUF$:BLK=BLK+C128:S=C6:L$(LEN(L$)+C1)=" -OK":H=C1:GOSUB C40
1060 POKE 708,47:IF BLK<XMAX THEN 1010
1070 IF SOH<>C20+C4 THEN 1110
1080 TRAP SERR:? #M;"┴┴";:L$="Xmodem Aborted":GOSUB C40:POKE 766,Z:? :? "|XMODEM ABORTED|":GOSUB CLM:CLOSE #C5
1090 XFLAG=Z:GOSUB OW:? :? "Erase Partial file";:GOSUB YN:GOSUB CW:IF  NOT X THEN 130
1100 XIO 33,#C5,Z,Z,XF$:GOTO 130
1110 POKE 77,Z:BLK=C128:BS=BS+C1:L$="Save - ":L$(C8)=STR$(BS):GOSUB C40:GOSUB CLM
1120 IF SOH<>C4 THEN X=LEN(XM$)-C128:? #C5;XM$(C1,X);:XM$=XM$(X+C1):GOSUB OPM:GOTO 1010
1125 X=LEN(XM$):B=ASC(XM$(X)):IF B>C128 THEN 1140
1130 FOR A=X TO X-B STEP -C1:IF XM$(A,A)=CHR$(B) THEN XM$(A)="":NEXT A
1140 ? #C5;XM$;:CLOSE #C5:L$="File Recieved":GOSUB C40:XFLAG=Z:POKE 766,Z:? :GOSUB OPM:? #M;"╱╱";:GOTO 130
2000 POKE 708,249:T=MSG:L=C10+C6:BS=C1:H=C1:POKE 752,C1:POKE 766,C1:TRAP 2110:GOTO 2010
2005 IF LAST THEN LAST=Z:? #M;"┤┤";:L$="Xmodem Complete":GOTO 2120
2006 GOSUB 30150:IF X<>XMAX THEN XM$(X+C1)="":LAST=C1
2007 GOSUB OPM:POKE 77,Z:IF XFLAG=Z THEN XFLAG=C2:RETURN
2010 BLK=INT(LEN(XM$)/C128):A=LEN(XM$)-(BLK*128):IF  NOT A THEN 2025
2020 X=C128-A:FOR A=LEN(XM$)+C1 TO LEN(XM$)+X:XM$(A)=CHR$(X):NEXT A
2025 A$=XM$(C1,C128):BLK=C1:GOTO 2075
2030 STATUS #M,X:POKE CON,C8:IF PEEK(CON)<C7 THEN 2110
2040 IF PEEK(747)<C1 THEN 2030
2050 GET #M,S
2051 IF S=C20+C4 OR S=C20+C1 THEN POKE 708,67:L$(LEN(L$)+C1)=" -RETRY":GOSUB C40:H=H+C1:GOTO 2075+OW*(S=C20+C4)
2060 POKE 708,249:H=C1:BLK=BLK+C1:BS=BS+C1:L$(LEN(L$)+C1)=" -OK":GOSUB C40:IF BLK*C128>LEN(XM$) THEN 2005
2070 A$=XM$(BLK*C128-127,BLK*C128)
2075 ? :? "|Sending Blk: ";BS;"/";H:? :SUM=Z:L$="BLK:":L$(C5)=STR$(BS)
2076 PUT #M,C1:PUT #M,BS:PUT #M,255-ASC(CHR$(BS))
2080 FOR A=C1 TO C128:X=ASC(A$(A)):PUT #M,X:SUM=SUM+X:? CHR$(X);:NEXT A:?
2090 STATUS #M,X:IF PEEK(747) THEN GET #M,X:GOTO 2090
2100 PUT #M,ASC(CHR$(SUM)):GOTO 2030
2110 L$="Xmodem Abort":? #M;"┴┴";:? :? "|Xmodem Aborted|":?
2120 GOSUB C40:GOSUB CLM:CLOSE #C5:XFLAG=Z:LAST=Z:POKE 766,Z:? :GOSUB OPM:GOTO C100+C30
3000 IL=15:? "|Filename: ";
3010 TRAP SERR:FILE$="D1:":GOSUB 110:IF L$="" AND CDEV<C2 THEN POP :GOTO CW
3015 IF CDEV=C2 AND L$="" THEN GOSUB 790:POP :CDEV=Z:GOSUB CW:GOSUB OPM:? #M;"┌┌";:RETURN
3020 IF L$="P:" THEN FILE$=L$:GOTO 3050
3022 IF LEN(L$)<C3 THEN 3040
3025 IF ASC(L$)<53 AND ASC(L$)>48 AND L$(C2,C2)=":" THEN FILE$(C2,C2)=L$(C1,C1):FILE$(C4)=L$(C3):GOTO 3050
3030 IF L$(C1,C2)="D:" AND LEN(L$)>C2 THEN FILE$(C4)=L$(C3):GOTO 3050
3035 IF L$(C3,C3)=":" AND ASC(L$(C2))<53 AND ASC(L$(C2))>48 THEN FILE$=L$:GOTO 3050
3037 IF ASC(L$)<53 AND ASC(L$)>48 THEN FILE$(C2,C2)=L$(C1,C1):FILE$(C4)=L$(C2):GOTO 3050
3040 FILE$(C4)=L$
3050 T=39504:L=C10+C1:L$=FILE$:GOTO C40
3100 A$="hh┐[h┐Zh┐]h┐\h┐Uh┐Thh┐b ♥┤^)(┐a1ZEbP␛┴%\ea┐\%]i♥┐])(┐af^%^I┼pJP4"♥I♥♣▕"
3110 A$(71)=""♥╱◆)▶I 0▕) I◆0┘8i ┴e◆┌\FaP▘)(┐af^%^I┼p└f\P▕f]fZP▕f[FTP!%Up╱FUp▌P┬◆"
3120 GOSUB OW:? "View - File/Buffer:":? :? "File or Buffer";:GET #K,X:X=X-128*(X>127):X=X-32*(X>96)
3130 IF X<>66 AND X<>70 THEN GOTO CW
3133 IF X=66 THEN GOSUB CW:GOTO 3180
3135 ? "↑";:GOSUB 670
3140 GOSUB 3000:GOSUB CLM:CLOSE #D:OPEN #D,C4,Z,FILE$:GOSUB CW:GOSUB C20:? "↰":PMENU=Z
3150 CAPT$(CMAX)=" ":A=USR(DR,D,ADR(CAPT$),CMAX-C1):CAPT$(PEEK(41)*256+PEEK(C40)+C1)=""
3155 IF LEN(CAPT$)<C1 THEN 3170
3160 L=C1:GOSUB 3200:IF A<>136 THEN 3150
3170 CLOSE #D:GOSUB OPM:GOTO 790
3180 X=PEEK(BUF+C1)*256+PEEK(BUF)-ADR(CAPT$):IF  NOT X THEN T=MSG:L=C10+C6:L$="Buffer empty":GOTO C40
3185 CAPT$(X+C1)="":GOSUB C20:PMENU=Z:? "↰":L=C1:GOSUB 3200:CAPT$(CMAX)=" ":RETURN
3200 H=(LEN(CAPT$)-L)+C1:IF H>800 THEN H=800
3205 X=USR(ADR(A$),ADR(CAPT$(L)),38288,H,155):B=L:F=H-X:L=L+F+C1
3210 POSITION 0,22:? "<A>bort, <P>rint Screen, or RETURN";
3220 GET #K,X:X=X-128*(X>127):X=X-32*(X>96):X=X-64:IF X=C1 THEN POP :RETURN
3230 IF X=C10+C6 THEN CLOSE #K:OPEN #K,C8,Z,"P:":? #K;CAPT$(B,B+F-C1):CLOSE #K:OPEN #K,4,0,"K":GOTO 3210
3240 IF L<LEN(CAPT$) THEN ? "↰":GOTO 3200
3250 ? "↰":RETURN
3300 POKE 559,Z:STRP=Z:IL=C3:BMENU=Z:PMENU=Z:? "↰"
3301 GOSUB C20:? "↰":POSITION 8,C5:? "◢Auto dial Menu Editor◣":GOSUB 80
3310 POKE 82,C9:? :? "L -Load a BBS Menu":? :? "S -Save a BBS Menu":? :? "A -Add # (or create NEW menu)"
3320 ? :? "D -Long distance dialing":? :? "X -Exit":POKE 82,0:? :GOSUB 80:? :? "  OPTION:";:POKE 559,34:GOSUB 110
3330 IF L$<>"L" THEN 3335
3332 ADM=Z:POP :? "↰":POSITION 0,C9:? "Enter filename or type RETURN.":? "(no extenders)":? :? ">";
3333 IL=C8:GOSUB 110:IF L$="" THEN L$="*"
3334 FILE$="D:":FILE$(C3)=L$:FILE$(LEN(FILE$)+C1)=".ADM":GOTO 10000
3335 IF L$="X" THEN ? "↰":RETURN
3337 IF L$<>"S" THEN 3351
3338 IF  NOT ADM THEN 3300
3340 ? "(No extenders)":? :GOSUB 3000:GOSUB CLM:FILE$(LEN(FILE$)+C1)=".ADM":CLOSE #D:OPEN #D,C8,Z,FILE$
3350 ? #D;"├├";LD$:? #D;ADM$;:CLOSE #D:GOSUB OPM:GOTO 3300
3351 IF L$<>"D" THEN 3360
3352 ? "↰":POSITION 0,C8:? :? "Enter: [access number] [delay] [code]":? "Each comma is a 2 sec. delay."
3354 ? :? "Example: 555-5555,,221121,":? :? ">";:IL=C20:GOSUB 110:IF L$="" THEN 3300
3356 LD$=L$:GOTO 3300
3360 IF L$<>"A" THEN 3300
3380 IL=C30:? "↰":POSITION Z,C10:IF ADM THEN 3400
3385 ADM$=" ":ADM$(1080)=ADM$:ADM$(C2)=ADM$:POKE 752,Z
3390 ? "Enter a Title:  (40 char's max)":? :INPUT L$:? "↰":POSITION Z,C10:? L$:? :? "Above correct";:GOSUB YN
3395 POKE 752,C1:ADM$(C1,C40)=L$:ADM$(C40+C1)="":IF  NOT X THEN 3380
3400 STRP=C1:A$=" ":A$(200)=A$:A$(C2)=A$:IF LEN(ADM$)>1079 THEN 3300
3410 ? "↰":POSITION Z,C10:? "RETURN EXITS":? :? "Enter BBS name: (16 Char's Max)":? :? ">";:IL=16:GOSUB 110
3415 IF L$="" THEN 3300
3420 A$(C2,17)=L$:? "↰":POSITION Z,C10:? "Enter Telephone Num. (21 Chars Max)":? :? ">";:IL=21:GOSUB 110
3430 A$(18,38)=L$:? "↰":POSITION Z,C10:? "Y-ATASCII or N-Ascii";:GOSUB YN:A$(39,39)=STR$(X)
3440 ? "↰":POSITION Z,C10:? "Name________>";A$(C2,17):? "Number______>";:? A$(18,38)
3450 ? "Translation_>";:IF X THEN ? "ATASCII"
3550 IF  NOT X THEN ? "Ascii"
3560 ? :? "Above Correct";:GOSUB YN:IF  NOT X THEN 3400
3570 ADM$(LEN(ADM$)+C1)=A$(C1,C40):ADM=C1:GOTO 3400
10000 IF ADM THEN 10040
10005 GOSUB CLM:TRAP 10020:CLOSE #D:OPEN #D,C4,Z,FILE$:TRAP SERR:ADM=C1:GET #D,X:IF X=C1 THEN GET #D,X:GOTO 10030
10020 TRAP SERR:CLOSE #D:ADM=Z:ADM$="":T=39529:L$="No BBS Menu":L=16:GOSUB C40:ROW=13:COL=Z:GOSUB C30
10025 ? "↰":POSITION Z,C4:? ," ◢Terminal mode◣":? "↓▶  Hit select for menu."
10026 ? "▶←OPTION & M to make a call.":GOTO 140
10030 INPUT #D;LD$:ADM$(1080)=" ":X=USR(DR,D,ADR(ADM$),1080):ADM$(PEEK(41)*C256+PEEK(C40)+1)=""
10040 GOSUB OPM:CLOSE #M:LOCAL=C1:GOSUB C30:IF BMENU THEN 10072
10045 ? "↰":POSITION Z,C3:? ADM$(C1,C40):? :POSITION Z,C6:POKE 752,C1
10050 FOR T=C2 TO LEN(ADM$)/C40 STEP C2:X=T*C40-39:? " ";CHR$((T-C1)+64);ADM$(X,X+16);"  ";
10060 IF X+39<LEN(ADM$) THEN ? CHR$(T+64);ADM$(X+C40,X+56)
10070 NEXT T:? :? :? "▶←Type BBS Letter to Dial.":BMENU=C1
10072 GOSUB 15:POKE CON,C8:IF PEEK(764)>254 AND PEEK(CON)=C7 THEN 10072
10073 IF PEEK(CON)=C3 AND PEEK(764)<255 THEN 160
10074 IF PEEK(CON)=C5 THEN POKE CON,C7:GOSUB 20120:MENU=C1:GOTO 160
10078 IF PEEK(764)>254 OR PEEK(CON)<7 THEN 10072
10080 GOSUB GCHR:I=X-63:IF I>LEN(ADM$)/C40 OR I<C1 THEN 10072
10140 GOSUB C20:? "↰":POSITION Z,C7:? "▶ ESC re-dials number.":? "  Any other key to ABORT dialing.":PMENU=Z
10150 I=I*C40-39:GOSUB OPM:CLOSE #M:OPEN #M,13,Z,"T":LOCAL=Z
10170 N$="":FOR Y=I+17 TO I+38:IF ADM$(Y,Y)<>" " THEN N$(LEN(N$)+C1)=ADM$(Y,Y):NEXT Y
10175 TEMP$=ADM$(I+C1,I+14):L$=ADM$(I+38,I+38):AMODE=L$="1":AMODE=AMODE=Z:GOSUB 580
10180 POSITION Z,12:? "|Calling: ";ADM$(I+C1,I+16):? :? "|Dialing: ";
10190 POSITION C10,14:POKE 752,Z:? "→←";:B=Z:GOSUB 10200:GOTO 10190-150*(B>Z AND B<>27)
10200 POKE C7,255:IF TONE THEN ? #M;"␛O";
10210 ? #M;"␛K";:N$(LEN(N$)+(LEN(N$)<>C40))=CHR$(155)
10215 IF LD THEN T=MSG:L=C10+C6:L$="L.D.A. ON":GOSUB C40:? #M;LD$;
10220 A$="hh┐ah┐◆hh┐c ♥┤T┤U" -|▕I▶P=1◆I*P▘"<▂↑▕.↑▕P♠"♥╱b┤♥()▝↓B┘)♥↓H┘↓I┘┴ Vd$♥&b1◆Ecp▝◆♥p┤"♥p?HP:┐T◆"
10225 X=USR(ADR(A$),ADR(N$),155):N$(LEN(N$))=""
10230 POKE 752,C1:? "→←";:IF X<>155 THEN PUT #M,155
10240 POKE C7,Z:FOR Y=C1 TO C100*C5:STATUS #M,A:IF PEEK(764)<>255 THEN GET #K,B:Y=C100*C5
10250 IF PEEK(746)>C128 THEN 10270
10255 NEXT Y:GOSUB C70:FOR T=C1 TO C30:NEXT T:RETURN
10270 IF AUTO THEN L$="00:00:00":L=C8:T=39518:GOSUB C40:POKE 1788,C1
10272 IF WIN THEN GOSUB CW
10275 POP :POKE 752,Z:IF ADM AND DUPLEX<C2 AND ESC=C2 THEN ADM$(I,I)=" "
10277 IF LEN(TEMP$)>15 THEN TEMP$(16)=""
10280 T=MSG:L=16:L$=TEMP$:GOSUB C40
10290 GOSUB C30:? "↰↰";:POSITION Z,C7:ROW=C3:COL=Z:GOTO C100+C40
20000 READ C1,C2,C3,C4,C5,C6,C7,C8,C9,C10,C20,C30,C40,C50,C60,C70,C100,C128,C256:M=C2:D=C1:K=C3:CON=53279
20005 YN=C70+C20:MEMSAV=Z:DUPLEX=Z:AMODE=C1:LOCAL=Z:DL=39957
20006 CLM=C50:OPM=C60:TONE=C1:MSG=39529:SERR=30010:GCHR=125
20010 DIM L$(C70+C10),BUF$(129),ADM$(1080),N$(C40),SAV$(C20+C3),A$(C100*C2),TEMP$(C40),PR$(C40+C1),FILE$(C30+C1)
20020 CW=C30+C7:OW=C30+C5:AMT=C3:BUF=C1:XMAX=2048:CMAX=4200:DIM CFIL$(15),XM$(XMAX),XF$(15),CAPT$(CMAX),LD$(C20)
20030 L$="P@0N(└B♥└▂Bh↑▕▕▕▕▕▕▕▕▕▕▕▕▕▕▕▕▕B8→B◆→▕▕▕N(└BP└N(└A◣↑"
20040 DR=ADR("hhh◣◣◣◣*)╲↓B┘h↓E┘h↓D┘h↓I┘h↓H┘ Vd┤T ♥┤U◆")
20050 X=USR(ADR("hh┐Uh┐Thh*hh┐W ♥%W┌THJPx◆"),39464,40,85)
20060 MO=ADR("h"┐h▄rJPzh┐r ♥1v┌tHDrPw◆")
20070 X=USR(MO,ADR(L$),39946,LEN(L$)):POKE 560,C10
20110 POKE 195,Z:OPEN #K,C4,Z,"K":LOCAL=C1:? "↰":L=C40:POKE 1788,Z:POKE 708,C20+C5
20115 L$="Key:A | ATASCII | Dup:FULL | Memsav:OFF ":T=39424:GOSUB C40
20117 L$="D1:         | 00:00:00 |":T=39504:GOSUB C40:X=USR(39680):AUTO=C1:POKE 559,34:GOSUB 790:GOSUB 340
20118 FILE$="D:*.ADM":GOTO 10000
20120 POKE 752,C1:POKE 559,34*PMENU:GOSUB C20:IF PMENU THEN RETURN
20130 ? "↰":? :? "▶  ◢ Pro*Term Functions ◣":? "┌─────────────────────────────────────┐"
20135 ? "|START:  Starts Xmodem Transfer       |":? "|SELECT: Displays this Menu           |"
20140 ? "├─────────────────────────────────────┤":? "|OPTION &:                            |":? "|","▶▶▶▶←|"
20145 ? "| 1-4 Directories     A -Answer Call  |":? "| B -BBS Menu Editor  C -Capture Save |"
20150 ? "| D -Download         E -Erase File   |":? "| F -Format Disk      H -Hangup Phone |"
20155 ? "| J -Copy File        M -Make a Call  |":? "| N -New Filename     O -Tone/Pulse   |"
20160 ? "| P -Duplex           Q -Send Buffer  |":? "| R -Reset Timer      S -Print Screen |"
20165 ? "| T -Translation      U -Upload       |":? "| V -View File        X -Erase Buffer |"
20170 ? "└─────────────────────────────────────┘":? :? "   SPACE BAR toggles Memsav."
20175 ? "   RETURN exits to terminal screen."
20200 PMENU=C1:POKE 559,34:RETURN
30000 DATA 1,2,3,4,5,6,7,8,9,10,20,30,40,50,60,70,100,128,256
30010 IF WIN THEN GOSUB CW
30012 IF MEMSAV THEN GOSUB 750
30015 POP :POP :POP :POKE 708,87:TRAP SERR:T=MSG:L$="*** ERR: ":X=PEEK(195):L=16:L$(C10)=STR$(X):POKE 195,Z
30020 IF X=170 THEN L$="File not found"
30025 IF X=160 OR X=138 THEN L$="Device Offline"
30030 IF X=140 OR X=139 OR X=150 THEN L$="Modem Error"
30035 IF X=165 THEN L$="Invalid file"
30040 GOSUB C40:GOSUB OPM:GOSUB CLM:CLOSE #D:CLOSE #K:OPEN #K,C4,Z,"K":GOSUB OPM
30050 POKE 708,144-119*LOCAL:GOTO 171
30100 POKE 1788,AUTO=Z:L$=" OFF->LINE":L=16:TEMP$=L$:POKE 708,25:RETURN
30110 FOR T=C1 TO C1:POKE 656,C2:POKE 657,Z:POKE 752,Z:? "→←";
30120 B=Z:GOSUB 10200:FOR S=C1 TO C100*C2:NEXT S:T=B:NEXT T:RETURN
30130 IF  NOT X THEN L$=""
30140 RETURN
30150 GOSUB CLM:XM$(XMAX)=" ":X=USR(DR,C5,ADR(XM$),XMAX):X=PEEK(C40+C1)*C256+PEEK(C40):RETURN
30160 GOSUB OPM:X=USR(1536,DUPLEX,LOCAL,MEMSAV,AMODE):ROW=PEEK(84):COL=PEEK(85):RETURN