Atartoon (ATARTOON.BAS)

Atartoon by Matthew Ratcliff, 73 (BASIC, binary data)

Description

Atartoon by Matthew Ratcliff, 73 (BASIC, binary data)

From the Antic disk of August 1985 (Vol. 4 No. 4).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 8.4 KB

Dialect
Atari BASIC
Lines
190
Variables
CSN, CST$, CSO, CCS, DLL1, DLH1, DL1, SCR1, SCR2, SCR, DLL2, DLH2, DL2, SC1, SC2, SC, A$, B$, EDIT$, FILE$, LSZ, BUF$, XD, XC, YD, YC, C4, C5, C2, C10, A, FILL, BOTMNU, FILEN, C0, C6, YES, C1, MX, W, C8, C9, FILE, SIZE, NUMBER, FULL, IO, ADDRESS, AB, CMND, CGET, CPUT, ERR, SZ, SP, C256, B, DELA, SHOW, ALL, FLAG, EDIT, LB, J, CONSOL, C7, C3, CNT, IOCB, ADRHI, ADRLO, NUMHI, NUMLO, I, X, Y, KEY, N$
BASIC listing (190 lines)
10 REM ATARTOON, LISTING 1
20 REM BY MATT RATCLIFF
30 REM (c) 1985, ANTIC PUBLISHING
40 POKE 106,PEEK(740)
50 CSN=PEEK(106)-4:POKE 106,CSN
60 GRAPHICS 0:DIM CST$(20):CSO=PEEK(756):CCS=CSO:CST$="":POKE 82,2:POKE 83,39
70 DLL1=PEEK(560):DLH1=PEEK(561):DL1=DLL1+256*DLH1:SCR1=PEEK(DL1+4):SCR2=PEEK(DL1+5):SCR=SCR1+256*SCR2
80 POKE 106,PEEK(106)-4
90 GRAPHICS 0:POKE 752,1:POKE 710,0:? "↰":POKE 712,5
100 DLL2=PEEK(560):DLH2=PEEK(561):DL2=DLL2+256*DLH2:SC1=PEEK(DL2+4):SC2=PEEK(DL2+5):SC=SC1+256*SC2
110 DIM A$(40),B$(40),EDIT$(256),FILE$(20):LSZ=FRE(0)-2048:DIM BUF$(LSZ):BUF$=""
120 GOSUB 1740:GOTO 300
130 XD=PEEK(XC):YD=PEEK(YC):POKE DL2+C4,SCR1:POKE DL2+C5,SCR2:POKE 88,SCR1:POKE 89,SCR2:POKE 756,CSO:RETURN
140 POKE DL2+C4,SC1:POKE DL2+C5,SC2:POKE 88,SC1:POKE 89,SC2:POKE 756,CCS:POSITION XD,YD:GOTO 160
150 POSITION C2,C10:A=USR(FILL,BOTMNU,FILEN,C0)
160 POKE 16,112:POKE 53774,112:RETURN
170 TRAP 200:POKE 702,64:POKE 694,C0:? "<Press Y or N> ";:GET #C6,YES
180 IF YES=89 THEN ? "Yes":YES=C1:RETURN
190 IF YES=78 THEN ? "No ":YES=C0:RETURN
200 GOSUB 290:IF PEEK(YC)=22 THEN GOSUB 150:? " KEEP TRYING "
210 CLOSE #C6:OPEN #C6,C4,C0,"K:":? " BAD KEY ":GOTO 170
220 TRAP 260:? "(# 1-";MX;")";
230 GET #C6,A:? CHR$(27);CHR$(A):A=A-48
240 IF A<C1 OR A>MX THEN 270
250 RETURN
260 ? :CLOSE #C6:OPEN #C6,C4,C0,"K:"
270 GOSUB 290:IF PEEK(YC)=22 THEN GOSUB 150:? "KEEP TRYING!"
280 ? "# ERROR, RETRY ";:GOTO 220
290 FOR W=C1 TO 25:SOUND C0,100,C10,C8:SOUND C0,140,C10,C8:NEXT W:SOUND C0,C0,C0,C0:RETURN
300 GOSUB 140:GOSUB 1560:GOSUB 130
310 CLOSE #C6:OPEN #C6,C4,C0,"K:"
320 POKE 752,C0:POKE 702,64:POKE 694,C0:TRAP 310:GOSUB 130:GOSUB 1670:GOSUB 150
330 SOUND C0,C0,C0,C0:MX=C9:? "  COMMAND>";:GOSUB 220
340 ON A GOTO 350,470,570,610,740,930,980,1030,1000
350 GOSUB 150:? " Load ATARI'Toon File "
360 IF LEN(BUF$)=C0 THEN 390
370 ? "Erase Cartoon in memory?":GOSUB 170:IF  NOT YES THEN 320
380 ? :BUF$=""
390 GOSUB 1180:IF  NOT FILE THEN 450
400 CLOSE #C1:TRAP 350
410 OPEN #C1,C4,C0,FILE$:SIZE=LEN(BUF$):INPUT #C1,NUMBER:FULL=C0:IF NUMBER=LSZ THEN FULL=C1
420 IF NUMBER+SIZE>LSZ THEN ? "Can't fit file into memory!":GOTO 460
430 IO=C1:ADDRESS=AB+SIZE:CMND=CGET:GOSUB 1350
440 BUF$(SIZE+NUMBER)=CHR$(PEEK(AB+NUMBER+SIZE-C1)):GOTO 320
450 ? "↰File ";FILE$;" not there!"
460 ? "Press RETURN to continue";:INPUT A$:GOTO 320
470 SIZE=LEN(BUF$):IF SIZE=C0 THEN ? "↰Nothing to save.":GOTO 460
480 GOSUB 150:? "Save this ATARI'Toon."
490 GOSUB 1180:IF  NOT FILE OR FILE$="C:" THEN 510
500 ? "Overwrite existing file?":GOSUB 170:IF  NOT YES THEN 320
510 TRAP 560:CLOSE #C1:OPEN #C1,C8,C0,FILE$
520 ? #C1;SIZE
530 NUMBER=SIZE:ADDRESS=AB:IO=C1:CMND=CPUT:GOSUB 1350:CLOSE #C1:IF ERR>127 THEN 550
540 GOTO 320
550 ? "I/O ERROR ";ERR
560 ? CHR$(253);"File error.":GOTO 460
570 SIZE=LEN(BUF$):IF SIZE=C0 THEN 350:REM MERGE
580 GOSUB 150:? "Merge an ATARI'Toon.":IF FULL THEN 740
590 SZ=LSZ-SIZE:? "Room for ";SZ;" characters."
600 GOTO 390
610 IF LEN(BUF$)=C0 THEN ? "NOTHING TO SHOW":GOSUB 290:GOTO 460
620 GOSUB 150:? " GIVE-A-SHOW "
630 ? "Input speed, 1-256 ";
640 TRAP 610:INPUT SP:IF SP<C1 OR SP>C256 THEN 610
650 TRAP 620:? "Press  1  for cursor on,":? " or    2  for cursor off during show ?"
660 MX=C2:GOSUB 220:B=A-C1
670 POKE 752,B
680 DELA=C256-SP:? "During Playback press SPACE":? "stop & start."
690 ? "Press  START  to exit."
700 ? "Press  RETURN to see show."
710 TRAP 720:INPUT A$
720 GOSUB 140:A=USR(SHOW,AB,LEN(BUF$)-C1,DELA):ALL=PEEK(FLAG):GOSUB 730:GOTO 320
730 FOR W=C0 TO 400:NEXT W:RETURN
740 IF FULL THEN GOSUB 290:? " BUFFER FULL ":GOTO 460
750 GOSUB 140
760 IF LEN(BUF$)=C0 THEN BUF$="↰":ALL=C0
770 POKE 752,C0:? "→←";:IF  NOT ALL THEN A=USR(SHOW,ADR(BUF$),LEN(BUF$)-C1,C256):ALL=PEEK(FLAG)
780 SZ=LEN(BUF$):A=USR(EDIT,ADR(BUF$)+SZ,SZ,LSZ-1)
790 LB=A-ADR(BUF$):A=PEEK(A-C1):BUF$(LB,LB)=CHR$(A)
800 A=PEEK(FLAG):ON A GOTO 810,840,910,920
810 FOR J=15 TO C0 STEP -0.4:SOUND C0,60,C10,J:NEXT J
820 IF PEEK(CONSOL)<>C7 THEN SOUND C0,240,C10,C10:SOUND C0,250,C10,C10:GOTO 820
830 SOUND C0,C0,C0,C0:A=USR(SHOW,AB,LEN(BUF$)-C1,DELA):ALL=PEEK(FLAG):GOTO 770
840 GOSUB 130:GOSUB 1670
850 GOSUB 150:? "Delete Character(s)":? "RETURN only deletes last character."
860 TRAP 860:? "How many chars";:INPUT A$:IF A$="" THEN A=C1:YES=C1:GOTO 890
870 A=VAL(A$):IF A>LEN(BUF$) OR A<C1 THEN GOSUB 290:? "# ERROR":? "Press RETURN":GET #C6,A:GOTO 850
880 ? "Delete ";A;" character(s)":? "from BUFFER?":GOSUB 170
890 IF YES THEN BUF$(LEN(BUF$)-A+C1)="":ALL=C0
900 GOTO 740
910 GOTO 320
920 FULL=C1:GOSUB 730:POKE 764,255:GOTO 320
930 ? "Make a new picture."
940 SIZE=LEN(BUF$):IF SIZE=C0 THEN GOTO 740
950 ? "Erase current CARTOON first?":GOSUB 170
960 IF  NOT YES THEN 320
970 BUF$="":SZ=LSZ:GOTO 740
980 ? "Disk directory.":GOSUB 1430
990 GOTO 320
1000 ? "Quit the ATARI'Toons program?":GOSUB 170
1010 IF  NOT YES THEN 320
1020 POKE 106,PEEK(106)+C8:GRAPHICS C0:CLR :END
1030 GOSUB 150:? " Custom Character Set "
1040 ? "[1] Enable ATARI Set"
1050 ? "[2] Load & Enable a Custom Set":MX=C2
1060 IF CST$<>"" THEN ? "[3] Re-Enable Set ";CST$:MX=C3
1070 GOSUB 220
1080 ON A GOTO 1090,1110,1100
1090 CCS=CSO:? "* ATARI SET *":GOTO 460
1100 CCS=CSN:? "* C-SET ";CST$;" *":GOTO 460
1110 GOSUB 150:? "C-SET to load ?":GOSUB 1180:CST$="":CCS=CSO
1120 IF  NOT FILE THEN 450
1130 POKE 756,CSN:CLOSE #C5:OPEN #C5,C4,C0,FILE$
1140 ADDRESS=CSN*C256:NUMBER=1024:CMND=CGET:IO=C5:GOSUB 1350:POKE 756,CSO
1150 IF ERR=C3 THEN 1170
1160 GOSUB 290:? FILE$;" IS  NOT  A VALID C-SET FILE!":GOTO 460
1170 CCS=CSN:CST$=FILE$:GOTO 320
1180 POKE 702,64:POKE 649,C0
1190 ? "Type dev.filename.ext":? "and press RETURN."
1200 ? "Press RETURN for a directory."
1210 ? "Press ESCAPE to abort function."
1220 CNT=C0:FILE$=""
1230 TRAP 1230:CLOSE #C6:OPEN #C6,C4,C0,"K:":GET #C6,A
1240 IF A=27 THEN POP :GOTO 320
1250 IF A=155 AND CNT=C0 THEN GOSUB 1430:GOSUB 150:GOTO 1180
1260 IF A<>126 THEN 1290
1270 CNT=CNT-C1:IF CNT<C0 THEN 1220
1280 ? CHR$(A);:FILE$=FILE$(C1,CNT):GOTO 1230
1290 IF A=155 AND CNT<>C0 THEN 1320
1300 IF A<32 OR A>90 THEN 1230
1310 CNT=CNT+C1:FILE$(CNT,CNT)=CHR$(A):? CHR$(A);:GOTO 1230
1320 TRAP 1340:FILE=C0:? :IF FILE$="C:" THEN FILE=1:GOTO 1340
1330 CLOSE #C4:OPEN #C4,C4,C0,FILE$:FILE=C1
1340 CLOSE #C4:RETURN
1350 IO=16*IO
1360 IOCB=832+IO:POKE IOCB+C2,CMND
1370 ADRHI=INT(ADDRESS/C256):ADRLO=ADDRESS-C256*ADRHI
1380 NUMHI=INT(NUMBER/C256):NUMLO=NUMBER-256*NUMHI
1390 POKE IOCB+C4,ADRLO:POKE IOCB+C5,ADRHI
1400 POKE IOCB+C8,NUMLO:POKE IOCB+C9,NUMHI
1410 I=USR(ADR("hhh*LVd"),IO):ERR=PEEK(IOCB+C3)
1420 RETURN
1430 IF PEEK(C9)=C0 THEN GOSUB 290:? "* NO DISK HERE *":RETURN
1440 GOSUB 150:TRAP 1430:? " DIRECTORY":? "Which Drive";:MX=C4:GOSUB 220:B=A
1450 GOSUB 150:A$="D1:*.*":A$(C2,C2)=STR$(B):CLOSE #C5:TRAP 1550:OPEN #C5,C6,C0,A$:I=C0:CNT=C0
1460 INPUT #C5,A$:IF A$(C4,C5)=" F" THEN 1510
1470 I= NOT I:? A$;:IF I THEN ? "|";:GOTO 1460
1480 ? :CNT=CNT+C1:IF CNT<11 THEN 1460
1490 TRAP 1500:? "*MORE* Press RETURN":GET #C6,A
1500 GOSUB 150:CNT=C0:GOTO 1460
1510 IF I THEN ?
1520 ? CHR$(252);A$;CHR$(252):CLOSE #C5
1530 TRAP 1540:? "Press  RETURN ";:INPUT A$
1540 RETURN
1550 ? :? "DISK I/O ERROR # ";PEEK(195):? "At line ";PEEK(186)+256*PEEK(187):POP :GOTO 460
1560 POKE 88,SCR1:POKE 89,SCR2:? "↰":POSITION C2,C0
1570 ? " ◢    ─────  ATARI'Toons  ─────    ◣"
1580 ? "◢     By Matthew J. W. Ratcliff     ◣"
1590 ? "─────────────────────────────────────"
1600 ? " Current Size=       Room Left=      "
1610 ? "[1]Load a Show   [2] Save this Show  "
1620 ? "[3]Merge a Show  [4] Play back Show  "
1630 ? "[5]Edit this Show[6] Make NEW Show   "
1640 ? "[7]Disk Directory[8] Character Set   "
1650 ? "◣       [9] Quit  ATARI'Toons       ◢"
1660 ? " ◣        Press Number 1-9         ◢"
1670 A$=STR$(LEN(BUF$)):X=16:Y=3:GOSUB 1700
1680 SZ=LSZ-LEN(BUF$)
1690 A$=STR$(SZ):X=33:Y=C3
1700 POSITION X,Y:IF LEN(A$)=C5 THEN 1720
1710 FOR I=C1 TO C5-LEN(A$):? CHR$(160);:NEXT I
1720 FOR I=C1 TO LEN(A$):A=ASC(A$(I)):? CHR$(A+128);:NEXT I
1730 RETURN
1740 C0=0:C1=1:C2=2:C3=3:C4=4:C5=5:C6=6:C7=7:C8=8:C9=9:C10=10:CONSOL=53279
1750 AB=ADR(BUF$):BUF$="":SIZE=LEN(BUF$):KEY=764:FULL=C0
1760 C256=256:CPUT=11:CGET=C7:EDIT$(C1)="♥":EDIT$(256)="♥":EDIT$(C2)=EDIT$:EDIT=ADR(EDIT$)
1770 TRAP 1890:CLOSE #C5:FILE$="D:ATARTOON.SYS":IF PEEK(C9)=C0 THEN FILE$="C:":POKE 764,12
1780 OPEN #C5,C4,C0,FILE$
1790 IO=C5:NUMBER=244:ADDRESS=1536:CMND=CGET:GOSUB 1350:IF ERR>127 THEN 1900
1800 IO=C5:NUMBER=209:ADDRESS=EDIT:CMND=CGET:GOSUB 1350:IF ERR>127 THEN 1900
1810 FILL=1735:SHOW=1629:BOTMNU=SCR+400:FILEN=559:CLOSE #C5
1820 IF PEEK(C9)=C0 THEN GOTO 1860
1830 TRAP 1860:OPEN #C5,C4,C0,"D:CHAR.SET"
1840 IO=C5:ADDRESS=CSN*C256:NUMBER=1024:CMND=CGET:GOSUB 1350:IF ERR<>C3 THEN 1860
1850 CST$="D:CHAR.SET":CCS=CSN:GOTO 1870
1860 CST$="":CCS=CSO
1870 CLOSE #C5:DELA=128:FLAG=1024:POKE FLAG,C0:ALL=C0:XC=85:YC=84:XD=C2:YD=C0
1880 RETURN
1890 ERR=PEEK(195)
1900 POKE 106,PEEK(106)+C8:GRAPHICS C0:? "CARTOON System File Load error # ";ERR