game (SLIDE.BAS)
game by Mark Moore, 25
Description
game by Mark Moore, 25
From the Antic disk of July 1985 (Vol. 4 No. 3).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 3.0 KB
- Dialect
- Atari BASIC
- Lines
- 79
- Variables
Y,N(,V,H,R,C,P,HL,S,D,K,T,V1,H1,LH
BASIC listing (79 lines)
10 REM SLIDE
20 REM BY MARK MOORE
30 REM (c) 1985, ANTIC PUBLISHING
40 DIM N(30)
50 GRAPHICS 0:SETCOLOR 2,7,0:SETCOLOR 4,0,2:POKE 752,1
60 POSITION 17,1:? "SLIDE":POSITION 13,2:? "by Mark Moore":POSITION 6,18:? " Please wait "
70 POSITION 2,4:POKE 82,12:?
80 ? " ┌─┬─┬─┬─┬─┐"
90 ? " | | | | | |"
100 ? " ├─┼─┼─┼─┼─┤"
110 ? " | | | | | |"
120 ? " ├─┼─┼─┼─┼─┤ ┌─┐"
130 ? " | | | | | | YOU ARE ON | |"
140 ? " ├─┼─┼─┼─┼─┤ └─┘"
150 ? " | | | | | |"
160 ? " ├─┼─┼─┼─┼─┤"
170 ? " | | | | | |"
180 ? " └─┴─┴─┴─┴─┘"
190 POKE 82,2:? :C=1
200 FOR V=1 TO 5:HL=5:IF V=5 THEN HL=4
210 FOR H=1 TO HL
220 R=INT(RND(0)*24)+1
230 N(C)=R
240 FOR P=0 TO C-1:IF N(P)=R THEN 220
250 NEXT P:C=C+1
260 POSITION H*2+12,V*2+4:? CHR$(64+R)
270 NEXT H:NEXT V
280 ? :? :? :? " Arrange in alphabetical order (A-X)."
290 POSITION 3,7:? "YOU CAN "
300 ? "MOVE INTO"
310 ? "THE BLANK"
320 ? " SPACE.":?
330 ? " NO "
340 ? "DIAGONAL"
350 ? " MOVES."
360 H=22:V=14:POKE 20,0:POKE 19,0:POKE 18,0
370 S=STICK(0)
380 IF PEEK(764)=33 THEN 640
390 IF S=14 AND V>6 THEN V=V-2
400 IF S=13 AND V<14 THEN V=V+2
410 IF S=7 AND H<22 THEN H=H+2
420 IF S=11 AND H>14 THEN H=H-2
430 LOCATE H,V,C
440 POSITION H,V:? CHR$(C+128)
450 IF S=15 THEN FOR D=1 TO 10:NEXT D
460 IF S<>15 THEN FOR D=14 TO 0 STEP -0.5:SOUND 0,30,10,D:NEXT D:POKE 53279,0
470 POSITION H,V:? CHR$(C):POSITION 37,10:? CHR$(C)
480 IF STRIG(0)=0 THEN 500
490 GOTO 370
500 LOCATE H,V+2,K
510 IF K=160 THEN POSITION H,V+2:? CHR$(C):GOTO 610
520 LOCATE H,V-2,K
530 IF K=160 THEN POSITION H,V-2:? CHR$(C):GOTO 610
540 LOCATE H+2,V,K
550 IF K=160 THEN POSITION H+2,V:? CHR$(C):GOTO 610
560 LOCATE H-2,V,K
570 IF K=160 THEN POSITION H-2,V:? CHR$(C):GOTO 610
580 LOCATE 1,1,K
590 POSITION 12,21:? " ILLEGAL MOVE ":SOUND 0,70,12,6:FOR D=1 TO 30:NEXT D
600 SOUND 0,0,0,0:POSITION 12,21:? "- -":GOTO 370
610 POSITION H,V:? " "
620 FOR D=14 TO 0 STEP -1:SOUND 0,20,12,D:NEXT D:POKE 77,0
630 GOTO 370
640 T=0:POKE 764,255:FOR V1=1 TO 5:HL=5:IF V1=5 THEN HL=4
650 FOR H1=1 TO HL
660 T=T+1:LOCATE H1*2+12,V1*2+4,C
670 POSITION H1*2+12,V1*2+4:? "*":FOR D=1 TO 10:NEXT D
680 POSITION H1*2+12,V1*2+4:? CHR$(C)
690 IF C-64<>T THEN 760
700 NEXT H1:NEXT V1
710 POSITION 4,20:? " YOU DID IT!!":? "TIME: "
720 T=PEEK(20)+256*PEEK(19)+256*PEEK(18):T=T/60
730 ? :? " ";T;" SECONDS"
740 ? :? :? :?
750 END
760 FOR T=1 TO 5:POSITION 3,21:? " SORRY ":SOUND 0,70,12,8
770 FOR D=1 TO 10:NEXT D:SOUND 0,0,0,0:POSITION 3,21:? " "
780 FOR D=1 TO 10:NEXT D:NEXT T
790 LOCATE 1,1,K:GOTO 370
