Minigolf (MINIGOLF.BAS)

Minigolf (old, refer to 90-06B)

Description

Minigolf (old, refer to 90-06B)

From the Antic disk of July 1985 (Vol. 4 No. 3).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 10.7 KB

Dialect
Atari BASIC
Lines
172
Variables
HOLSCR, PN, MAXHOLE, F1, STARTHOLE, HOLENUM, NUMPLAY, TOTAL(, FL, OLDX, BALLX, OLDY, BALLY, L, VEL, TESTX, MX, TESTY, MY, Z, Z1, HX, HY, HSX, HSY, D, UD0$, BALL$, PMB, BX, RITEX, LEFTX, SPEED, WW, P6, CLUBX, CLUBY, UD1$, CLUB$, DX, DY, SS, LS, M, S, BLANK$, HOLEX, HOLEY, STARTX, STARTY, NUMTARG, L2, TYPE, X, Y, W, HOLE(, X1, XC, I, LP, LQ, Y1, YC, BY, UD2$, BARRIER$, NAME$, NN$, TOTAL, R, L1, PMBASE, P, DL, HOLD, WIN, LLQ
BASIC listing (172 lines)
1 REM MINIATURE GOLF
2 REM BY DAVID AND MARISA PLOTKIN
3 REM (c) 1985, ANTIC PUBLISHING
5 GOSUB 3000
10 GRAPHICS 0:GOSUB 1500:HOLSCR=0:PN=1:MAXHOLE=8:GOSUB 1600:REM GET NAMES AND SETUP P/M GRAPHICS
15 F1=1:STARTHOLE=1
20 FOR HOLENUM=STARTHOLE TO MAXHOLE
30 GOSUB 1750:GOSUB 1000:REM SHOW STATUS AND DRAW HOLE
40 IF PN<=NUMPLAY THEN GOSUB 900:GOSUB 700:POKE 77,0:GOTO 40:REM LOOP TIL EVERYONE HAS DONE THE HOLE
50 PN=1:GOSUB 1450:PRINT #6;CHR$(125);:POKE 53278,0:NEXT HOLENUM:REM ERASE P/M, SCREEN, GO TO NEXT HOLE
60 GOTO 3100:REM GAME OVER!
700 REM MOVE THE BALL AROUND THE FIELD
705 HOLSCR=HOLSCR+1:TOTAL(PN)=TOTAL(PN)+1:GOSUB 1765:FL=0:OLDX=BALLX:OLDY=BALLY
710 FOR L=1 TO VEL:TESTX=ABS(BALLX+MX-48):TESTY=ABS(BALLY+MY-15):LOCATE TESTX,TESTY,Z
715 IF (Z=0 AND PEEK(53260)=0) THEN GOTO 770
716 SOUND 0,40,8,14:SOUND 0,0,0,0
717 IF Z=0 THEN GOTO 750
720 IF Z=1 THEN MX=-MX:LOCATE ABS(BALLX+MX-48),TESTY,Z1:IF Z1<>0 THEN MY=-MY
730 IF Z=3 THEN MY=-MY:LOCATE TESTX,ABS(BALLY+MY-15),Z1:IF Z1<>0 THEN MX=-MX
735 HX=ABS(MX):HY=ABS(MY):HSX=SGN(MX):HSY=SGN(MY):IF Z<>2 THEN GOTO 770
736 HSX=HSX+(HSX=0):HSY=HSY+(HSY=0)
740 MX=HY*HSX:MY=HX*HSY:LOCATE ABS(BALLX+MX-48),ABS(BALLY+MY-15),Z1:IF Z1=0 THEN GOTO 770
745 MX=-HY*HSX:MY=-HX*HSY:LOCATE ABS(BALLX+MX-48),ABS(BALLY+MY-15),Z1:IF Z1=0 THEN GOTO 770
747 MX=-HX*HSX:MY=-HY*HSY:GOTO 770
750 IF PEEK(53260)=4 THEN MY=-MY:REM HIT THE BARRIER
760 IF PEEK(53260)=8 THEN GOSUB 850:GOTO 790:REM HIT THE HOLE
770 BALLX=BALLX+MX:BALLY=BALLY+MY
775 D=USR(ADR(UD0$),ADR(BALL$),PMB+512+BALLY,3,BALLX):IF (BX>=RITEX OR BX<=LEFTX) THEN SPEED=-SPEED
776 BX=BX+SPEED:POKE 53250,BX
780 POKE 53278,0:NEXT L:REM CLEAR COLLISIONS
790 RETURN
800 IF (BX>=RITEX OR BX<=LEFTX) THEN SPEED=-SPEED:REM MOVE THE BARRIER
810 BX=BX+SPEED:POKE 53250,BX
820 RETURN
840 REM BALL GOES IN THE HOLE
850 FOR WW=0 TO 100 STEP 2:SOUND 0,WW,10,4:SOUND 1,100-WW,10,4:POKE 712,WW:NEXT WW
860 SOUND 0,0,0,0:SOUND 1,0,0,0:POKE 712,198
870 PN=PN+1:HOLSCR=0:FL=1:IF PN<=NUMPLAY THEN GOSUB 1750:GOSUB 1490:GOSUB 1080:POKE 53278,0
880 RETURN
900 REM MOVE THE CLUB UNDER JOYSTICK CONTROL
905 CLUBX=BALLX:CLUBY=BALLY
910 P6=PEEK(632):CLUBX=CLUBX+2*(P6>4 AND P6<8)*(CLUBX<204)-2*(P6>8 AND P6<12)*(CLUBX>46)
915 IF PEEK(53260)>=4 THEN BALLY=BALLY+MY:D=USR(ADR(UD0$),ADR(BALL$),PMB+512+BALLY,3,BALLX):POKE 53278,0
920 CLUBY=CLUBY+2*(P6=5 OR P6=13 OR P6=9)*(CLUBY<112)-2*(P6=10 OR P6=14 OR P6=6)*(CLUBY>12)
925 IF FL=1 OR PEEK(53279)<>6 OR HOLSCR=0 THEN 930
926 FL=1:HOLSCR=HOLSCR-1:TOTAL(PN)=TOTAL(PN)-1:GOSUB 1765:GOSUB 1480
927 BALLX=OLDX:BALLY=OLDY:D=USR(ADR(UD0$),ADR(BALL$),PMB+512+BALLY,3,BALLX):CLUBX=BALLX:CLUBY=BALLY
930 D=USR(ADR(UD1$),ADR(CLUB$),PMB+639+CLUBY,9,CLUBX)
931 IF PEEK(53279)=5 THEN GOSUB 3400:REM DISPLAY THE SCORES
933 IF PEEK(644)=1 THEN GOSUB 800:GOTO 910
935 IF (BALLY=CLUBY AND BALLX=CLUBX) THEN PRINT CHR$(253);:GOTO 910
940 DX=ABS(BALLX-CLUBX):DY=ABS(BALLY-CLUBY):MX=SGN(BALLX-CLUBX):IF DX<>0 THEN MY=DY/DX*SGN(BALLY-CLUBY):SS=DX
945 IF DY>DX THEN MX=DX/DY*SGN(BALLX-CLUBX):MY=SGN(BALLY-CLUBY):SS=DY
950 FOR LS=1 TO SS:CLUBX=CLUBX+MX:CLUBY=CLUBY+MY:SOUND 0,LS,8,2
960 D=USR(ADR(UD1$),ADR(CLUB$),PMB+639+CLUBY,9,CLUBX):NEXT LS:REM MOVE THE CLUB
965 M=ABS(DX)+ABS(DY):S=3+(M>15)+(M>20)+(M>25)+2*(M>30)+2*(M>35)
970 SOUND 0,40,8,14:SOUND 0,0,0,0:VEL=S*M:REM SET SPEED OF BALL
980 D=USR(ADR(UD1$),ADR(BLANK$),PMB+639+CLUBY,9,CLUBX):REM ERASE CLUB
990 RETURN
1000 RESTORE (2000+(HOLENUM-1)*20):READ HOLEX,HOLEY,STARTX,STARTY,NUMTARG
1005 COLOR 1:PLOT 0,0:DRAWTO 0,79:PLOT 159,0:DRAWTO 159,79:COLOR 3:PLOT 0,0:DRAWTO 159,0:PLOT 0,79
1006 DRAWTO 159,79:COLOR 2:PLOT 0,0:PLOT 0,79:PLOT 159,0:PLOT 159,79:COLOR 1:PLOT 1,0:DRAWTO 1,79
1010 FOR L2=1 TO NUMTARG:READ TYPE,X,Y:IF TYPE=1 OR TYPE=2 THEN GOSUB 1100:REM DRAW TYPE 1/2-DOWN/UP TRIANGLE
1020 IF TYPE=3 OR TYPE=4 THEN GOSUB 1200:REM DRAW TYPE 3/4-RIGHT/LEFT TRIANGLE
1030 IF TYPE=5 THEN GOSUB 1300:REM DRAW SQUARE OR RECTANGLE
1040 IF TYPE=6 THEN GOSUB 1400:REM DRAW BARRIER
1045 IF TYPE=7 THEN GOSUB 1430:REM DRAW THE DIAGONAL LINES
1050 NEXT L2
1060 HOLEX=HOLEX+48:HOLEY=HOLEY+16:FOR W=0 TO 3:POKE PMB+896+HOLEY+W,HOLE(W):NEXT W:POKE 53251,HOLEX
1070 STARTX=STARTX+48:STARTY=STARTY+15:CLUBX=STARTX:CLUBY=STARTY
1075 D=USR(ADR(UD1$),ADR(CLUB$),PMB+639+CLUBY,9,CLUBX)
1080 BALLX=STARTX:BALLY=STARTY:D=USR(ADR(UD0$),ADR(BALL$),PMB+512+BALLY,3,BALLX)
1090 RETURN
1100 READ X1:XC=(X+X1)/2:I=(TYPE=1)-(TYPE=2)
1110 LP=Y-I:FOR LQ=X TO XC:COLOR 1:LP=LP+I:PLOT LQ,Y:DRAWTO LQ,LP:COLOR 2:PLOT LQ,LP:PLOT LQ,LP+I
1115 NEXT LQ:LP=LP+I
1120 FOR LQ=XC TO X1:COLOR 1:LP=LP-I:PLOT LQ,Y:DRAWTO LQ,LP:COLOR 2:PLOT LQ,LP:PLOT LQ,LP+I:NEXT LQ
1130 COLOR 3:PLOT X+1,Y:DRAWTO X1-1,Y:RETURN
1200 READ Y1:YC=(Y+Y1)/2:I=(TYPE=4)-(TYPE=3)
1210 LQ=X+I:FOR LP=Y TO YC:COLOR 1:LQ=LQ-I:PLOT X,LP:DRAWTO LQ,LP:COLOR 2:PLOT LQ,LP:PLOT LQ-I,LP
1215 NEXT LP:LQ=LQ-I
1220 FOR LP=YC TO Y1:COLOR 1:LQ=LQ+I:PLOT X,LP:DRAWTO LQ,LP:COLOR 2:PLOT LQ,LP:PLOT LQ-I,LP:NEXT LP
1230 RETURN
1300 READ X1,Y1
1310 COLOR 1:FOR LP=Y TO Y1:PLOT X,LP:DRAWTO X1,LP:NEXT LP:COLOR 3:PLOT X,Y:DRAWTO X1,Y:PLOT X,Y1:DRAWTO X1,Y1
1320 COLOR 2:PLOT X,Y:PLOT X1,Y:PLOT X1,Y1:PLOT X,Y1
1330 RETURN
1400 READ X1,SPEED:BX=X+48:BY=Y+15:LEFTX=BX:RITEX=X1+48:BX=BX+SPEED
1410 D=USR(ADR(UD2$),ADR(BARRIER$),PMB+768+BY,5,BX)
1420 RETURN
1430 READ X1:Y1=Y+ABS(X1-X):COLOR 2:PLOT X,Y:DRAWTO X1,Y1:PLOT X,Y+1:DRAWTO X1,Y1+1
1440 RETURN
1450 REM ERASE P/M GRAPHICS SHAPES
1460 FOR W=0 TO 3:POKE PMB+896+HOLEY+W,0:NEXT W:REM ERASE THE HOLE
1470 D=USR(ADR(UD2$),ADR(BLANK$),PMB+768+BY,5,0):REM THEN THE BARRIER
1480 D=USR(ADR(UD1$),ADR(BLANK$),PMB+639+CLUBY,9,0):REM NOW THE CLUB
1490 D=USR(ADR(UD0$),ADR(BLANK$),PMB+512+BALLY,3,0):RETURN :REM FINALLY THE BALL
1500 REM GET THE NAMES OF PLAYERS
1505 POSITION 10,3:? "MINIATURE GOLF";
1510 POSITION 0,5:? "How many players (max 8)";:INPUT NUMPLAY:IF NUMPLAY>8 THEN ? CHR$(125):GOTO 1510
1520 DIM NAME$(NUMPLAY*10),NN$(10),TOTAL(NUMPLAY)
1530 FOR L=1 TO NUMPLAY:PRINT "NAME OF PLAYER #";L;" (MAX 10 LETTERS)":INPUT NN$:R=LEN(NN$)+1
1540 IF R<=10 THEN FOR L1=R TO 10:NN$(L1,L1)=" ":NEXT L1
1550 NAME$((L-1)*10+1,L*10)=NN$:TOTAL(L)=0:NEXT L:RETURN
1600 REM SETUP P/M GRAPHICS
1610 PMBASE=PEEK(106)-24:POKE 88,0:POKE 89,PMBASE:? CHR$(125)
1620 GRAPHICS 7:PMB=PMBASE*256:POKE 54279,PMBASE:POKE 53277,3:POKE 559,46:POKE 623,1:POKE 752,1
1630 DIM UD0$(44),UD1$(44),UD2$(44):RESTORE 1640:FOR W=1 TO 44:READ P:UD0$(W,W)=CHR$(P):NEXT W
1640 DATA 104,104,133,215,104,133,214, 104,133,217,104,133,216,104,133,218
1650 DATA 104,170,160,0,177,214,145,216, 200,208,4,230,215,230,217,202
1660 DATA 208,242,198,218,16,238,104, 104,141,0,208,96
1670 UD1$=UD0$:UD2$=UD0$:UD1$(42,42)=CHR$(1):UD2$(42,42)=CHR$(2)
1680 POKE 704,14:POKE 705,24:POKE 706,52:POKE 707,100:POKE 708,200:POKE 709,228:POKE 710,206:POKE 712,198
1690 DIM CLUB$(9),BARRIER$(5),HOLE(4),BALL$(3),BLANK$(9):RESTORE 1740
1700 FOR W=1 TO 9:READ P:CLUB$(W,W)=CHR$(P):NEXT W
1710 FOR W=1 TO 5:READ P:BARRIER$(W,W)=CHR$(P):NEXT W
1720 FOR W=0 TO 3:READ P:HOLE(W)=P:NEXT W
1730 FOR W=1 TO 3:READ P:BALL$(W,W)=CHR$(P):NEXT W
1735 FOR W=1 TO 9:BLANK$(W,W)=CHR$(0):NEXT W:RETURN
1740 DATA 0,0,124,252,252,252,252,0,0,0,255,255,255,0,112,248,248,112,0,128,0
1750 POKE 656,0:POKE 657,0:PRINT "PLAYER: ";NAME$((PN-1)*10+1,PN*10);:POKE 657,22:? "SELECT for scores";
1760 POKE 656,1:POKE 657,1:PRINT "HOLE NUMBER: ";HOLENUM;:POKE 657,22:? "OPTION to return";
1765 POKE 656,2:POKE 657,1
1770 PRINT "HOLE SCORE: ";HOLSCR;"  ";:POKE 657,21:PRINT "TOTAL SCORE: ";TOTAL(PN);"  ";:RETURN
2000 DATA 5,7,80,72,6,1,68,1,92,5,1,50,45,78,5,45,22,65,78,5,95,22,115,78,5,115,50,158,78,6,65,22,87,2
2020 DATA 4,7,142,65,2,5,1,35,125,78,7,130,1,158
2040 DATA 78,7,80,66,5,5,1,1,60,78,5,100,1,159,78,7,70,1,61,7,90,1,99,1,66,15,94
2060 DATA 10,70,143,66,3,5,41,30,119,78,7,20,1,1,7,140,1,158
2080 DATA 15,60,143,60,3,5,40,20,44,78,5,80,1,84,60,5,120,20,124,78
2100 DATA 78,20,80,70,10,1,40,1,70,1,90,1,120,2,40,50,70,2,90,50,120
2101 DATA 5,1,1,54,78,5,54,50,70,78,5,106,1,158,78,5,90,50,106,78,6,55,27,97
2102 DATA 2,7,72,30,84
2120 DATA 10,15,128,65,4,5,1,40,80,79,7,100,1,120,7,140,40,158,7,1,22,12
2140 DATA 145,26,40,65,7,2,90,55,130,5,70,34,109,78,5,110,55,158,78,7,130,1,110,5,70,21,110,22
2141 DATA 5,1,1,10,78,7,53,1,20
3000 GRAPHICS 2+16:POKE 708,36
3010 POKE 752,1:POSITION 2,1:? #6;"DAVID AND MARISA    plotkin  PRESENT";:POSITION 1,3
3015 ? #6;"******************";
3020 POSITION 1,4:? #6;"* miniature golf *";:POSITION 5,6:? #6;"PRESS FIRE";
3025 POSITION 1,5:? #6;"******************";
3030 HOLD=PEEK(708):POKE 708,PEEK(710):POKE 710,HOLD
3040 FOR W=1 TO 10:NEXT W:IF STRIG(0)=0 THEN RETURN
3050 GOTO 3030
3100 REM GAME OVER SEQUENCE
3110 POKE 53277,0:POKE 559,34:GRAPHICS 1+16:POKE 708,52:POSITION 0,0:? #6;"    MINIATURE GOLF ";:REM TURN OFF P/M
3120 POSITION 0,1:? #6;"     SCORE BOARD";:POSITION 0,2:? #6;CHR$(138);:POSITION 1,2:? #6;CHR$(170);
3125 POSITION 0,23:? #6;CHR$(10);:POSITION 1,23:? #6;CHR$(170);:FOR W=2 TO 17 STEP 3:POSITION W,2
3130 ? #6;CHR$(10);:POSITION W+1,2:? #6;CHR$(138);:POSITION W+2,2:? #6;CHR$(170);
3140 POSITION W,23:? #6;CHR$(138);:POSITION W+1,23:? #6;CHR$(10);:POSITION W+2,23:? #6;CHR$(170);:NEXT W
3150 FOR W=3 TO 21 STEP 3:POSITION 19,W:? #6;CHR$(10);:POSITION 19,W+1:? #6;CHR$(138);
3160 POSITION 19,W+2:? #6;CHR$(170);:NEXT W
3170 FOR W=3 TO 21 STEP 3:POSITION 0,W:? #6;CHR$(170);:POSITION 0,W+1:? #6;CHR$(138);
3180 POSITION 0,W+2:? #6;CHR$(10);:NEXT W:FOR PN=1 TO NUMPLAY:POSITION 2,PN+3
3190 ? #6;NAME$((PN-1)*10+1,PN*10);:POSITION 14,PN+3:? #6;TOTAL(PN);:NEXT PN:REM PRINT THE NAMES AND SCORES
3200 WIN=1:IF NUMPLAY=1 THEN GOTO 3240:REM ONLY ONE PLAYER
3210 FOR PN=2 TO NUMPLAY:IF TOTAL(PN)<TOTAL(PN-1) THEN WIN=PN:REM FIND THE WINNER (LOW SCORE)
3220 NEXT PN:FOR PN=1 TO NUMPLAY:IF PN<>WIN THEN IF TOTAL(PN)=TOTAL(WIN) THEN WIN=0
3230 NEXT PN
3240 POSITION 2,21:IF WIN=0 THEN ? #6;"NO WINNER--A TIE!";:GOTO 3260
3250 ? #6;"WINNER:";NAME$((WIN-1)*10+1,WIN*10);
3260 POSITION 1,22:? #6;"PRESS fire TO PLAY";
3300 HOLD=PEEK(709):POKE 709,PEEK(710):POKE 710,PEEK(711):POKE 711,HOLD
3310 FOR W=1 TO 10:NEXT W:IF STRIG(0)=0 THEN RUN
3320 GOTO 3300
3400 REM DISPLAY THE SCORES
3410 ? CHR$(125):FOR LLQ=1 TO NUMPLAY
3420 IF LLQ/2<>INT(LLQ/2) THEN POKE 657,0:GOTO 3440
3430 POKE 657,20
3440 POKE 656,INT((LLQ-1)/2)
3450 ? NAME$((LLQ-1)*10+1,LLQ*10);" ";TOTAL(LLQ);:NEXT LLQ
3460 IF PEEK(53279)<>3 THEN 3460
3470 ? CHR$(125):GOSUB 1750:RETURN