Minigolf (MGCONST.BAS)
Minigolf (old, refer to 90-06B)
Description
Minigolf (old, refer to 90-06B)
From the Antic disk of July 1985 (Vol. 4 No. 3).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 10.0 KB
- Dialect
- Atari BASIC
- Lines
- 192
- Variables
FILES$,T1(,T2(,T3(,T4(,T5(,T6(,T7(,X(,T$,FILE$,HOLE,HOLEX,HOLEY,STARTX,STARTY,CHOICE,T1,L,LL,X,Y,X1,T2,T3,Y1,Y3(,T4,T5,T6,BX,BY,BX1,SPEED,T7,XC,I,YC,Z,LP,LQ,ANS,LINE,NUMTARG,PLUS,COUNT,TYPE,XX(,TYP,ND
BASIC listing (192 lines)
10 REM MINI GOLF CONSTRUCTION SET
20 REM BY DAVID AND MARISA PLOTKIN
30 REM (c) 1985, ANTIC PUBLISHING
100 GRAPHICS 0:GOSUB 800:REM PRINT THE TITLE
110 DIM FILE$(15),T1(45),T2(45),T3(45),T4(45),T5(60),T6(3),T7(45),X(60),T$(2),XX(60)
120 REM OUTPUT DEVICE
130 ? "WHAT DEVICE AND FILENAME (FOR CASSETTE USE C:)";:INPUT #16;FILE$:T$=FILE$(1,2)
140 IF (T$="C:" OR T$="D:" OR T$="D1" OR T$="D2") THEN GOTO 160
150 ? "INVALID DEVICE SPECIFIED. PLEASE USE C: OR D:FILENAME":GOTO 130
160 GOSUB 1000:REM INITIAL QUANTITIES
170 GOSUB 1100:REM TYPE 1 (DOWN TRIANGLES)
180 GOSUB 1200:REM TYPE 2 (UP TRIANGLES)
190 GOSUB 1300:REM TYPE 3 (RIGHT TRIANGLES)
200 GOSUB 1400:REM TYPE 4 (LEFT TRIANGLES)
210 GOSUB 1500:REM TYPE 5 (RECTANGLES)
220 GOSUB 1600:REM TYPE 6 (MOVING BARRIER)
230 GOSUB 1700:REM TYPE 7 (DIAGONAL LINES)
240 TRAP 240:GOSUB 1800:REM PREVIEW, EDIT OR SAVE MENU
250 ON CHOICE GOTO 2000,2300,2500,799:REM CHOOSE THE MENU SELECTION
799 END
800 ? "↰":POSITION 4,0:? "MINIATURE GOLF CONSTRUCTION SET":? :RETURN
850 ? "INVALID QUANTITY ENTERED. PLEASE TRY AGAIN":RETURN
1000 GOSUB 800:? "WHAT HOLE NUMBER:";:INPUT #16;HOLE
1010 ? "WHAT X POSITION FOR HOLE (0-159)";:INPUT #16;HOLEX
1020 IF (HOLEX<0 OR HOLEX>159) THEN GOSUB 850:GOTO 1010
1030 ? "WHAT Y POSITION FOR HOLE (0-79)";:INPUT #16;HOLEY
1040 IF (HOLEY<0 OR HOLEY>79) THEN GOSUB 850:GOTO 1030
1050 ? "WHAT START X POS. FOR BALL (0-159)";:INPUT #16;STARTX
1060 IF (STARTX<0 OR STARTX>159) THEN GOSUB 850:GOTO 1050
1070 ? "WHAT START Y POS. FOR BALL (0-79)";:INPUT #16;STARTY
1080 IF (STARTY<0 OR STARTY>79) THEN GOSUB 850:GOTO 1070
1090 RETURN
1100 GOSUB 800:? "◣◢ DOWN TRIANGLE PLACEMENT ◣◢"
1110 ? "HOW MANY DOWN TRIANGLES (15 MAX)";:INPUT T1
1120 IF T1>15 THEN GOSUB 850:GOTO 1110
1130 IF T1=0 THEN GOTO 1190
1140 ? "FORMAT: UPPER LEFT X AND Y, UPPER RIGHT X"
1150 FOR L=1 TO T1:LL=(L-1)*3
1160 ? "TRIANGLE NUMBER ";L;" POSITION";
1170 INPUT X,Y,X1:IF (X>159 OR X1>159 OR Y>79 OR X1<X) THEN GOSUB 850:GOTO 1160
1180 T1(LL)=X:T1(LL+1)=Y:T1(LL+2)=X1:NEXT L
1190 RETURN
1200 GOSUB 800:? "◢◣ UP TRIANGLE PLACEMENT ◢◣"
1210 ? "HOW MANY UP TRIANGLES (15 MAX)";:INPUT T2
1220 IF T2>15 THEN GOSUB 850:GOTO 1210
1230 IF T2=0 THEN GOTO 1290
1240 ? "FORMAT: LOWER LEFT X AND Y, LOWER RIGHT X"
1250 FOR L=1 TO T2:LL=(L-1)*3
1260 ? "TRIANGLE NUMBER ";L;" POSITION";
1270 INPUT X,Y,X1:IF (X>159 OR X1>159 OR Y>79 OR X1<X) THEN GOSUB 850:GOTO 1260
1280 T2(LL)=X:T2(LL+1)=Y:T2(LL+2)=X1:NEXT L
1290 RETURN
1300 GOSUB 800:? "◣ RIGHT TRIANGLE PLACEMENT ◣"
1301 ? "◢ ◢"
1310 ? "HOW MANY RIGHT TRIANGLES (15 MAX)";:INPUT T3
1320 IF T3>15 THEN GOSUB 850:GOTO 1310
1330 IF T3=0 THEN GOTO 1390
1340 ? "FORMAT: UPPER LEFT X AND Y, LOWER LEFT Y"
1350 FOR L=1 TO T3:LL=(L-1)*3
1360 ? "TRIANGLE NUMBER ";L;" POSITION";
1370 INPUT X,Y,Y1:IF (X>159 OR Y>79 OR Y1>79 OR Y1<Y) THEN GOSUB 850:GOTO 1360
1380 T3(LL)=X:T3(LL+1)=Y:T3(LL+2)=Y1:NEXT L
1390 RETURN
1400 GOSUB 800:? "◢ LEFT TRIANGLE PLACEMENT ◢"
1401 ? "◣ ◣"
1410 ? "HOW MANY LEFT TRIANGLES (15 MAX)";:INPUT T4
1420 IF T4>15 THEN GOSUB 850:GOTO 1410
1430 IF T4=0 THEN GOTO 1490
1440 ? "FORMAT: UPPER RIGHT X AND Y, LOWER RIGHT Y"
1450 FOR L=1 TO T4:LL=(L-1)*3
1460 ? "TRIANGLE NUMBER ";L;" POSITION";
1470 INPUT X,Y,Y1:IF (X>159 OR Y>79 OR Y1>79 OR Y1<Y) THEN GOSUB 850:GOTO 1460
1480 T4(LL)=X:T4(LL+1)=Y:T4(LL+2)=Y1:NEXT L
1490 RETURN
1500 GOSUB 800:? "SQUARE/RECTANGLE PLACEMENT"
1510 ? "HOW MANY RECTANGLES (15 MAX)";:INPUT T5
1520 IF T5>15 THEN GOSUB 850:GOTO 1510
1530 IF T5=0 THEN GOTO 1590
1540 ? "FORMAT: UPPER LEFT X AND Y, LOWER RIGHT X AND Y"
1550 FOR L=1 TO T5:LL=(L-1)*4
1560 ? "RECTANGLE NUMBER ";L;" POS.";
1570 INPUT X,Y,X1,Y1:IF (X>159 OR X1>159 OR Y>79 OR Y1>79 OR X1<X OR Y1<Y) THEN GOSUB 850:GOTO 1560
1580 T5(LL)=X:T5(LL+1)=Y:T5(LL+2)=X1:T5(LL+3)=Y1:NEXT L
1590 RETURN
1600 GOSUB 800:? "MOVING BARRIER PLACEMENT"
1610 ? "HOW MANY BARRIERS (0-NONE 1-FOR BARRIER)";:INPUT T6
1620 IF (T6<>0 AND T6<>1) THEN GOSUB 850:GOTO 1610
1630 IF T6=0 THEN GOTO 1690
1640 ? "FORMAT: LEFT X AND Y BOUNDARY, RIGHT XBOUNDARY"
1650 INPUT BX,BY,BX1:IF (BX>159 OR BX1>159 OR BY>79 OR BX1<BX) THEN GOSUB 850:GOTO 1650
1660 ? "WHAT SPEED (3-4 WORKS BEST)";:INPUT SPEED
1670 T6(0)=BX:T6(1)=BY:T6(2)=BX1:T6(3)=SPEED
1690 RETURN
1700 GOSUB 800:? "DIAGONAL LINE PLACEMENT"
1710 ? "HOW MANY DIAGONAL LINES (15 MAX)";:INPUT T7
1720 IF T7>15 THEN GOSUB 850:GOTO 1710
1730 IF T7=0 THEN GOTO 1790
1740 ? "FORMAT: UPPER X AND Y, LOWER X"
1750 FOR L=1 TO T7:LL=(L-1)*3
1760 ? "DIAGONAL LINE NUMBER ";L;" POS.";
1770 INPUT X,Y,X1:IF (X>159 OR X1>159 OR Y>79) THEN GOSUB 850:GOTO 1760
1780 T7(LL)=X:T7(LL+1)=Y:T7(LL+2)=X1:NEXT L
1790 RETURN
1800 GRAPHICS 0:GOSUB 800:? " MAIN MENU":?
1810 ? "1. PREVIEW HOLE":? "2. EDIT HOLE DATA":? "3. SAVE DATA":? "4. QUIT THIS PROGRAM":?
1820 ? "YOUR CHOICE";:INPUT CHOICE:IF (CHOICE<1 OR CHOICE>4) THEN ? :GOSUB 850:? :GOTO 1810
1830 RETURN
2000 REM PREVIEW THE HOLE (DRAW TARGETS)
2004 GRAPHICS 7:POKE 752,1:POKE 708,200:POKE 709,228:POKE 710,206:POKE 712,198:TRAP 3250
2005 COLOR 1:PLOT 0,0:DRAWTO 0,79:PLOT 159,0:DRAWTO 159,79:COLOR 3:PLOT 0,0:DRAWTO 159,0
2006 PLOT 0,79:DRAWTO 159,79:COLOR 2:PLOT 0,0:PLOT 0,79:PLOT 159,0:PLOT 159,79
2010 IF T1=0 THEN GOTO 2040:REM DRAWT DOWN TRIANGLES
2020 FOR L=1 TO T1:LL=(L-1)*3:X=T1(LL):Y=T1(LL+1):X1=T1(LL+2)
2030 XC=(X+X1)/2:I=1:GOSUB 3000:NEXT L:REM DRAW TYPE 1
2040 IF T2=0 THEN GOTO 2070:REM DRAW UP TRIANGLES
2050 FOR L=1 TO T2:LL=(L-1)*3:X=T2(LL):Y=T2(LL+1):X1=T2(LL+2)
2060 XC=(X+X1)/2:I=-1:GOSUB 3000:NEXT L:REM DRAW TYPE 2
2070 IF T3=0 THEN GOTO 2100:REM DRAW RIGHT TRIANGLES
2080 FOR L=1 TO T3:LL=(L-1)*3:X=T3(LL):Y=T3(LL+1):Y1=T3(LL+2)
2090 YC=(Y+Y1)/2:I=-1:GOSUB 3100:NEXT L:REM DRAW TYPE 3
2100 IF T4=0 THEN GOTO 2150:REM DRAW LEFT TRIANGLES
2110 FOR L=1 TO T4:LL=(L-1)*3:X=T4(LL):Y=T4(LL+1):Y1=T4(LL+2)
2120 YC=(Y+Y1)/2:I=1:GOSUB 3100:NEXT L:REM DRAW TYPE 4
2150 IF T5=0 THEN GOTO 2171:REM DRAW RECTANGLES
2160 FOR L=1 TO T5:LL=(L-1)*4:X=T5(LL):Y=T5(LL+1):X1=T5(LL+2):Y1=T5(LL+3)
2170 GOSUB 3200:NEXT L:REM DRAW TYPE 5
2171 IF T7=0 THEN GOTO 2180:REM DRAW DIAGONAL LINES
2172 FOR L=1 TO T7:LL=(L-1)*3:X=T7(LL):Y=T7(LL+1):X1=T7(LL+2)
2173 Y1=Y+ABS(X1-X):COLOR 2:PLOT X,Y:DRAWTO X1,Y1:PLOT X,Y+1:DRAWTO X1,Y1+1
2174 NEXT L:REM DRAW TYPE 7
2180 COLOR 3:PLOT HOLEX+1,HOLEY:DRAWTO HOLEX+3,HOLEY:PLOT HOLEX+1,HOLEY+4:DRAWTO HOLEX+3,HOLEY+4:REM DRAW HOLE
2190 FOR L=HOLEY+1 TO HOLEY+3:PLOT HOLEX,L:DRAWTO HOLEX+4,L:NEXT L
2195 IF T6=0 THEN GOTO 2220
2200 FOR L=BX TO BX+8 STEP 2:COLOR 2:PLOT L,BY:DRAWTO L,BY+2:REM DRAW THE BARRIER
2210 COLOR 3:PLOT L+1,BY:DRAWTO L+1,BY+2:NEXT L
2220 LOCATE STARTX,STARTY,Z:Z=Z+2:COLOR Z:PLOT STARTX,STARTY
2230 POKE 764,255:? "HIT ANY KEY TO RETURN TO MENU";
2240 IF PEEK(764)=255 THEN 2240
2250 POKE 764,255:GOTO 240
2300 REM EDIT HOLE DATA
2310 GRAPHICS 0:GOSUB 800:? "EDIT HOLE DATA":? :?
2320 ? "ENTER WHICH TYPE OF OBJECT TO EDIT":? "1. DOWN TRIANGLES"
2330 ? "2. UP TRIANGLES":? "3. RIGHT TRIANGLES":? "4. LEFT TRIANGLES":? "5. RECTANGLES"
2340 ? "6. MOVING BARRIER":? "7. DIAGONAL LINES":? "8. INITIAL DATA (HOLE NUMBER,HOLE LOC.,BALL LOC.)"
2350 ? "9. RETURN TO MAIN MENU"
2360 ? :? "YOUR CHOICE";:INPUT ANS:IF (ANS<1 OR ANS>9) THEN GOSUB 850:GOTO 2360
2370 IF ANS=9 THEN GOTO 240
2380 ON ANS GOSUB 1100,1200,1300,1400,1500,1600,1700,1000
2390 GOTO 2310
2500 REM SAVE DATA TO DISK OR CASSETTE
2510 GRAPHICS 0:GOSUB 800:? :? "PLEASE WAIT. SAVING YOUR DATA..."
2515 ND=(T1+T2+T3+T4+T7)*4+(T5+T6)*5
2520 LINE=(HOLE-1)*20+2000:NUMTARG=T1+T2+T3+T4+T5+T6+T7:PLUS=0:COUNT=0:CLOSE #1:OPEN #1,8,0,FILE$:GOSUB 2710
2530 PRINT #1;HOLEX;",";HOLEY;",";STARTX;",";STARTY;",";NUMTARG;",";:COUNT=5
2540 IF T1=0 THEN GOTO 2560
2550 TYPE=1:FOR L=1 TO T1:LL=(L-1)*3:XX(LL)=T1(LL):XX(LL+1)=T1(LL+1):XX(LL+2)=T1(LL+2):GOSUB 2750:NEXT L
2560 IF T2=0 THEN GOTO 2580
2570 TYPE=2:FOR L=1 TO T2:LL=(L-1)*3:XX(LL)=T2(LL):XX(LL+1)=T2(LL+1):XX(LL+2)=T2(LL+2):GOSUB 2750:NEXT L
2580 IF T3=0 THEN GOTO 2600
2590 TYPE=3:FOR L=1 TO T3:LL=(L-1)*3:XX(LL)=T3(LL):XX(LL+1)=T3(LL+1):XX(LL+2)=T3(LL+2):GOSUB 2750:NEXT L
2600 IF T4=0 THEN GOTO 2620
2610 TYPE=4:FOR L=1 TO T4:LL=(L-1)*3:XX(LL)=T4(LL):XX(LL+1)=T4(LL+1):XX(LL+2)=T4(LL+2):GOSUB 2750:NEXT L
2620 IF T5=0 THEN GOTO 2650
2630 TYPE=5:FOR L=1 TO T5:LL=(L-1)*4:XX(LL)=T5(LL):XX(LL+1)=T5(LL+1):XX(LL+2)=T5(LL+2):GOSUB 2750
2640 PRINT #1;T5(LL+3);:COUNT=COUNT+1:ND=ND-1:GOSUB 2765:NEXT L
2650 IF T6=0 THEN GOTO 2680
2660 TYPE=6:LL=0:FOR L=0 TO 2:XX(L)=T6(L):NEXT L:GOSUB 2750
2670 PRINT #1;T6(3);:COUNT=COUNT+1:ND=ND-1:GOSUB 2765
2680 IF T7=0 THEN GOTO 2700
2690 TYPE=7:FOR L=1 TO T7:LL=(L-1)*3:XX(LL)=T7(LL):XX(LL+1)=T7(LL+1):XX(LL+2)=T7(LL+2):GOSUB 2750:NEXT L
2700 GOTO 240
2710 PRINT #1;LINE+PLUS;" DATA ";:RETURN :REM PRINT NEW LINE
2750 PRINT #1;TYPE;",";XX(LL);",";XX(LL+1);",";XX(LL+2);
2760 COUNT=COUNT+4:ND=ND-4
2765 IF (COUNT<21 AND ND>0) THEN PRINT #1;",";:GOTO 2780
2770 COUNT=0:PLUS=PLUS+1:PRINT #1;"":IF ND>0 THEN GOSUB 2710:REM NEW LINE
2780 RETURN
3000 REM DRAW TYPE 1 OR 2
3010 LP=Y-I:FOR LQ=X TO XC:COLOR 1:LP=LP+I:PLOT LQ,Y:DRAWTO LQ,LP:COLOR 2:PLOT LQ,LP:PLOT LQ,LP+I
3020 NEXT LQ:LP=LP+I
3030 FOR LQ=XC TO X1:COLOR 1:LP=LP-I:PLOT LQ,Y:DRAWTO LQ,LP:COLOR 2:PLOT LQ,LP:PLOT LQ,LP+I:NEXT LQ
3040 COLOR 3:PLOT X+1,Y:DRAWTO X1-1,Y:RETURN
3100 REM DRAW TYPE 3 OR 4
3110 LQ=X+I:FOR LP=Y TO YC:COLOR 1:LQ=LQ-I:PLOT X,LP:DRAWTO LQ,LP:COLOR 2:PLOT LQ,LP:PLOT LQ-I,LP
3120 NEXT LP:LQ=LQ-I
3130 FOR LP=YC TO Y1:COLOR 1:LQ=LQ+I:PLOT X,LP:DRAWTO LQ,LP:COLOR 2:PLOT LQ,LP:PLOT LQ-I,LP:NEXT LP
3140 RETURN
3200 REM DRAW TYPE 5
3210 COLOR 1:FOR LP=Y TO Y1:PLOT X,LP:DRAWTO X1,LP:NEXT LP:COLOR 3:PLOT X,Y:DRAWTO X1,Y:PLOT X,Y1:DRAWTO X1,Y1
3220 COLOR 2:PLOT X,Y:PLOT X1,Y:PLOT X1,Y1:PLOT X,Y1
3230 RETURN
3250 ? "ERROR TRYING TO DRAW THE HOLE":? "PLEASE EDIT AND TRY AGAIN":GOTO 2230
