Guess That Song! (GUESSIT.BAS)
Guess That Song!, game by Karl E. Wiegers, 59
Description
Guess That Song!, game by Karl E. Wiegers, 59
From the Antic disk of July 1985 (Vol. 4 No. 3).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 7.2 KB
- Dialect
- Atari BASIC
- Lines
- 157
- Variables
PLYR1$,PLYR2$,NAME$,CAT$,DONE$,P$,D$,BID$,BL$,WHO$,S(,LAST,OLDBID,A,I,Y,DL,SONG,CA,LN,NUBID,TEMPO,PAUSE,J,K,TIM,OB,CURBID
BASIC listing (157 lines)
10 REM GUESS THAT SONG!
20 REM BY KARL E. WIEGERS
30 REM (c) 1985, ANTIC PUBLISHING
50 DIM PLYR1$(8),PLYR2$(8),NAME$(40),CAT$(44),DONE$(40),P$(11),D$(11),BID$(2),BL$(38),WHO$(8),S(2)
60 NAME$=" ":NAME$(40)=NAME$:NAME$(2)=NAME$:DONE$=NAME$:BL$=NAME$(3)
70 CAT$=" rock classical theme songs general "
80 S(1)=0:S(2)=0:LAST=2:OLDBID=11
90 GOSUB 1000:REM GET PLAYER NAMES
110 GOSUB 1500:REM GET CATEGORY
120 GOSUB 2000:REM DO BIDDING
130 GOSUB 2200:REM PLAY SONG
140 GOSUB 2800:REM JUDGE ANSWER
150 GOSUB 3500:REM SEE IF THERE'S A WINNER YET
160 IF A=78 OR A=110 THEN END
170 IF A=89 OR A=121 THEN 60
180 FOR I=1 TO 40:IF DONE$(I,I)=" " THEN 110
190 NEXT I
200 GRAPHICS 17:? #6;"SORRY, OUT OF SONGS"
210 ? #6:? #6;" PRESS ANY KEY TO":? #6;" PLAY AGAIN"
220 GOSUB 900:GOTO 60
800 FOR I=1 TO 15:SOUND 0,96,10,10:NEXT I
810 FOR I=1 TO 15:SOUND 0,128,10,10:NEXT I
820 SOUND 0,0,0,0:RETURN
900 OPEN #1,4,0,"K:":GET #1,A:CLOSE #1:RETURN
1000 GRAPHICS 18:TRAP 1000:POKE 65,0
1010 POSITION 2,0:? #6;"guess that SONG!"
1020 POSITION 1,4:? #6;"WHO IS PLAYER 1?"
1030 POSITION 5,5:? #6;"?":Y=5:GOSUB 1100
1040 PLYR1$=NAME$(1,I-1)
1050 POSITION 1,8:? #6;"WHO IS PLAYER 2?"
1060 POSITION 5,9:? #6;"?":Y=9:GOSUB 1100
1070 PLYR2$=NAME$(1,I-1)
1080 TRAP 40000:RETURN
1100 OPEN #1,4,0,"K:"
1110 FOR I=1 TO 14:GET #1,A
1120 IF A=155 THEN 1150
1130 POSITION I+5,Y:PUT #6,A
1140 NAME$(I,I)=CHR$(A):NEXT I
1150 CLOSE #1:RETURN
1500 GRAPHICS 0:POKE 752,1:POKE 708,88:POKE 710,18
1510 DL=PEEK(560)+256*PEEK(561)
1520 POKE DL+3,70:FOR I=6 TO 10:POKE DL+I,6:NEXT I
1530 POSITION 1,0:? #6;PLYR1$:POSITION 11,0:? #6;PLYR2$
1540 POSITION 3,1:? #6;S(1):POSITION 13,1:? #6;S(2)
1550 SONG=INT(100*RND(0)):IF SONG<1 OR SONG>40 THEN 1550
1560 IF DONE$(SONG,SONG)="1" THEN 1550
1570 CA=INT((SONG+9)/10):LN=3990+SONG*10
1580 POSITION 20,2:? #6;"CATEGORY:";CAT$(11*CA-10,11*CA)
1590 RETURN
2000 OLDBID=11
2005 TRAP 40000:IF LAST=1 THEN WHO$=PLYR2$
2010 IF LAST=2 THEN WHO$=PLYR1$
2020 POSITION 2,6:? WHO$;", you can guess that song in":? "how many notes..."
2030 POSITION 20,7:INPUT BID$
2035 IF BID$="0" THEN OB=2:GOTO 2071
2036 IF BID$<>"1" THEN 2040
2037 IF LAST=2 THEN LAST=1:GOTO 2039
2038 IF LAST=1 THEN LAST=2
2039 BID$="P":OLDBID=1:POSITION 10,4:? "CURRENT BID = ";OLDBID;" "
2040 IF BID$="P" OR BID$="p" THEN 2110
2050 TRAP 2070:NUBID=VAL(BID$)
2060 IF NUBID<OLDBID AND NUBID>0 THEN 2090
2070 OB=OLDBID
2071 GOSUB 800:? :? "MUST BE FROM 1 TO ";OB-1;", OR P TO PASS":FOR TIM=1 TO 500:NEXT TIM
2075 ? "↑Please try again. ":FOR TIM=1 TO 500:NEXT TIM
2077 ? "↑ "
2080 POSITION 20,7:? " ":GOTO 2030
2090 OLDBID=NUBID:LAST=1+(LAST=1):POSITION 10,4:? "CURRENT BID = ";OLDBID;" "
2100 POSITION 1,6:? BL$:? BL$:? BL$:? BL$:GOTO 2005
2110 IF OLDBID=11 THEN OLDBID=10
2120 RETURN
2200 POSITION 1,6:? BL$:? BL$:? BL$:? BL$
2210 IF LAST=1 THEN WHO$=PLYR1$
2220 IF LAST=2 THEN WHO$=PLYR2$
2230 POSITION 2,6:? "Okay, ";WHO$;", here are your ";OLDBID;" notes."
2240 ? "For ";11-OLDBID;" point";:IF OLDBID<10 THEN ? "s";
2245 ? ", GUESS THAT SONG!!"
2250 FOR I=1 TO 300:NEXT I
2260 GOSUB 2500
2270 POSITION 2,10:? "Press A for answer, R to play again"
2280 GOSUB 900
2290 IF A=82 OR A=114 THEN 2260
2300 IF A<>65 AND A<>97 THEN GOSUB 800:GOTO 2280
2310 RETURN
2500 RESTORE LN:READ TEMPO,PAUSE,P$,D$,NAME$
2510 FOR I=1 TO OLDBID
2520 FOR J=1 TO TEMPO*(ASC(D$(I,I))-64)
2530 SOUND 0,ASC(P$(I,I)),10,8:NEXT J
2540 FOR J=1 TO PAUSE:SOUND 0,0,0,0:NEXT J
2550 NEXT I:SOUND 0,0,0,0:RETURN
2800 POSITION 2,10:? "The title of this song is: ":? :? NAME$
2810 POSITION 2,15:? "Did ";WHO$;" get the title correct?"
2820 GOSUB 900
2830 IF A=78 OR A=110 THEN 2900
2840 IF A<>89 AND A<>121 THEN GOSUB 800:? :? " PRESS Y FOR YES OR N FOR NO":GOTO 2820
2850 FOR I=1 TO 11-OLDBID:S(LAST)=S(LAST)+1:POSITION 3+(LAST=2)*10,1:? #6;S(LAST);" "
2860 GOSUB 3100:NEXT I
2870 DONE$(SONG,SONG)="1"
2880 POSITION 2,15:? "Here are the first ten notes.... ":OLDBID=10:GOSUB 2500
2890 GOTO 3000
2900 FOR I=1 TO OLDBID:S(LAST)=S(LAST)-1:POSITION 3+(LAST=2)*10,1:? #6;S(LAST);" "
2910 POKE 53279,1:FOR J=1 TO 20:NEXT J:NEXT I
3000 POSITION 7,20:? " PRESS ANY KEY TO CONTINUE "
3010 GOSUB 900:RETURN
3100 FOR J=8 TO 0 STEP -1:SOUND 0,53,10,J:FOR K=1 TO 4:NEXT K:NEXT J:RETURN
3500 IF S(1)>=50 THEN WHO$=PLYR1$:GOTO 3530
3510 IF S(2)>=50 THEN WHO$=PLYR2$:GOTO 3530
3520 A=0:RETURN
3530 GRAPHICS 18
3540 POSITION 3,4:? #6;WHO$;" wins!!"
3550 FOR I=40 TO 230:POKE 708,I:NEXT I
3560 LN=5000:OLDBID=11:GOSUB 2500
3570 POSITION 4,8:? #6;"PLAY AGAIN?"
3580 GOSUB 900:IF A=78 OR A=89 OR A=110 OR A=121 THEN RETURN
3600 POSITION 4,10:? #6;"PRESS Y OR N":GOTO 3580
3999 REM SONG DATA
4000 DATA 15,8,llyl♣▌"Y6Y,AAABBBBABA,"Sunshine of Your Love"
4010 DATA 10,4,♣◢y♣"♣6♣♣",BAHABAIBAB,"Yellow Submarine"
4020 DATA 16,4,"66♣♥rl◆[◆,AAHAAAAAAB,"Yesterday"
4030 DATA 6,5,ylf[fly◢y◢,CCOCCCBBPC,"The Age of Aquarius"
4040 DATA 16,3,◆◆@@@UQU◆@,DBACBCABHB,"Scarborough Fair"
4050 DATA 13,4,◆U◆l◆◆U◆l♥,AAAALAAACL,"California Dreaming"
4060 DATA 4,6,A♣<@HA♣HQH,BFFCHBFFCH,"Happy Together"
4070 DATA 25,4,♣y◆H@◆y@<Q,AAAAAAAAAA,"Stairway to Heaven"
4080 DATA 12,6,6▌ffrf[yyf,CCFBABAHAB,"Close to You"
4090 DATA 20,5,♣"♣y◢y[QHH,AABBBACAAA,"Ebony and Ivory"
4100 DATA 28,3,"yf"yf"yf",AAAAAAAAAA,"Moonlight Sonata"
4110 DATA 21,4,"6◢y[ly[l◢,BBBAABAABB,"Pictures at an Exhibition"
4120 DATA 12,4,<@<5<@H<<H,LAAAAAABAA,"Ravel's Bolero"
4130 DATA 20,7,YY-♣♣HHUUY,AAAABABABA,"The Blue Danube"
4140 DATA 6,5,"""L666Y"",CCCNCCCLBB,"Beethoven's Fifth Symphony"
4150 DATA 20,3,♣♣y♣♣y♣y[◆,AADAADAABC,"Brahms' Lullaby"
4160 DATA 23,4,◆yl◆Q[[HQQ,AAAAAAAAAA, "Jesu Joy of Man's Desiring" (Bach)
4170 DATA 20,3,◆U◆lrl♥♥rl,ABABAACAAB,"Carnival of Venice"
4180 DATA 4,8,llll◆◆Ul◆l,FAAAFFFFME,Marche Miniature from "The Nutcracker"
4190 DATA 15,8,"♣◢yl◢lr♣r,AAAAAABAAB,"In the Hall of the Mountain King"
4200 DATA 28,3,"yflyfyly▌,AAAAAAAAAA,"The Godfather"
4210 DATA 5,4,"♣yl◆yyyl◆,DBDBGDZDBD,"All in the Family"
4220 DATA 15,4,A◆r♥A◆♥♣♣H,BCAJBCAJBC,"Tara's Theme" (Gone With the Wind)
4230 DATA 15,5,[flflflyly,BBACBBAGAA,"MASH" ("Suicide is Painless")
4240 DATA 8,5,A♣◆lr♥H◆lr,DGGAAAGDAA,"Star Wars"
4250 DATA 14,4,QHQ[◆ly♥♣♥,BBAAFAABBD,"The Sound of Music"
4260 DATA 12,4,"▌♣[♣[♣[[Q,AAABABAFAA,"The Sting"
4270 DATA 6,20,""◢y""6-"",CCBBCCBBCC,"Mission Impossible"
4280 DATA 10,5,A♣lr♣-♥◆◆L,CAFBAAAFAJ,"Star Trek"
4290 DATA 10,5,D[fly◢y[[◆,MAAAAABBAA,"Oklahoma!"
4300 DATA 10,7,◆◆◆[◆ly◆◆Q,CBABABAKAB,"Raindrops Keep Falling on My Head"
4310 DATA 9,5,"AsA"y◆lyA,BACCCFBACC,"The Star-Spangled Banner"
4320 DATA 14,3,l[QH@HQ◆yl,BDBCABDBCA,"Greensleeves"
4330 DATA 10,5,♣♣▌♣♥♣♥♣♥♣,DCAAGABAAB,"Beer Barrel Polka"
4340 DATA 11,5,lQl♥"◆l♥l♣,BBBBCAAABI,"How Much is That Doggy in the Window?"
4350 DATA 30,3,A-"yYA-♥♥s,AAAEAAABCA,"Autumn Leaves"
4360 DATA 30,4,A◆lr◢♥U▌LU,AAAAAABAAA,"When You Wish Upon A Star"
4370 DATA 21,4,"ylfQ♣l♥▌",AAAAAFBFBH,"The Shadow of Your Smile"
4380 DATA 13,4,6♣yl♣l[Qy[,DBBCADDBBH,"Anchors Aweigh"
4390 DATA 3,8,yl◆[y♣"6Al,BBBGGGDBDB,"Seventy-Six Trombones"
5000 DATA 6,4,lrl♥l◆[UQLH,DCABDBBBBBD,WINNER
