game (DARKSTAR.BAS)
game by Michael Mitchell, 66
Description
game by Michael Mitchell, 66
From the Antic disk of July 1985 (Vol. 4 No. 3).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.5 KB
- Dialect
- Atari BASIC
- Lines
- 30
- Variables
XX,YY,X,Y,A,B,Z,S,LO,L,H,LL,LOC,P,BC,SC,SH,SL,G,C,D,MEME,SS
BASIC listing (30 lines)
10 REM DARKSTAR, LISTING 2
20 REM BY MICHAEL MITCHELL
30 REM (c) 1985, ANTIC PUBLISHING
40 GRAPHICS 17:SOUND 0,191,10,15:SOUND 2,190,10,15:SH=2:SS=STICK(0)
50 POSITION 5,5:? #6;"DARK STAR":POSITION 2,10:? #6;"by mike mitchell":POSITION 1,16:? #6;"PRESS FIRE to begin"
60 X=X+1:SETCOLOR 0,X,10:SETCOLOR 1,X+3,10:SETCOLOR 2,X+5,10:SETCOLOR 3,X+7,10:IF STRIG(0)=0 THEN 80
70 GOTO 50
80 POKE 559,0:POKE 53768,133:FOR S=1 TO 2500:NEXT S:GRAPHICS 23:POKE 559,0:SOUND 0,0,0,0:SOUND 2,0,0,0
90 COLOR 3:XX=1:YY=0:X=50:Y=50:PLOT 2,2:DRAWTO 159,2:DRAWTO 159,79:DRAWTO 2,79:DRAWTO 2,2:POKE 559,34
100 SETCOLOR 0,10,15:SETCOLOR 2,5,7:SC=SC+10
110 A=RND(0)*152+3:B=RND(50)*70+5:COLOR 1:PLOT A,B:DRAWTO A+2,B
120 POKE 77,0:DRAWTO A+2,B+2:DRAWTO A,B+2:DRAWTO A,B
130 LOCATE X,Y,Z:IF Z=3 THEN 210
140 COLOR 3:PLOT X,Y:POKE 53279,5:SS=STICK(0):IF SS=14 THEN XX=0:YY=-1
150 IF Z=1 THEN FOR B=10 TO 1 STEP -1:SETCOLOR 4,B,B:SOUND 0,10,8,B:NEXT B:X=X+XX:Y=Y+YY:SETCOLOR 4,0,0:GOTO 100
160 IF SS=13 THEN XX=0:YY=1
170 IF SS=11 THEN XX=-1:YY=0
180 IF SS=7 THEN XX=1:YY=0
190 X=X+XX:Y=Y+YY:GOTO 130
200 REM EXPLOSION SUBROUTINE
210 S=PEEK(560)+256*PEEK(561)+5:L=0:H=0:FOR LL=70 TO 0 STEP -1.3:L=L+60:IF L>255 THEN L=L-256:SOUND 0,LL,8,13
220 SOUND 1,LL+5,8,14:SOUND 2,LL+10,8,12
230 POKE S,L:POKE S+1,H:NEXT LL:SH=SH-1:IF SH<0 THEN GOSUB 300:GRAPHICS 18:GOTO 250
240 GOSUB 300:GRAPHICS 7+16:GOTO 90
250 SOUND 0,191,10,15:SOUND 2,190,10,15
260 POSITION 5,3:? #6;"GAME OVER":POSITION 5,5:? #6;"SCORE ";SC:X=X+1
270 SETCOLOR 0,X,X:IF X>350 THEN GOSUB 300:GOTO 40
280 IF STRIG(0)=0 THEN GOTO 80
290 SH=2:GOTO 260
300 FOR D=0 TO 3:SOUND D,0,0,0:NEXT D:RETURN
