Crypto Quotes (CRYPTO.BAS)
Crypto Quotes, game by Mike Fleischmann, 67
Description
Crypto Quotes, game by Mike Fleischmann, 67
From the Antic disk of July 1985 (Vol. 4 No. 3).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 3.2 KB
- Dialect
- Atari BASIC
- Lines
- 84
- Variables
A$,B$,CH1$,CH2$,ALPH$,C$,I,BPT1,BPT2,BPT3,BPT4,T,X,KK,CH$
BASIC listing (84 lines)
10 REM CRYPTO QUOTES
20 REM BY MIKE FLEISCHMANN
30 REM (c) 1985, ANTIC PUBLISHING
90 DIM A$(320),B$(320),CH1$(3),CH2$(1),ALPH$(26),C$(320)
100 GRAPHICS 0:? ," CRYPTO QUOTES ":?
105 ? "INPUT YOUR STRING:"
110 INPUT A$
140 REM If your string is too long for A$, continue it in B$, below.
160 ? :? "INPUT THE REST OF YOUR STRING":? " or press [RETURN]."
170 INPUT B$:IF LEN(B$)<1 THEN C$=A$:GOTO 190
180 C$(1,LEN(A$))=A$:C$(LEN(A$)+1,LEN(A$)+1)=" ":C$(LEN(A$)+2)=B$:A$=C$
190 FOR I=1 TO LEN(C$):KK=ASC(C$(I,I)):IF KK=32 THEN 210
200 IF KK<65 OR KK>90 THEN POP :POSITION 7,10:? "↰ UPPER CASE LETTERS ONLY!";:FOR KK=1 TO 300:NEXT KK:GOTO 10
210 NEXT I
220 FOR I=1 TO LEN(C$):C$(I,I)=CHR$(ASC(C$(I,I))+128):NEXT I
230 FOR I=1 TO 320:B$(I)=" ":NEXT I
240 GRAPHICS 0:? ," CRYPTO QUOTES ":GOSUB 10090:REM FIGURE OUT STRING BREAK POSITIONS
250 ALPH$="ABCDEFGHIJKLMNOPQRSTUVWXYZ"
260 GOSUB 1050:REM PRINT CRYPTO STRING
270 GOSUB 2050:REM PRINT REPLACEMENT STRING
280 POSITION 6,10:? ALPH$:? :? " Type in the letter you want to "
290 ? " change and then the letter you "
300 ? " think it should be."
305 ? :? "(For example, typing W S changes all W's to S's.)"
310 ? :? " IF W= # GUESSES WILL BE ERASED"
320 ? " IF W= @ START OVER"
330 ? " IF W= % END PROGRAM":PRINT " ":POSITION 3,22
340 INPUT CH1$:IF LEN(CH1$)<1 THEN 240
341 FOR X=1 TO LEN(CH1$):KK=ASC(CH1$(X,X))
342 IF (KK>64 AND KK<91) THEN 348
343 IF KK=32 OR KK=35 OR KK=37 OR KK=64 THEN 348
344 POP :POSITION 7,6:? "↰ UPPERCASE LETTERS ONLY!";:FOR KK=1 TO 150:NEXT KK
347 GOTO 240
348 NEXT X
350 IF CH1$="#" THEN 230
360 IF CH1$="@" THEN A$="":GOTO 100
370 IF CH1$="%" THEN 420
380 IF LEN(CH1$)<3 THEN CH2$=" ":CH1$=CH1$(1,1):GOTO 400
390 CH2$=CH1$(3,3):CH1$=CH1$(1,1)
400 GOSUB 3060
410 GOTO 270
420 GRAPHICS 0:END
1050 POSITION 1,2:FOR I=1 TO BPT1:PRINT C$(I,I);:NEXT I
1060 IF BPT2=0 THEN RETURN
1070 POSITION 1,4:FOR I=BPT1+1 TO BPT2:PRINT C$(I,I);:NEXT I
1080 IF BPT3=0 THEN RETURN
1090 POSITION 1,6:FOR I=BPT2+1 TO BPT3:PRINT C$(I,I);:NEXT I
1100 IF BPT4=0 THEN RETURN
1110 POSITION 1,8:FOR I=BPT3+1 TO BPT4:PRINT C$(I,I);:NEXT I
1120 RETURN
2050 POSITION 1,1:FOR I=1 TO BPT1:PRINT B$(I,I);:NEXT I
2060 IF BPT2=0 THEN RETURN
2070 POSITION 1,3:FOR I=BPT1+1 TO BPT2:PRINT B$(I,I);:NEXT I
2080 IF BPT3=0 THEN RETURN
2090 POSITION 1,5:FOR I=BPT2+1 TO BPT3:PRINT B$(I,I);:NEXT I
2100 IF BPT4=0 THEN RETURN
2110 POSITION 1,7:FOR I=BPT3+1 TO BPT4:PRINT B$(I,I);:NEXT I
2120 PRINT " "
2130 RETURN
3020 REM SEARCH CRYPTO AND PUT GUESS IN REPLACEMENT STRING, UPDATE ALPHA$
3060 FOR I=1 TO LEN(A$):IF CH1$=A$(I,I) THEN B$(I,I)=CH2$
3070 NEXT I
3080 ALPH$="ABCDEFGHIJKLMNOPQRSTUVWXYZ"
3090 FOR I=1 TO LEN(A$):CH1$=B$(I,I):IF CH1$<>" " THEN T=ASC(CH1$)-ASC("A")+1:ALPH$(T,T)=" "
3100 NEXT I
3110 RETURN
10090 BPT1=0:BPT2=0:BPT3=0:BPT4=0:REM BPTn IS THE BREAK POINT FOR EACH LINE
10100 IF LEN(A$)<38 THEN BPT1=LEN(A$):RETURN :REM CHECK FOR A$ LESS THAN 1 LINE LONG
10110 FOR I=38 TO 20 STEP -1:IF A$(I,I)=" " THEN 10130
10120 NEXT I
10130 BPT1=I
10140 IF LEN(A$)<BPT1+38 THEN BPT2=LEN(A$):RETURN
10150 FOR I=BPT1+38 TO BPT1+20 STEP -1:IF A$(I,I)=" " THEN 10170
10160 NEXT I
10170 BPT2=I
10180 IF LEN(A$)<BPT2+38 THEN BPT3=LEN(A$):RETURN
10190 FOR I=BPT2+38 TO BPT2+20 STEP -1:IF A$(I,I)=" " THEN 10210
10200 NEXT I
10210 BPT3=I
10220 IF LEN(A$)<BPT3+38 THEN BPT4=LEN(A$):RETURN
10230 FOR I=BPT3+38 TO BPT3+20 STEP -1:IF A$(I,I)=" " THEN 10250
10240 NEXT I
10250 BPT4=I
10260 RETURN
