Biorhythm predictor, source unknown? (BIORYTHM.BAS)
Biorhythm predictor, source unknown?
Description
Biorhythm predictor, source unknown?
From the Antic disk of July 1985 (Vol. 4 No. 3).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 7.8 KB
- Dialect
- Atari BASIC
- Lines
- 134
- Variables
FQ(,LI$,ML$,M(,H$,I,DX,J$,N$,Q$,J,WEIRD,CH$,D$,P,S,Z(,P$,Y1,M2,L1,M1,D1,X,M,Y2,L2,D2,D,K,L,N,Z1,Z2,Z3,Z4,W,B,L3,NJ,Y,K$,LN,L1ANDB,KD,L3ANDB,KDAYS,OK,YES,A$,X$,TD$,T9$,M9,D9,Y9,T9,D9$,I$,THEN
BASIC listing (134 lines)
6 DIM FQ(3),LI$(3),ML$(48),M(12),N$(30),Q$(31),H$(8),J$(48),CH$(1),D$(15),Z(5),P$(5),K$(30),A$(1),TD$(8),T9$(8),D9$(3)
7 POKE 82,0:SETCOLOR 4,9,4
8 PRINT "↰":GOSUB 8800:H$="I'M PAL.":GOSUB 7000
40 ? "↰↓I FORGET TODAY'S DATE, ";Q$;".":? "↓WOULD YOU PLEASE TELL ME BY ENTERING"
70 ? "↓THE DATE (USE THE FORM 3/24/82)?↓"
80 GOSUB 8000:IF LEN(D$)>1 THEN TD$=D$(1,LEN(D$)-1)
90 IF I<>3 THEN P$="DATE":GOTO 300
205 IF Z(3)<82 OR Z(3)>99 THEN P$="YEAR":GOTO 300
206 Y1=Z(3):IF Y1/4=INT(Y1/4) THEN M(2)=29:L1=1
210 IF Z(1)<1 OR Z(1)>12 THEN P$="MONTH":GOTO 300
220 M1=Z(1):IF Z(2)<1 OR Z(2)>M(M1) THEN P$="DAY":GOTO 300
240 D1=Z(2):GOTO 400
300 GOSUB 8100:? :? "TODAY'S DATE";:GOTO 80
400 ? :? "↰THANK YOU, ";Q$;"."
410 ? :? "NOW I'M GOING TO TELL YOU SOME":? :? "INFORMATION YOU PROBABLY DON'T KNOW."
414 ? :? "FIRST OF ALL, ";Q$;",":? :? "WOULD YOU PLEASE ENTER THE DATE YOU":? :? "WERE BORN";
420 GOSUB 8000:IF I<>3 THEN P$="DATE":GOTO 500
435 IF Z(3)<1 OR Z(3)>=Y1 THEN P$="YEAR":GOTO 500
436 Y2=Z(3):M(2)=28:IF Y2/4=INT(Y2/4) THEN M(2)=29:L2=1
440 IF Z(1)<1 OR Z(1)>12 THEN P$="MONTH":GOTO 500
450 M2=Z(1):IF Z(2)<1 OR Z(2)>M(M2) THEN P$="DAY":GOTO 500
490 D2=Z(2):GOTO 600
500 GOSUB 8100:? :? "YOUR BIRTHDATE";:GOTO 420
600 POKE 752,1:? "↰↓WAIT A BIT WHILE I DO SOME CALCULATING.";:DX=5:GOSUB 8200
610 D=0:I=Y2+1
620 IF I>Y1-1 THEN 680
630 D=D+365:IF I/4=INT(I/4) THEN D=D+1
660 I=I+1:GOTO 620
680 I=M2+1
690 IF I>12 THEN 730
695 M(2)=28:IF L2 THEN M(2)=29
700 D=D+M(I):I=I+1:GOTO 690
730 I=1
740 IF I>M1-1 THEN 770
745 M(2)=28:IF L1 THEN M(2)=29
750 D=D+M(I):I=I+1:GOTO 740
770 M(2)=28:IF L2 THEN M(2)=29
780 D=D+(M(M2)-D2):D=D+D1
810 K=INT(0.6+1/M2):L=Y2-K:N=M2+12*K:P=L/100:Z1=INT(P/4):Z2=INT(P):Z3=INT(5*L/4):Z4=INT(13*(N+1)/5):W=Z4+Z3+Z2+Z1+D2-1
811 W=W-7*INT(W/7)+1
915 IF M1=M2 THEN IF D1<=D2 THEN B=D2-D1:GOTO 1110
918 M(2)=28:IF L1 THEN M(2)=29
920 B=(M(M1)-D1)+D2:IF M1>=M2 THEN X=12
923 IF M2=2 AND D2=29 THEN B=B-1
925 IF M1<M2 THEN X=0
930 I=M1+1:L3=((Y1+1)/4=INT((Y1+1)/4))
940 IF I<=12 THEN 950
944 I=1:X=0:M(2)=28:IF L3 THEN M(2)=29
950 IF I-X>M2-1 THEN 1110
960 B=B+M(I):I=I+1:GOTO 940
1110 GOSUB 3000
1116 ? "↰";:IF B=0 THEN 1200
1130 IF B<=30 THEN 1300
1140 IF B>=335 THEN 1400
1150 GOTO 1501
1200 GOSUB 4900:? "↓CONGRATULATIONS...TODAY'S":? "↓YOUR BIRTHDAY, ";Q$;"!!!":GOTO 1500
1300 IF B<>1 THEN 1350
1310 ? "↓TOMORROW'S YOUR BIRTHDAY, ";Q$;".":? "↓I HOPE YOU HAVE A VERY HAPPY ONE!":GOTO 1500
1350 ? "YOUR BIRTHDAY'S COMING UP IN JUST ";B:? "↓DAYS, ";Q$;". I WANT TO":? "↓WISH YOU A HAPPY BIRTHDAY!":GOTO 1500
1400 GOSUB 4900:IF B<364 THEN 1440
1405 IF (L1) AND (B=364) AND (M2<3) THEN KD=366:GOTO 1450
1407 IF (L3) AND (B=364) AND (M2>2) THEN KD=366:GOTO 1450
1410 ? "↓YESTERDAY WAS YOUR BIRTHDAY, ":? :? Q$;"! I MISSED IT. LET ME":? "↓WISH YOU A BELATED HAPPY BIRTHDAY!!!":GOTO 1500
1440 KD=365
1450 ? "↓YOU BIRTHDAY WAS JUST ";KD-B;" DAYS AGO,":? "↓";Q$;" - "
1455 ? "↓I'M SORRY I MISSED IT! PLEASE ACCEPT":? "↓MY BELATED HAPPY BIRTHDAY!!!"
1500 DX=5:GOSUB 8200
1501 ? "↰":POSITION 11,9:? "S O L O N G ,":POSITION (37-LEN(Q$))/2,11:? Q$;" ! ! !"
1502 DX=3:GOSUB 8200:? "↰";:POKE 752,0:GOSUB 13000
1640 ? :? "DO ANY OF YOUR FRIENDS WANT TO KNOW":? :? "HOW MANY DAYS OLD THEY ARE";:GOSUB 1700:IF NOT OK THEN 1640
1660 IF NOT YES THEN 1800
1670 H$="":GOSUB 7000:? :? "NICE MEETING YOU, ";Q$;".":GOTO 410
1700 YES=0:OK=1:INPUT A$:IF LEN(A$)=0 THEN 1715
1705 IF A$(1,1)="Y" THEN YES=1:RETURN
1710 IF A$(1,1)="N" THEN RETURN
1715 ? :? "PLEASE ANSWER YES OR NO.":? :OK=0:RETURN
1800 ? "↰":? "NICE CHATTING WITH YOU, ";Q$;".":? :? "HAVE A GREAT DAY TODAY AND A BETTER DAY":? :? "TOMORROW!!"
1820 ? :? :? "THIS IS PAL SAYING,":? :? :? " '' S O L O N G ! ! ! '' ":? :? :POKE 752,0:END
3000 ? "↰";
3010 L=LEN(N$):I=(40-2*L)/2:IF L>20 THEN I=(40-L)/2
3014 FOR NJ=1 TO I:? " ";:NEXT NJ:IF L>20 THEN ? N$;:GOTO 3020
3018 FOR I=1 TO L:? N$(I,I);" ";:NEXT I
6000 ? "↰NOW, ";Q$;",":? "↓LET'S LOOK AT YOUR BIORHYTHM FOR THE"
6012 ? "↓NEXT FEW WEEKS. IT WILL SHOW YOU A":? "↓PICTURE OF YOUR PHYSICAL, EMOTIONAL,"
6014 ? "↓AND INTELLECTUAL STATES.":? :? :? "PRESS THE SPACE BAR TO START.":GOSUB 13000
6015 GET #2,I:IF I<>32 THEN 6015
6030 GOSUB 10000:RETURN
7000 ? :? "HI... ";H$:GOSUB 13000
7020 ? :? "WHAT'S YOUR NAME";:INPUT N$
7030 Q$=N$:Q$(LEN(Q$)+1)=" ":J=-1:FOR I=0 TO 1:J=J+1:I=ASC(Q$(J+1))=32:NEXT I
7040 IF J=0 THEN ? :? "I DIDN'T QUITE GET THAT...":GOTO 7020
7045 Q$=N$(1,J):WEIRD=0
7051 FOR I=1 TO LEN(N$):CH$=N$(I,I):IF NOT ((CH$>="A") AND (CH$<="Z") OR (CH$=" ") OR (CH$=".")) THEN WEIRD=1
7064 NEXT I:IF NOT WEIRD THEN 7069
7065 ? :? "COME ON NOW, REALLY...":DX=1:GOSUB 8200:GOTO 7020
7069 REM IF LEN(Q$)=1 THEN Q$(2)=" "
7070 RETURN
8000 INPUT D$:IF LEN(D$)<5 THEN RETURN
8005 IF LEN(D$)>14 THEN D$=D$(1,14)
8006 D$(LEN(D$)+1)="/":P=0:S=1:I=0
8020 P=P+1:IF P>LEN(D$) THEN RETURN
8025 IF D$(P,P)<>"/" AND (D$(P,P)<"0" OR D$(P,P)>"9") THEN RETURN
8030 IF D$(P,P)<>"/" THEN 8020
8035 IF P<>LEN(D$) THEN IF D$(P+1,P+1)="/" OR P=1 THEN RETURN
8040 I=I+1:Z(I)=VAL(D$(S,P-1)):S=P+1:GOTO 8020
8100 ? :? "YOU ENTERED AN INCORRECT ";P$;",":? :? Q$;". PLEASE ENTER IT AGAIN."
8120 ? :? "IT SHOULD BE ENTERED AS MONTH/DAY/YEAR,":? :? "USING NUMBERS ONLY. FOR EXAMPLE,"
8140 ? :? "MARCH 24, 1982, WOULD BE ENTERED AS":? :? "3/24/82.":RETURN
8200 FOR I=1 TO 200*DX:NEXT I:RETURN
8800 J$="MONDAY TUESDAY WEDNESDAYTHURSDAY FRIDAY SATURDAYSUNDAY"
8830 FOR I=1 TO 12:READ X:M(I)=X:NEXT I:DATA 31,28,31,30,31,30,31,31,30,31,30,31
8836 ML$="JAN.FEB.MAR.APR.MAY JUNEJULYAUG.SEP.OCT.NOV.DEC."
8840 OPEN #2,4,0,"K:":RETURN
10000 REM BIORHYTHM BY KELLY WILLIAMS
10010 FQ(1)=23:FQ(2)=28:FQ(3)=33:LI$=".+*":M9=M1:D9=D1:Y9=Y1:T9=D:T9$=TD$
10040 ? "↰ YOUR BIORHYTHMIC FORECAST FOR ";T9$
10050 M(2)=28:IF Y9/4=INT(Y9/4) THEN M(2)=29
10060 POSITION 0,10:? ML$((M9-1)*4+1,(M9-1)*4+4):FOR I=1 TO 10:D9$=STR$(100+D9):? D9$(2);"─";:IF I<>10 THEN ? "─";
10080 D9=D9+2:IF D9<=M(M9) THEN 10110
10100 D9=D9-M(M9):M9=M9+1:IF M9=13 THEN M9=1:Y9=Y9+1
10104 IF I=10 THEN 10110
10105 IF I<>9 THEN ? "↓";ML$((M9-1)*4+1,(M9-1)*4+4);"↑←←←←";:GOTO 10110
10106 ? "↓";ML$((M9-1)*4+1,(M9-1)*4+3);:? "↑←←←";
10110 NEXT I:POSITION 0,22:? "PHYSICAL.. EMOTIONAL++ INTELLECTUAL**"
10111 FOR K=1 TO 3:I=(T9/FQ(K)-INT(T9/FQ(K)))*FQ(K)*2:GOSUB 11000:NEXT K
10160 POSITION 0,23:? "PRESS E TO END BIORHYTHM OR G TO GO ON";:GOSUB 13000
10170 IF NOT (CHR$(PEEK(764))="*" OR CHR$(PEEK(764))="=") THEN 10170
10175 GET #2,P:IF CHR$(P)="E" THEN RETURN
10190 T9=T9+20:T9$(7)=" ":T9$(1)=STR$(M9):T9$(LEN(T9$)+1)="/":T9$(LEN(T9$)+1)=STR$(D9):T9$(LEN(T9$)+1)="/"
10200 T9$(LEN(T9$)+1)=STR$(Y9):GOTO 10040
11000 FOR X=0 TO 38 STEP 2:Y=10-(SIN((X+I)/2*6.2318/FQ(K))*9):IF Y>=10 THEN Y=Y+0.5
11030 POSITION X,Y+0.5:? LI$(K,K):NEXT X:RETURN
13000 IF PEEK(764)<>255 THEN GET #2,P
13100 RETURN
