Music
Atari BASIC program with 252 lines.
Description
From the Antic disk of June 1985 (Vol. 4 No. 2).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 15.2 KB
- Dialect
- Atari BASIC
- Lines
- 252
- Variables
SI,TEMPO,A,I,PITCH,SONG$,C1,C2,C3,SUST,C0,X,G,YPOS,YPO$,NT$,T$,TEMP,C,CHRBASE,PMBASE,L,CHA$,DESC$,NTFLAG,MOVEFLAG,XPOS,SHARPFLAT,NTTYPE,RFLAG,STEM1$,STEM2$,STEMFLAG$,DOT,EIGHTFLAG,D,FIRSTTIME,NX,SCALE$,SVEXPOS,SUBFL,CH$,CI,XP,SIXTH,SEVENTH,GOODCHAR,SECONDPASS,OS1,OS2,Q,FILENAME$,CH,SNAME$,P,E$,START,Z
BASIC listing (252 lines)
10 REM THE MUSICIAN
20 REM BY ANGELO GIAMBRA
30 REM (c) 1985, ANTIC PUBLISHING
40 SI=1:POKE 65,0:GOTO 2060
50 IF PEEK(20)<TEMPO THEN 50
60 A=PEEK(764):RETURN
70 FOR I=1 TO SI-1:PITCH=ASC(SONG$(I,I))
80 IF PITCH=255 THEN POKE C1,ASC(SONG$(I+1,I+1)):POKE C2,ASC(SONG$(I+2,I+2))
90 IF PITCH=255 THEN POKE C3,ASC(SONG$(I+3,I+3)):I=I+3:NEXT I:GOTO 200
100 IF PITCH=254 THEN POKE C1,0:POKE C2,0:POKE C3,0:NEXT I
110 IF PITCH>128 THEN SUST=1:PITCH=PITCH-128:IF PITCH=125 THEN PITCH=128
120 POKE C0,PITCH:POKE 20,0:IF PITCH=0 THEN 170
130 IF X>15 THEN X=5:G=1:GOSUB 210
140 YPOS=ASC(YPO$(I,I)):IF YPOS>131 AND YPOS<147 THEN YPOS=YPOS-128:POSITION X,YPOS:? #6;"♣":X=X+1
150 IF YPOS>203 AND YPOS<219 THEN YPOS=YPOS-200:POSITION X,YPOS:? #6;"b":X=X+1
160 POSITION X,YPOS:? #6;NT$:POSITION X,YPOS-1:? #6;"▕":POSITION X,YPOS-2:? #6;"▕":X=X+2
170 TEMPO=ASC(T$(I,I))*TEMP:GOSUB 50:IF SUST OR PITCH=0 THEN SUST=0:NEXT I:GOTO 200
180 IF A<>255 THEN POKE 764,255:IF A=28 THEN I=SI
190 POKE 53760,0:NEXT I
200 G=0:POKE C1,0:POKE C2,0:POKE C3,0:POKE C0,0:SUST=0:RETURN
210 POKE 53277,0:NT$="●":X=3:SETCOLOR 4,0,0:C=1:SETCOLOR 0,7,4
220 SETCOLOR 1,1,4:SETCOLOR 2,54,4:GRAPHICS 17:POKE 559,46:POKE 53277,3
230 POKE 16,112:POKE 53774,112
240 POKE 756,CHRBASE/256:POSITION 7,0:? #6;"play"
250 POKE 53761,170:POKE 53763,168:POKE 53765,168:POKE 53767,168:POKE 53768,0:POKE 53775,3:IF G THEN RETURN
260 POKE 53254,60:POKE 53255,188:POKE 53260,0:POKE 54279,PMBASE:FOR L=704 TO 707:POKE L,68:NEXT L
270 FOR L=53256 TO 53259:POKE L,3:NEXT L:POKE 53248,60:POKE 53249,92:POKE 53250,124:POKE 53251,156:GOTO 70
280 INPUT #1,TEMP:INPUT #1,SI
290 FOR I=1 TO SI:INPUT #1,CHA$:SONG$(I,I)=CHA$:NEXT I
300 FOR I=1 TO SI:INPUT #1,CHA$:T$(I,I)=CHA$:NEXT I:FOR I=1 TO SI
310 INPUT #1,CHA$:YPO$(I,I)=CHA$:NEXT I:SI=SI+1:POKE 53762,0:POKE 53764,0:POKE 53768,0:RETURN
320 POSITION 4,22:? #6;" ";DESC$;" ":NTFLAG=0:RETURN
330 IF MOVEFLAG THEN POSITION XPOS-1,YPOS:GOTO 360
340 IF SUST THEN POSITION XPOS,YPOS+2:? #6;" "
350 POSITION XPOS,YPOS-2:? #6;" ":POSITION XPOS,YPOS
360 IF SHARPFLAT=3 THEN ? #6;"╱"
370 IF SHARPFLAT=1 THEN ? #6;"♣"
380 IF SHARPFLAT=2 THEN ? #6;"b"
390 IF MOVEFLAG THEN RETURN
400 MOVEFLAG=1:XPOS=XPOS+1:RETURN
410 IF SHARPFLAT THEN GOSUB 330
420 POSITION XPOS,YPOS+1:? #6;" ":POSITION XPOS,YPOS-3
430 ? #6;" ":POSITION XPOS+1,YPOS+1:? #6;" ":POSITION XPOS+1,YPOS-3:? #6;" "
440 IF SHARPFLAT THEN POSITION XPOS-1,YPOS+1:? #6;" ":POSITION XPOS-1,YPOS-1:? #6;" "
450 IF SUST THEN POSITION XPOS,YPOS+3:? #6;" "
460 POSITION XPOS,YPOS:? #6;NT$;" "
470 IF NTTYPE<>1 AND RFLAG=0 THEN POSITION XPOS,YPOS-1:? #6;STEM1$;" ":POSITION XPOS,YPOS-2:? #6;STEM2$;" "
480 IF NTTYPE=8 OR NTTYPE=6 OR NTTYPE=3 THEN POSITION XPOS+1,YPOS-2:? #6;STEMFLAG$
490 IF NTTYPE=6 OR NTTYPE=3 THEN POSITION XPOS+1,YPOS-1:? #6;STEMFLAG$
500 IF NTTYPE=3 THEN POSITION XPOS+1,YPOS:? #6;STEMFLAG$
510 IF DOT=1 THEN POSITION XPOS+1,YPOS:? #6;"▘"
520 IF SUST THEN POSITION XPOS,YPOS+2:? #6;"s"
530 IF RFLAG OR NTTYPE=1 THEN POSITION XPOS,YPOS-1:? #6;" ":POSITION XPOS,YPOS-2:? #6;" "
540 GOTO 320
550 REM POLL JOYSTICK
560 A=STICK(0):IF A=15 OR RFLAG THEN 590
570 IF A=14 THEN IF YPOS>4 THEN YPOS=YPOS-1:GOSUB 410:GOTO 550
580 IF A=13 THEN IF YPOS<18 THEN YPOS=YPOS+1:GOSUB 410:GOTO 550
590 A=PEEK(764):IF A<>255 THEN POKE 764,255:GOTO 620
600 IF STRIG(0)=0 THEN 1020
610 GOTO 550
620 IF A=42 THEN POSITION 4,22:? #6;"exit y or n":GOSUB 2490:GOTO 550
630 IF A=46 THEN NT$=CHR$(239):NTTYPE=1:DESC$="whole":RFLAG=0:GOTO 900
640 IF A=8 THEN SONG$(SI,SI)=CHR$(254):SI=SI+1:POSITION 4,22:? #6;"chord off ":GOTO 550
650 IF A=18 THEN 1780
660 IF A=45 THEN GOSUB 1670:GOTO 550
670 IF A=63 THEN GOSUB 1900:GOTO 1970
680 IF A=0 THEN GOSUB 1900:GOTO 2010
690 IF A=57 THEN NT$=CHR$(239):NTTYPE=2:DESC$="half":RFLAG=0:GOTO 870
700 IF A=40 THEN 940
710 IF A=47 THEN NT$=CHR$(148):NTTYPE=4:DESC$="quarter":RFLAG=0:GOTO 870
720 IF A=53 THEN NTTYPE=8:STEMFLAG$=CHR$(224):DESC$="eighth":EIGHTFLAG=1:RFLAG=0:NT$=CHR$(148):GOTO 900
730 IF A=27 THEN NTTYPE=6:STEMFLAG$=CHR$(224):DESC$="sixteenth":RFLAG=0:EIGHTFLAG=1:NT$=CHR$(148):GOTO 900
740 IF A=26 THEN NTTYPE=3:STEMFLAG$=CHR$(224):DESC$="thirty sec":RFLAG=0:EIGHTFLAG=1:NT$=CHR$(148):GOTO 900
750 IF A=34 THEN DOT=1:GOTO 900
760 IF A=7 THEN GOSUB 1270:GOTO 550
770 IF A=62 THEN SUST=1:GOTO 900
780 IF A=54 THEN SI=1:FOR I=1 TO 3:SOUND 0,15,10,10:FOR D=1 TO 8:NEXT D:SOUND 0,0,0,0:NEXT I
790 POSITION 4,22:? #6;"song cleared":GOTO 810
800 GOTO 820
810 FOR I=1 TO 300:NEXT I:FIRSTTIME=0:GOTO 2120
820 IF A=21 THEN SHARPFLAT=2:GOTO 900
830 IF A=90 THEN SHARPFLAT=1:GOTO 900
840 IF A=10 THEN GOSUB 210:FIRSTTIME=0:GOTO 2120
850 IF A=7 THEN GOSUB 550:GOTO 900
860 IF A=35 THEN SHARPFLAT=3:GOTO 900
870 IF EIGHTFLAG THEN POSITION XPOS+1,YPOS-2:? #6;" ":POSITION XPOS+1,YPOS-1:? #6;" "
880 IF NOT DOT THEN POSITION XPOS+1,YPOS:? #6;" "
890 GOSUB 410:GOTO 550
900 IF NTTYPE<>1 THEN GOSUB 410:GOTO 550
910 POSITION XPOS,YPOS-2:? #6;" ":POSITION XPOS,YPOS-1:? #6;" ":IF EIGHTFLAG THEN POSITION XPOS+1,YPOS-2:? #6;" "
920 IF EIGHTFLAG THEN POSITION XPOS+1,YPOS-1:? #6;" ":IF NOT DOT THEN POSITION XPOS+1,YPOS:? #6;" "
930 GOSUB 410:GOTO 550
940 IF NTTYPE=4 THEN NT$="◣"
950 IF NTTYPE=8 THEN NT$="◢":NTTYPE=9
960 IF NTTYPE=2 THEN NT$="▄"
970 RFLAG=1:IF YPOS=12 THEN GOSUB 410:GOTO 550
980 IF YPOS>11 THEN 1010
990 IF YPOS<11 THEN FOR YPOS=YPOS TO 11 STEP 1:GOSUB 410:NEXT YPOS
1000 GOTO 550
1010 FOR YPOS=YPOS TO 13 STEP -1:GOSUB 410:NEXT YPOS:GOTO 550
1020 NX=(YPOS=4)*4+(YPOS=5)*7+(YPOS=6)*13+(YPOS=7)*19+(YPOS=8)*25+(YPOS=9)*28+(YPOS=10)*34+(YPOS=11)*40
1030 NX=NX+(YPOS=12)*43+(YPOS=13)*49+(YPOS=14)*55+(YPOS=15)*61+(YPOS=16)*64+(YPOS=17)*70+(YPOS=18)*76
1040 IF SHARPFLAT=1 THEN NX=NX-3
1050 IF SHARPFLAT=2 THEN NX=NX+3
1060 IF SHARPFLAT=3 THEN SHARPFLAT=0
1070 IF RFLAG THEN SOUND 0,10,8,10:GOTO 1090
1080 SOUND 0,VAL(SCALE$(NX,NX+2)),10,10
1090 FOR I=1 TO 50:NEXT I:SOUND 0,0,0,0:TEMPO=100:IF DOT THEN T$(SI+1,SI+1)="."
1100 TEMPO=120*(NTTYPE=1)+60*(NTTYPE=2)+30*(NTTYPE=4)+15*(NTTYPE=8)+7*(NTTYPE=6)+3*(NTTYPE=3)
1110 IF DOT THEN TEMPO=TEMPO*1.5
1120 PITCH=VAL(SCALE$(NX,NX+2)):IF SUST THEN PITCH=PITCH+128:IF PITCH=256 THEN PITCH=253
1130 SONG$(SI)=CHR$(PITCH):T$(SI,SI)=CHR$(TEMPO)
1140 IF RFLAG THEN SONG$(SI)=CHR$(0):DOT=0:SUST=0:DESC$="quarter":NTTYPE=4
1150 YPO$(SI,SI)=CHR$(YPOS):IF SHARPFLAT=1 THEN YPO$(SI,SI)=CHR$(ASC(YPO$(SI,SI))+128)
1160 IF SHARPFLAT=2 THEN YPO$(SI,SI)=CHR$(ASC(YPO$(SI,SI))+200)
1170 REM MAKE NEW NOTE
1180 SI=SI+1:POSITION 3,0:IF NT$=CHR$(148) THEN NT$="●"
1190 IF NT$=CHR$(239) THEN NT$="o"
1200 STEM1$="▕":STEM2$="▕":STEMFLAG$="◆":IF FIRSTTIME=0 THEN FIRSTTIME=1:GOTO 1220
1210 GOSUB 410:TRAP 40000:IF RFLAG THEN NT$="●":RFLAG=0
1220 MOVEFLAG=0:SVEXPOS=XPOS:XPOS=XPOS+2:IF XPOS>15 THEN SUBFL=1:XPOS=3:GOSUB 2130
1230 IF SVEXPOS=1 THEN SVEXPOS=3
1240 STEM1$=CHR$(130):STEM2$=CHR$(130):STEMFLAG$=CHR$(224):IF NT$="●" THEN NT$=CHR$(148)
1250 IF NT$="o" THEN NT$=CHR$(239)
1260 DOT=0:SUST=0:GOSUB 410:GOTO 550
1270 POSITION 2,22:? #6;" enter chord ":POSITION 2,23:? #6;"then press return"
1280 FOR I=1 TO 3:SOUND 0,15,10,10:FOR D=1 TO 6:NEXT D:SOUND 0,0,0,0:NEXT I
1290 CH$=" ":OPEN #1,4,0,"K:":POKE 702,0:CI=1:XP=XPOS-1
1300 A=PEEK(764):IF A=255 THEN 1300
1310 GET #1,A:POKE 764,255:IF A=155 THEN 1470
1320 IF CI=6 THEN 1300
1330 CH$(CI,CI)=CHR$(A)
1340 IF CHR$(A)="6" THEN CH$(CI,CI)="▎":SIXTH=1
1350 IF CHR$(A)="7" THEN CH$(CI,CI)="┬":SEVENTH=1
1360 CHA$=CH$(CI,CI)
1370 IF CHA$="+" THEN CHA$=CHR$(19):GOODCHAR=1
1380 IF CHA$="-" THEN CHA$=CHR$(18):GOODCHAR=1
1390 IF CHA$="#" THEN CHA$=CHR$(16):GOODCHAR=1
1400 IF CHA$="*" THEN CLOSE #1:POSITION XPOS-1,20:? #6;" ":SECONDPASS=0:GOTO 1630
1410 IF CHA$="a" OR CHA$="b" OR CHA$="c" OR CHA$="d" OR CHA$="e" OR CHA$="f" OR CHA$="g" THEN 1450
1420 IF (CHA$="m" OR CHA$="j") AND SECONDPASS THEN 1460
1430 IF (GOODCHAR OR SIXTH OR SEVENTH) AND SECONDPASS THEN 1460
1440 GOTO 1300
1450 SECONDPASS=1
1460 POSITION XP,20:? #6;CHA$:GOODCHAR=0:CI=CI+1:XP=XP+1:GOTO 1300
1470 CLOSE #1:POKE 702,64:SECONDPASS=0:CHA$=CH$(1,1)
1480 NX=112*(CHA$="c")+106*(CHA$="d")+100*(CHA$="e")+97*(CHA$="f")+91*(CHA$="g")+85*(CHA$="a")+79*(CHA$="b")
1490 IF CI=2 THEN OS1=12:OS2=21:GOTO 1610
1500 OS1=12:OS2=21:CI=2:IF CH$(2,2)="#" THEN NX=NX-3:CI=3
1510 IF CH$(2,2)="b" THEN NX=NX+3:CI=3
1520 IF SIXTH THEN SIXTH=0:OS2=27
1530 IF SEVENTH THEN SEVENTH=0:OS2=30
1540 IF CH$(CI,CI)="+" THEN OS2=24
1550 IF CH$(CI,CI)="d" THEN OS1=9:OS2=18
1560 IF CH$(CI,CI)="-" THEN OS1=12:OS2=18
1570 IF CH$(CI,CI)="m" THEN IF CH$(CI+1,CI+1)=" " THEN OS1=9:OS2=21
1580 IF CH$(CI,CI)="m" THEN IF CH$(CI+1,CI+2)="aj" THEN OS1=12:OS2=33
1590 IF CH$(CI,CI)="m" THEN IF CH$(CI+1,CI+1)="┬" THEN OS1=9:OS2=30
1600 IF CH$(CI,CI)="m" THEN IF CH$(CI+1,CI+1)="▎" THEN OS1=9:OS2=27
1610 SONG$(SI,SI)=CHR$(255):SONG$(SI+1,SI+1)=CHR$(VAL(SCALE$(NX,NX+2)))
1620 SONG$(SI+2,SI+2)=CHR$(VAL(SCALE$(NX-OS1,NX-OS1+2))):SONG$(SI+3,SI+3)=CHR$(VAL(SCALE$(NX-OS2,NX-OS2+2)))
1630 SIXTH=0:SEVENTH=0:SI=SI+4:POSITION 2,22:? #6;" ":POSITION 2,23:? #6;" "
1640 POSITION 7,22:? #6;DESC$:IF CHA$="*" THEN RETURN
1650 SOUND 0,ASC(SONG$(SI-3,SI-3)),10,10:SOUND 1,ASC(SONG$(SI-2,SI-2)),10,10:SOUND 2,ASC(SONG$(SI-1,SI-1)),10,10
1660 FOR I=1 TO 20:NEXT I:SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,0,0,0:RETURN
1670 FOR I=1 TO 3:SOUND 0,15,10,10:FOR Q=1 TO 6:NEXT Q:SOUND 0,0,0,0:NEXT I
1680 POSITION 5,20:? #6;"change tempo":POSITION 5,22:? #6;" "
1690 POSITION 8,22:? #6;CHR$(243);CHR$(236);CHR$(239);CHR$(247);CHR$(229);CHR$(242):TEMPO=0.25
1700 A=STICK(0)
1710 IF A=14 THEN POSITION 8,22:? #6;CHR$(230);CHR$(225);CHR$(243);CHR$(244);CHR$(229);CHR$(242)
1720 TEMPO=-0.25:GOTO 1700
1730 IF A=13 THEN 1690
1740 IF STRIG(0)=0 THEN 1760
1750 GOTO 1700
1760 TEMP=TEMP+TEMPO:FOR I=1 TO 3:SOUND 0,15,10,10:FOR Q=1 TO 6:NEXT Q:SOUND 0,0,0,0:NEXT I
1770 POSITION 5,20:? #6;" ":POSITION 4,22:? #6;" ";DESC$;" ":RETURN
1780 SI=SI-1:FOR I=1 TO 3:SOUND 0,15,10,10:FOR D=1 TO 8:NEXT D
1790 SOUND 0,0,0,0:NEXT I:POSITION 7,22:? #6;"cancelled"
1800 POSITION XPOS,YPOS-2:? #6;" ":POSITION XPOS,YPOS-1:? #6;" ":POSITION XPOS,YPOS:? #6;" "
1810 IF SHARPFLAT THEN POSITION XPOS-1,YPOS:? #6;" "
1820 IF SUST THEN POSITION XPOS,YPOS+2:? #6;" "
1830 XPOS=SVEXPOS:IF SI<1 THEN SI=1
1840 IF SI<4 THEN 550
1850 IF ASC(SONG$(SI-3,SI-3))=255 THEN SI=SI-4:POSITION 3,22:? #6;"chord cancelled"
1860 FOR I=1 TO 100:NEXT I:POSITION 3,22:? #6;" "
1870 GOTO 550
1880 IF T$(SI,SI)="4" OR T$(SI,SI)="6" OR T$(SI,SI)="8" OR T$(SI,SI)="3" THEN STEMFLAG$="\"
1890 GOSUB 320
1900 GRAPHICS 18:POKE 53277,0:POKE 559,34:? #6;" ENTER SONG NAME"
1910 OPEN #1,4,0,"K":FILENAME$="D:":I=3:? #6:? #6:? #6;" ";
1920 POKE 16,112:POKE 53774,112
1930 GET #1,CH:IF CH=155 THEN CLOSE #1:RETURN
1940 IF CH=126 THEN POSITION (PEEK(85)-1),(PEEK(84)):? #6;" ";:POSITION (PEEK(85)-1),(PEEK(84)):I=I-1:GOTO 1930
1950 IF CHR$(CH)<"A" OR CHR$(CH)>"Z" THEN 1930
1960 FILENAME$(I)=CHR$(CH):? #6;CHR$(CH+128);:I=I+1:GOTO 1930
1970 IF LEN(FILENAME$)=2 THEN OPEN #1,8,0,"C:":FOR I=1 TO 128:PUT #1,CH:NEXT I:GOTO 1990
1980 OPEN #1,8,0,FILENAME$
1990 ? #1;TEMP:? #1;SI-1:FOR I=1 TO SI-1:CHA$=SONG$(I):? #1;CHA$:NEXT I:FOR I=1 TO SI-1:CHA$=T$(I)
2000 ? #1;CHA$:NEXT I:FOR I=1 TO SI-1:CHA$=YPO$(I):? #1;CHA$:NEXT I:CLOSE #1:FIRSTTIME=0:GOTO 2120
2010 FIRSTTIME=0:TRAP 2040
2020 IF LEN(FILENAME$)=2 THEN OPEN #1,4,0,"C:":FOR I=1 TO 128:GET #1,CH:NEXT I:GOTO 2050
2030 OPEN #1,4,0,FILENAME$:GOTO 2050
2040 CLOSE #1:GOTO 2120
2050 SI=1:NT$="●":GOSUB 280:CLOSE #1:GOSUB 210:FIRSTTIME=0:GOTO 2120
2060 REM INITIALIZE SCREEN
2070 DIM NT$(1),STEM1$(1),STEM2$(1),SONG$(1000),T$(1000),YPO$(1000),SNAME$(12),FILENAME$(12)
2080 DIM SCALE$(117),STEMFLAG$(1),DESC$(15):DESC$="quarter":DIM CH$(5),CHA$(1)
2090 SCALE$="028029031033035037040042045047050053057060064068072076081085091096102108114121128136144153162173182"
2100 SCALE$(100)="193204217230243255":GOSUB 2200:TEMP=1
2110 C0=53760:C1=53762:C2=53764:C3=53766
2120 NT$="●":STEM1$="▕":STEM2$="▕":NTTYPE=4:DESC$="quarter":YPOS=12:XPOS=1
2130 POKE 53277,0:GRAPHICS 17:SETCOLOR 0,0,0:POKE 756,INT(CHRBASE/256):POSITION 3,0:? #6;"the musician"
2140 POKE 16,112:POKE 53774,112
2150 POSITION 7,22:? #6;DESC$:POKE 559,46:POKE 53277,3:POKE 53254,60:POKE 53255,188:POKE 53260,0:POKE 623,4
2160 FOR I=CHRBASE TO CHRBASE+7:POKE I,0:NEXT I:FOR L=704 TO 707:POKE L,120:NEXT L
2170 FOR L=53256 TO 53259:POKE L,3:NEXT L:POKE 53248,60:POKE 53249,92:POKE 53250,124:POKE 53251,156
2180 IF SUBFL THEN SUBFL=0:RETURN
2190 GOTO 1190
2200 GRAPHICS 17:P=57856:PMBASE=INT(((PEEK(106)-12)*256)/1024)*1024
2210 CHRBASE=INT((((PEEK(106)-16)*256)/1024-1))*1024
2220 POKE 16,112:POKE 53774,112
2230 FOR I=1 TO 15:POSITION 3,I:? #6;"the musician":NEXT I:? #6:? #6:? #6;" rev.1.0"
2240 DIM E$(76):FOR I=1 TO 76:READ A:E$(I,I)=CHR$(A):NEXT I
2250 DATA 104,104,133,193,104,133,192,104,133,197,104,133
2260 DATA 196,169,226,133,195,169,0,133,194,160,0,162,0,177,194,145
2270 DATA 192,200,192,0,208,247,232,224,5,240,10,230,193,230
2280 DATA 195,160,0,169,0,240,232,162,0,160,0,169,0,145,196,200
2290 DATA 192,0,208,249,232,224,5,240,8,160,0,230,197,169,0,240,236,96
2300 X=USR(ADR(E$),CHRBASE,PMBASE):P=57344+176:FOR I=CHRBASE+176 TO CHRBASE+183:POKE I,PEEK(P):P=P+1:NEXT I
2310 P=57344+184:FOR I=CHRBASE+184 TO CHRBASE+191:POKE I,PEEK(P):P=P+1:NEXT I
2320 P=57344+24:FOR I=CHRBASE+128 TO CHRBASE+135:POKE I,PEEK(P):P=P+1:NEXT I:P=57344+112
2330 FOR I=CHRBASE+96 TO CHRBASE+103:POKE I,PEEK(P):P=P+1:NEXT I:P=57344+480
2340 FOR I=CHRBASE+256 TO CHRBASE+263:POKE I,PEEK(P):P=P+1:NEXT I
2350 FOR I=CHRBASE+80 TO CHRBASE+87:READ A:POKE I,A:NEXT I:FOR I=CHRBASE+64 TO CHRBASE+71:READ A:POKE I,A:NEXT I
2360 FOR I=CHRBASE+48 TO CHRBASE+55:READ A:POKE I,A:NEXT I
2370 START=PMBASE:PMBASE=PMBASE/256
2380 FOR I=START+384+49 TO START+384+81:POKE I,240:NEXT I
2390 FOR I=START+512+49 TO START+640-41 STEP 8:POKE I,255:FOR Z=I+1 TO I+7:POKE Z,0:NEXT Z:NEXT I
2400 FOR I=START+640+49 TO START+768-41 STEP 8:POKE I,255:FOR Z=I+1 TO I+7:POKE Z,0:NEXT Z:NEXT I
2410 FOR I=START+768+49 TO START+896-41 STEP 8:POKE I,255:FOR Z=I+1 TO I+7:POKE Z,0:NEXT Z:NEXT I
2420 FOR I=START+896+49 TO START+1024-41 STEP 8:POKE I,255:FOR Z=I+1 TO I+7:POKE Z,0:NEXT Z:NEXT I
2430 POKE 15,INT(CHRBASE/256):A=CHRBASE-(INT(CHRBASE/256)*256):POKE 14,A
2440 POKE 54279,PMBASE:POKE 559,46:POKE 53277,3
2450 POKE 53760,0:RETURN
2460 DATA 48,24,28,48,24,28,48,24
2470 DATA 48,62,4,8,8,16,16,32
2480 DATA 0,36,44,52,36,44,52,4
2490 A=PEEK(764):IF A=255 THEN 2490
2500 POKE 764,255:IF A<>43 THEN POSITION 4,22:? #6;" ":RETURN
2510 FOR I=1 TO 20:NEXT I
2520 X=USR(58484)
