Color Inkle Loom (INKLLOOM.BAS)

Color Inkle Loom by Gerald M. Hagopian, 67

Description

Color Inkle Loom by Gerald M. Hagopian, 67

From the Antic disk of June 1985 (Vol. 4 No. 2).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 8.1 KB

Dialect
Atari BASIC
Lines
174
Variables
ANS$, CL$, CL1$, SB$, SB1$, CR$, X, A, B, K, H, Y, ET, T, CL, T2, CL1, R, I, V, LG, DL, L, S, ADDRES, P, D, SCRN, Z, MODE, IO, JNK, U, WEAV$, AD, MOV, FROM, TU, N, ADX, ADHI, ADLO, LOD
BASIC listing (174 lines)
10 REM COLOR INKLE LOOM
20 REM GERALD M. HAGOPIAN
30 REM (c) 1985, ANTIC PUBLISHING
40 DIM ANS$(3),CL$(40),CL1$(40),SB$(1),SB1$(1),CR$(1),WEAV$(7684)
50 WEAV$(1)="♥":WEAV$(7684)=WEAV$:WEAV$(2)=WEAV$:ADX=ADR(WEAV$)
60 LOD=0
70 GOSUB 820:GOTO 980
80 GOSUB 930
90 SCRN=PEEK(88)+PEEK(89)*256
100 X=0:A=1:B=3
110 IF LOD THEN JNK=USR(ADR("hh┐qh┐ph┐Uh┐Th┐oh┐n ♥1p┌TfTP▕fUfpP▕fqFnPjFo♣f◆"),ADX,SCRN,7680)
120 IF LOD THEN POKE 712,ASC(WEAV$(7681,7681))
130 IF LOD THEN FOR Y=708 TO 710:POKE Y,ASC(WEAV$(Y+6974,Y+6974)):NEXT Y:GOTO 150
140 POKE 712,8:POKE 710,34
150 FOR K=1 TO 79:COLOR K/5:SOUND 0,255-(K*2),10,8:PLOT K,150:DRAWTO K,160:NEXT K:SOUND 0,0,0,0
160 GOSUB 180:POKE 559,34
170 GOTO 200
180 POSITION 0,0:? CHR$(125):POKE 752,1:POKE 710,34
190 ? "↑A  B C  D E  F G  H I  J K  L M  N O":RETURN
200 REM LOOM SET UP
210 CLOSE #1:OPEN #1,4,0,"K:"
220 IF LOD THEN LOD=0:GOTO 710
230 GOSUB 180:TRAP 230
235 POSITION 0,3:? "Number of threads per harness?":? "(LIMIT 39) ";:INPUT H:? :IF H<1 OR H>39 THEN 230
240 TRAP 40000:GOSUB 180
250 POSITION 0,3:? "SURE? (Y/N)     ":GET #1,K:IF K<>89 THEN 230
260 X=1:Y=0:COLOR 8:PLOT X,Y:DRAWTO H,Y:PLOT H,Y:COLOR 15:DRAWTO H*2,Y
270 REM HARNESS SET UP
280 CLOSE #1:OPEN #1,4,0,"K:":POKE 752,1
290 X=1:Y=0:ET=4
300 FOR T=1 TO H
310 GOSUB 180:POSITION 0,3:? "Harness #1: Thread # ";T:? " Color Selection?":GET #1,K:IF K<64 OR K>79 THEN 310
320 GOSUB 180
330 CL=K-64
340 CL$(T,T)=CHR$(K)
350 FOR X=X TO X+1:COLOR CL:PLOT X,Y:DRAWTO X,ET:NEXT X
360 POSITION 0,3:? "Color OK (Y/N) ?":GET #1,K:IF K<>89 THEN X=X-2:IF K<>89 THEN 310
370 NEXT T
380 X=1:Y=5:ET=Y+4
390 FOR T2=1 TO H
400 GOSUB 180:POSITION 0,3:? "Harness #2: Thread # ";T2:? " Color Selection?":GET #1,K:IF K<64 OR K>79 THEN 400
410 GOSUB 180
420 CL1=K-64
430 CL1$(T2,T2)=CHR$(K)
440 FOR X=X TO X+1:COLOR CL1:PLOT X,Y:DRAWTO X,ET:NEXT X
450 POSITION 0,3:? "Color OK (Y/N) ?":GET #1,K:IF K<>89 THEN X=X-2:IF K<>89 THEN 400
460 NEXT T2
470 POSITION 0,0:? "↰ Press START to weave.":POKE 53279,8
480 IF PEEK(53279)<>6 THEN 480
490 POKE 53279,8
500 REM WEAVING ROUTINE
510 POSITION 0,0:? "↰             WEAVING"
520 FOR K=1 TO 79:COLOR 0:SOUND 0,255-(K*2),10,8:PLOT K,150:DRAWTO K,160:NEXT K:SOUND 0,0,0,0
530 X=1:Y=0:ET=4
540 FOR R=1 TO 15:X=1
550 FOR I=1 TO H
560 SB$=CL$(I,I)
570 CL=ASC(SB$)-64
580 FOR X=X TO X+1:SOUND 0,RND(1)*255,10,8:COLOR CL:PLOT X,Y:DRAWTO X,ET:NEXT X
590 SOUND 0,0,0,0:NEXT I
600 X=1:Y=ET+1:ET=Y+4
610 FOR I=1 TO H
620 SB$=CL1$(I,I)
630 CL1=ASC(SB$)-64
640 FOR X=X TO X+1:SOUND 1,RND(1)*255,10,8:COLOR CL1:PLOT X,Y:DRAWTO X,ET:NEXT X
650 SOUND 1,0,0,0:NEXT I:Y=ET+1:ET=Y+4
660 NEXT R
670 JNK=USR(ADR("hh┐qh┐ph┐Uh┐Th┐oh┐n ♥1p┌TfTP▕fUfpP▕fqFnPjFo♣f◆"),SCRN,ADX,7680)
680 WEAV$(7681,7681)=CHR$(PEEK(712))
690 FOR X=7682 TO 7684:WEAV$(X,X)=CHR$(PEEK(X-6974)):NEXT X
700 REM VALUE CHANGE OF WEAVING
710 ? "↰Do you wish to change the value? (Y/N) ":GET #1,K:IF K<>89 THEN 780
720 TRAP 730
730 ? "↰Type a letter between A (darkest) and O (lightest)":GET #1,K:IF K<65 OR K>79 THEN 730
740 V=K-64
750 A=PEEK(712):POKE 712,V:? "↰Value OK? (Y/N)";:GET #1,K:IF K<>89 THEN POKE 712,A
760 IF K<>89 THEN 730
770 TRAP 40000
780 ? "↰Weave again? (Y/N)":GET #1,K:IF K=89 THEN GOSUB 1530:IF K=89 THEN 100
790 ? "↰Return to menu? (Y/N)":GET #1,K:IF K=89 THEN POP :GOTO 1010
800 ? "↰ Leave program? (Y/N)":GET #1,K:IF K<>89 THEN 780
810 ? "↰         Sure? (Y/N)":GET #1,K:IF K=89 THEN GRAPHICS 0:END
820 REM TITLE ROUTINE
830 GRAPHICS 2+16:COLOR 2:POSITION 0,0
840 FOR LG=0 TO 4:? #6;"*******************":FOR DL=1 TO 30:SOUND 0,RND(1)*200,10,8:NEXT DL
850 ? #6;"*******************":FOR DL=1 TO 30:SOUND 1,RND(1)*200,10,8:NEXT DL:NEXT LG
860 FOR DL=1 TO 300:NEXT DL:SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 1,96,10,8:POSITION 0,4:? #6;"        THE        "
870 FOR DL=1 TO 100:NEXT DL:SOUND 0,121,10,8:POSITION 0,5:? #6;"    COLOR  LOOM      "
880 POSITION 0,0
890 FOR DL=1 TO 100:NEXT DL:SOUND 2,81,10,8:POSITION 0,6:? #6;"       BY GMH      "
900 FOR L=1 TO 800:NEXT L
910 FOR S=0 TO 3:SOUND S,0,0,0:NEXT S
920 RETURN
930 REM SET UP TEXT WINDOW
940 POKE 54286,0:GRAPHICS 8:POKE 87,11:POKE 623,192:POKE PEEK(560)+256*PEEK(561)+166,143:RESTORE
950 ADDRES=1536:POKE 54286,64:FOR K=0 TO 18:READ P:POKE ADDRES+K,P:NEXT K:P=INT(ADDRES/256):POKE 513,P
960 POKE 512,ADDRES-256*P:POKE 54286,192:DATA 72,173,111,2,41,63,141,10,212,141,27,208,169,0,141,26,208,104,64
970 RETURN
980 REM MENU
990 GRAPHICS 2+16:POSITION 1,5:? #6;"  **** MENU ****"
1000 FOR D=1 TO 500:NEXT D
1010 GRAPHICS 0:POKE 752,1:POKE 710,210
1020 POSITION 0,8:? "             MENU":?
1030 ? "        1 CREATE NEW WEAVING"
1040 ? "        2 SAVE WEAVING"
1050 ? "        3 LOAD OLD WEAVING"
1060 ? "        4 LEAVE PROGRAM"
1070 ? :? "        Selection ?"
1080 CLOSE #1:OPEN #1,4,0,"K:"
1090 GET #1,K:IF K<49 OR K>52 THEN 1010
1100 A=K-48
1110 ON A GOSUB 80,1130,1280,810
1120 GOTO 1010
1130 REM SAVE PATTERN
1140 ? :? :? " Save to: 1..CASSETTE                           2..DISKETTE"
1150 GET #1,K:IF K<49 OR K>50 THEN 1140
1160 ON K-48 GOTO 1170,1200
1170 ? :? "Place tape in recorder":? "Press RECORD and PLAY":? "Then type  RETURN "
1180 POKE 764,255
1182 IF PEEK(764)<>12 THEN 1182
1184 POKE 764,255
1190 OPEN #2,8,128,"C:":GOTO 1210
1200 ? :? :? "Insert diskette and press  RETURN ":GET #1,K:OPEN #2,8,0,"D:WEAVING"
1210 ? :? :? :? "    SAVING PATTERN "
1220 ADHI=INT(ADX/256):ADLO=ADX-ADHI*256
1230 MODE=PEEK(87)
1240 IO=864:POKE IO+2,11:POKE IO+4,ADLO:POKE IO+5,ADHI
1250 POKE IO+8,4:POKE IO+9,30
1260 JNK=USR(ADR("hhh*LVd"),32):CLOSE #2
1270 RETURN
1280 REM LOAD OLD PATTERN
1290 ? :? :? "Load from:  1..CASSETTE                           2..DISKETTE"
1300 GET #1,K:IF K<49 OR K>50 THEN 1300
1310 POKE 752,1
1320 ON K-48 GOTO 1330,1370
1330 ? :? :? "Insert and queue tape"
1340 ? "press  PLAY , type  RETURN "
1350 POKE 764,255
1352 IF PEEK(764)<>12 THEN 1352
1354 POKE 764,255
1360 OPEN #2,4,128,"C:":GOTO 1420
1370 ? :? :? "Insert diskette and press  RETURN "
1380 POKE 764,255
1390 IF PEEK(764)<>12 THEN 1390
1400 POKE 764,255
1410 OPEN #2,4,0,"D:WEAVING"
1420 ? :? :? :? "    LOADING PATTERN "
1430 GOSUB 930
1440 ADHI=INT(ADX/256):ADLO=ADX-ADHI*256
1450 IO=864:POKE IO+2,7:POKE IO+4,ADLO:POKE IO+5,ADHI
1460 POKE IO+8,4:POKE IO+9,30
1470 JNK=USR(ADR("hhh*LVd"),32):CLOSE #2
1480 POKE 712,ASC(WEAV$(7681,7681))
1490 FOR X=708 TO 710:POKE X,ASC(WEAV$(X+6974,X+6974)):NEXT X:POKE 559,0
1500 LOD=1:POP :GOTO 90
1510 REM ERASE WEAVING AND RESET
1520 ? "↰     ERASING OLD PATTERN"
1530 FOR U=1 TO 40:CL$(U,U)="@":CL1$(U,U)="@":NEXT U
1540 SB$=" ":SB1$=" ":CR$=" "
1550 X=1:Y=0:ET=4
1560 FOR R=1 TO 15:X=1
1570 FOR I=1 TO H
1580 SB$=CL$(I,I)
1590 CL=ASC(SB$)-64
1600 FOR X=X TO X+1:SOUND 0,RND(1)*255,10,8:COLOR CL:PLOT X,Y:DRAWTO X,ET:NEXT X
1610 SOUND 0,0,0,0:NEXT I
1620 X=1:Y=ET+1:ET=Y+4
1630 FOR I=1 TO H
1640 SB$=CL1$(I,I)
1650 CL1=ASC(SB$)-64
1660 FOR X=X TO X+1:SOUND 1,RND(1)*255,10,8:COLOR CL1:PLOT X,Y:DRAWTO X,ET:NEXT X
1670 SOUND 1,0,0,0:NEXT I:Y=ET+1:ET=Y+4
1680 NEXT R
1690 RETURN