Lazy Loader, disk utility (LAZYLOAD.BAS)
Lazy Loader, disk utility by Frank Walters, 38
Description
Lazy Loader, disk utility by Frank Walters, 38
From the Antic disk of May 1985 (Vol. 4 No. 1).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 4.6 KB
- Dialect
- Atari BASIC
- Lines
- 85
- Variables
D$,DIR$,F$,T$,M$,Z$,D,I,J,FLG,N,X,K,F,Z,Y
BASIC listing (85 lines)
1 REM LAZY LOADER
2 REM BY FRANK WALTERS
3 REM ANTIC MAGAZINE
10 DIM D$(13),DIR$(6),F$(15),T$(200),M$(136),Z$(64):D=49:DIR$="D1:*.*":F$="D1:"
15 Z$="2→←└┴↓␛350B▕6▖7fu?▄─:*8=9▔├┐♥%#◢◣/(>-▝♣.▎+┬◆FbGN"<▄─:*8=9▔├┐♥%#◢"
20 FOR I=0 TO 128 STEP 8:FOR J=1 TO 7:M$(I+J)=CHR$(254):NEXT J:M$(I+J,I+J)=CHR$(29):NEXT I
30 POKE 82,0:POKE 83,39:GOSUB 40:GOTO 300
40 T$(1)="┌──────────────────────────────────────┐| LAZY LOADER by Frank Walters |"
50 T$(81)="| <1-4>Drive#: <RETURN>Directory || Keys: RUN: |"
60 T$(161)="└──────────────────────────────────────┘":RETURN
70 T$(129,132)="CAPS":IF PEEK(702)=0 THEN T$(129,132)="lowr"
80 IF PEEK(702)=128 THEN T$(129,132)="CTRL"
90 IF PEEK(694) THEN T$(129,132)="INVS"
100 T$(95,95)=CHR$(D+128):DIR$(2,2)=CHR$(D):POSITION 0,0:? T$:RETURN
110 TRAP 670:CLOSE #2:OPEN #2,6,0,DIR$
120 POKE 82,14:POSITION 14,5:FOR I=65 TO 90
130 INPUT #2;D$
140 IF D$(11,13)="SYS" OR D$(11,13)="EXE" OR D$(11,13)="OBJ" OR D$(11,13)="DAT" THEN 130
150 IF D$(4,7)=" FRE" OR D$(5,8)=" FRE" THEN POP :GOTO 270
160 IF I=82 THEN POKE 82,0:POSITION 0,5:? M$:POKE 82,20:POSITION 20,5
170 ? CHR$(I+128);CHR$(190);D$(3):NEXT I
180 FOR I=97 TO 122
190 INPUT #2;D$
200 IF D$(11,13)="SYS" OR D$(11,13)="EXE" OR D$(11,13)="OBJ" OR D$(11,13)="DAT" THEN 190
210 IF D$(4,7)=" FRE" OR D$(5,8)=" FRE" THEN POP :GOTO 270
220 IF I=105 THEN POKE 82,0:POSITION 0,5:? M$:POKE 82,26:POSITION 26,5
230 IF I=122 THEN 250
240 ? CHR$(I+128);CHR$(190);D$(3)
250 NEXT I:I=I-1:IF D$(4,7)=" FRE" OR D$(5,8)=" FRE" THEN 270
260 POSITION 12,22:? "more files...":CLOSE #2:TRAP 40000:POKE 82,0:I=I-1:RETURN
270 CLOSE #2:TRAP 40000:POKE 82,0:I=I-1
280 POSITION 12,22:? D$;:IF D$(5,5)=" " THEN ? "T";
290 ? "ORS";:RETURN :REM CHANGE 'ORS' TO 'KS' FOR DOS 3
300 GRAPHICS 0:POKE 752,1:POKE 710,192:POKE 709,198:POKE 712,192
301 GOSUB 70:GOSUB 110
302 POKE 694,0:IF PEEK(702)=128 THEN POKE 702,64
303 GOSUB 70
304 POKE 764,255:FLG=1
305 IF PEEK(764)=255 THEN 305
306 IF PEEK(764)=124 OR PEEK(764)=60 THEN POKE 702,(PEEK(764)-60):GOSUB 70:GOTO 304
307 N=PEEK(764):IF N>63 THEN N=N-64:FLG=0
308 IF PEEK(702)=64 THEN FLG=0
309 IF PEEK(764)=12 THEN RUN
310 FOR X=1 TO 64:IF CHR$(N)<>Z$(X,X) THEN 314
311 IF X<11 THEN FLG=0
312 K=(X+47)+32*(FLG):POP :GOTO 350
314 NEXT X:GOTO 303
350 POKE 764,255:GOSUB 70:IF K>48 AND K<53 THEN D=K:GOTO 300
360 IF K=4 THEN POKE 82,2:GRAPHICS 0:DOS
390 IF K<65 THEN 350
400 IF K>90 AND K<97 THEN 350
410 IF K>I THEN 350
420 POSITION 19,3:? CHR$(K+128)
430 CLOSE #1:T$(140,140)=CHR$(K+128):GOSUB 70
440 F=K-64:IF F>26 THEN F=F-6
450 CLOSE #2:OPEN #2,6,0,DIR$
460 TRAP 670:FOR I=1 TO F
470 INPUT #2;D$
480 IF D$(11,13)="SYS" OR D$(11,13)="EXE" OR D$(11,13)="OBJ" OR D$(11,13)="DAT" THEN 470
490 NEXT I:CLOSE #2:D$=D$(3,LEN(D$)):F$(2,2)=CHR$(D)
500 IF D$(9,9)<>" " THEN 530
510 FOR I=1 TO 9:IF D$(I,I)=" " THEN POP :GOTO 570
520 F$(I+3)=D$(I,I):NEXT I
530 FOR I=1 TO 8
540 IF D$(I,I)=" " THEN POP :GOTO 560
550 F$(I+3)=D$(I,I):NEXT I
560 F$(I+3,I+3)=".":FOR J=9 TO 11:IF D$(J,J)<>" " THEN F$(I+4)=D$(J,J):I=I+1:NEXT J
570 T$(142,156)=" ":T$(142,141+LEN(F$))=F$:GOSUB 70
580 TRAP 590:POKE 82,2:POKE 702,64:GRAPHICS 0:RUN F$
590 IF PEEK(195)<>21 THEN 670
600 POKE 82,0:GOSUB 710
610 CLOSE #1:OPEN #1,4,0,"K:"
620 GET #1,K:IF K<>89 AND K<>78 THEN 620
630 CLOSE #1:IF K=78 THEN 30
640 ? CHR$(125):GOSUB 70:POKE 82,2:POKE 752,0:POSITION 15,3:? "ENTER":POSITION 2,10
650 TRAP 40000:? "PRESS RETURN WHEN"
660 ? " TO":? " ENTER ";CHR$(34);F$:? :? :? " RUN";"↑↑↑↑↑";:NEW
670 TRAP 40000
680 POSITION 20,2:? "<RETURN>":POSITION 21,3:? "↰ ERROR - ";PEEK(195);" "
690 IF PEEK(764)<>12 THEN 690
700 POKE 195,0:POKE 764,255:RUN
710 COLOR 160:X=11:Z=27:FOR Y=8 TO 16:PLOT X,Y:DRAWTO Z,Y:NEXT Y:PLOT Z,Y-1
720 POSITION 14,9:? "DO YOU WANT":POSITION 15,11:? "TO ENTER:"
730 POSITION 19-(LEN(F$)/2),13:? F$
740 POSITION 17,15:? "(Y/N)↰":RETURN
