Fader II Modifier, patch (FADERMOD.BAS)
Fader II Modifier, patch by Patrick L. Dell'era, 18
Description
Fader II Modifier, patch by Patrick L. Dell'era, 18
From the Antic disk of May 1985 (Vol. 4 No. 1).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.2 KB
- Dialect
- Atari BASIC
- Lines
- 51
- Variables
FILE$,FILENAME$,X,Y,A,OKAY,SECTOR,BYTE,WAIT,DRVNUM
BASIC listing (51 lines)
5 REM FADER II MODIFIER
10 REM BY PATRICK DELL'ERA
15 REM ANTIC MAGAZINE
20 DIM FILE$(12),FILENAME$(16)
30 CLOSE #1:OPEN #1,4,0,"K:"
40 GRAPHICS 0:POKE 752,1:POKE 712,144:POKE 710,146:POKE 708,150
50 POSITION 10,1:? ;"▕FADER II MODIFIER▎"
60 POSITION 5,4:POKE 82,5
70 ? ;"▕ENTER NAME OF FADER II FILE:"
80 X=9:Y=6
90 FILENAME$="D1:------------":POSITION X-3,Y:? FILENAME$
100 FILE$=""
110 GET #1,A
120 IF LEN(FILE$)=12 AND A<>ASC("◀") THEN ? "↰":GOTO 110
130 OKAY=0:IF (A>64 AND A<91) OR A=46 OR (A>47 AND A<58) THEN OKAY=1
140 IF OKAY THEN POSITION X,Y:? CHR$(A);:FILE$(LEN(FILE$)+1)=CHR$(A):X=X+1:GOTO 110
150 IF A=155 THEN 200
160 IF A<>ASC("◀") THEN 110
170 IF LEN(FILE$)=1 THEN X=9:FILE$="":POSITION X,Y:? #6;"-";:GOTO 110
180 IF NOT LEN(FILE$) THEN 110
190 X=X-1:POSITION X,Y:? #6;"-";:POSITION X,Y:FILE$=FILE$(1,LEN(FILE$)-1):GOTO 110
200 IF FILE$(LEN(FILE$))="-" THEN FILE$=FILE$(LEN(FILE$)-1):GOTO 200
210 FILENAME$(4)=FILE$
220 TRAP 470:CLOSE #2:OPEN #2,12,0,FILENAME$
230 NOTE #2,SECTOR,BYTE:BYTE=6:POINT #2,SECTOR,BYTE
240 GET #2,WAIT
250 GET #2,DRVNUM
260 POSITION 5,9:? "▕DRIVE # =▎";CHR$(DRVNUM)
270 POSITION 5,11:? "▕PAUSE TIME =▎";INT(WAIT*4.27+0.05);" seconds◀◀◀"
280 POSITION 5,13
290 ? "▕OPTION CHANGES DRIVE # ▎"
300 ? "▕ ▎"
310 ? "▕SELECT CHANGES PAUSE TIME▎"
320 ? "▕(press '-' for less time,▎"
330 ? "▕any other key for more ▎"
340 ? "▕pause time) ▎"
350 ? "▕ ▎"
360 ? "▕START SAVES CHANGES ▎"
370 A=PEEK(53279):IF A=7 THEN 370
380 A=A-2:ON A GOTO 390,370,410,440,370
390 DRVNUM=DRVNUM+1-(DRVNUM=52)*4
400 GOTO 260
410 IF PEEK(764)=14 THEN WAIT=WAIT-1+(WAIT=0)*256:GOTO 260
420 WAIT=WAIT+1-(WAIT=255)*256
430 GOTO 260
440 POINT #2,SECTOR,BYTE:PUT #2,WAIT:PUT #2,DRVNUM
450 GRAPHICS 0
460 CLOSE #2:CLOSE #1:POKE 82,2:POKE 752,0:END
470 IF PEEK(195)=170 THEN POSITION 6,15:? "↰▕Can't find that file...":GOTO 80
480 GRAPHICS 0
490 ? "↰↓↓Error #";PEEK(195);" at line #";PEEK(186)+256*PEEK(187);".":GOTO 460
