The Eight Queens Problem (QUEENS8.BAS)
The Eight Queens Problem by Angelo Giambra, 28
Description
The Eight Queens Problem by Angelo Giambra, 28
From the Antic disk of April 1985 (Vol. 3 No. 12).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 3.4 KB
- Dialect
- Atari BASIC
- Lines
- 54
- Variables
COL(,ROW,I,A(,STARTOVER,CT,INC,INC1,X,Y,C(,C,DLIST,SCR,Z,S,CH,D,A,T,Q,PL$,PMBASE,X$,X1
BASIC listing (54 lines)
5 REM THE EIGHT QUEENS PROBLEM
6 REM BY ANGELO GIAMBRA
7 REM ANTIC MAGAZINE
10 GOTO 210
20 IF COL(ROW)>8 THEN 160
30 FOR I=1 TO 8:IF A(I,COL(ROW))=1 THEN STARTOVER=1:I=8
40 NEXT I
50 IF STARTOVER THEN STARTOVER=0:COL(ROW)=COL(ROW)+1:GOTO 20
60 FOR CT=1 TO 4
70 INC=(CT=1 OR CT=2)*-1+(CT=3 OR CT=4):INC1=(CT=1 OR CT=4)*-1+(CT=2 OR CT=3)
80 X=ROW+INC:Y=COL(ROW)+INC1:IF X<1 OR X>8 OR Y<1 OR Y>8 THEN 120
90 IF A(X,Y)=1 THEN STARTOVER=1:GOTO 50
100 X=X+INC:Y=Y+INC1:IF X<1 OR X>8 OR Y<1 OR Y>8 THEN 120
110 GOTO 90
120 NEXT CT
130 A(ROW,COL(ROW))=1:COLOR 1:SOUND 0,50,10,10
140 T=COL(ROW)+5:Q=ROW:POSITION T,Q:? #6;"!":SOUND 0,0,0,0:ROW=ROW+1:IF ROW=9 THEN 280
150 COL(ROW)=1:GOTO 30
160 ROW=ROW-1:A(ROW,COL(ROW))=0:SOUND 0,100,10,8
170 COLOR 0:T=COL(ROW)+5:Q=ROW:POSITION T,Q:? #6;" ":SOUND 0,0,0,0
180 COL(ROW)=COL(ROW)+1:IF COL(ROW)=9 AND ROW=1 THEN 320
190 IF COL(ROW)=9 THEN 160
200 GOTO 30
210 DIM A(8,8),COL(8),C(8,8)
220 ? "↰↓↓↓↓▶STARTING POSITION (1-8)";:INPUT C
230 OPEN #1,4,0,"K":X=1:COLOR 1
240 FOR I=1 TO 8:FOR Z=1 TO 8:A(I,Z)=0:NEXT Z:NEXT I
250 FOR I=1 TO 8:COL(I)=I:NEXT I:COL(1)=C
260 GOSUB 340
270 ROW=1:S=0:GOTO 130
280 S=S+1:? " SOLUTION ";S:? " PRESS ANY KEY↑"
290 FOR I=1 TO 10:SETCOLOR 4,15,4:FOR Z=1 TO 10:SOUND 0,Z*2,10,10:SOUND 1,Z*10,10,10:NEXT Z
300 SETCOLOR 4,0,0:FOR Z=1 TO 10:NEXT Z:NEXT I:SOUND 0,0,0,0:SOUND 1,0,0,0
310 GET #1,CH:? " ↑↑":GOTO 160
320 ? "↓ DONE "
330 GOTO 330
340 DIM X$(1),PL$(2048):PL$(1)=CHR$(0):PL$(2048)=CHR$(0):PL$(2)=PL$:A=ADR(PL$):PMBASE=INT(A/1024)*1024
350 IF PMBASE<A THEN PMBASE=PMBASE+1024
360 S=PMBASE-A+1:POKE 106,144:POKE 106,PEEK(106)-4
370 POKE 106,PEEK(106)-16:GRAPHICS 2:POKE 704,34:POKE 705,34:POKE 710,0:POKE 709,0:POKE 710,40:POKE 559,0
380 POKE 752,1:? " EIGHT QUEENS PROBLEM":POKE 756,PEEK(106):Z=PEEK(106)*256
390 DATA 85,85,127,28,28,127
400 FOR I=57344 TO 57344+512:POKE Z,PEEK(I):Z=Z+1:NEXT I:Z=PEEK(106)*256+9
410 FOR I=1 TO 6:READ A:POKE Z,A:Z=Z+1:NEXT I
420 POKE 706,34:POKE 707,34:POKE 53248,96:POKE 53249,112:POKE 53250,128:POKE 53251,144
430 FOR I=408 TO 471:PL$(S+I,S+I)=CHR$(255):NEXT I
440 X1=63:X$=CHR$(240):X=535:GOSUB 500:X=663:GOSUB 500:X=791:GOSUB 500:X=919:GOSUB 500
450 X1=55:X$=CHR$(15):X=543:GOSUB 500:X=671:GOSUB 500:X=799:GOSUB 500:X=927:GOSUB 500
460 POKE 53277,3:POKE 54279,PMBASE/256
470 FOR I=0 TO 3:POKE 53256+I,1:NEXT I:POKE 559,46
480 POKE 53252,95:POKE 53253,161:POKE 711,34:POKE 623,20
490 RETURN
500 FOR I=X TO X+X1 STEP 16:FOR D=1 TO 8:PL$(S+I+D,S+I+D)=X$:NEXT D:NEXT I:IF X1=63 THEN PL$(S+X)=CHR$(255)
510 PL$(S+X+X1+1,S+X+X1+1)=CHR$(255):RETURN
