Priceless Picture Show (PRICELES.BAS)
Priceless Picture Show by Patrick L. Dell'era, 32
Description
Priceless Picture Show by Patrick L. Dell'era, 32
From the Antic disk of April 1985 (Vol. 3 No. 12).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 3.9 KB
- Dialect
- Atari BASIC
- Lines
- 91
- Variables
P0$,P1$,P2$,P3$,FILE$,FILENAME$,BGET$,FIRSTL,FIRSTH,K,FIRSTSC,SECONDL,SECONDH,X,Y,A,OKAY,P0,P1,P2,P3,POT,LO,HI
BASIC listing (91 lines)
10 REM PATRICK'S PRICELESS
20 REM PICTURE SHOW
30 REM BY P.L. DELL'ERA
40 REM ANTIC MAGAZINE
70 DIM P0$(192),P1$(192),P2$(192),P3$(192),FILE$(17),FILENAME$(17),BGET$(48)
80 GRAPHICS 24:POKE 710,146:POKE 712,144:FIRSTL=PEEK(560):FIRSTH=PEEK(561)
90 K=FIRSTL+FIRSTH*256+3:FIRSTSC=PEEK(88)+PEEK(89)*256
100 POKE K,206:K=K+2
110 K=K+1
120 IF PEEK(K)=15 THEN POKE K,14
130 IF PEEK(K)=79 THEN POKE K,78:K=K+2
140 IF PEEK(K)<>65 THEN 110
150 POKE 106,PEEK(106)-34
160 GRAPHICS 0:SECONDL=PEEK(560):SECONDH=PEEK(561):GOSUB 1000
180 REM BUILD DLI ROUTINE, BGET$
190 REM (RELOCATABLE)
210 RESTORE 1050:FOR X=1536 TO 1577:READ K:POKE X,K:NEXT X
220 LET BGET$="hI┘p▗(◢0 hh┴♣xhh*h↓E┘h↓D┘h↓I┘h↓H┘)╲↓B┘ Vd)♥┐U┤T◆"
240 REM INPUT ROUTINE
260 GOSUB 1000:POKE 82,2:POKE 752,1
270 CLOSE #2:OPEN #2,4,0,"K:"
280 ? "↰↓▕PATRICK'S PRICELESS PICTURE SHOW▎"
290 CLOSE #1:OPEN #1,6,0,"D:*.*"
300 TRAP 390:X=4:Y=8
310 INPUT #1,FILE$
320 IF FILE$(2,2)<>" " THEN 390
330 K=3
340 K=K+1:IF FILE$(K,K)<>" " AND K<11 THEN 340
350 IF FILE$(K,K)<>" " AND K=11 THEN FILENAME$=FILE$(11,13):FILE$(K)=".":FILE$(K+1)=FILENAME$:GOTO 380
360 IF FILE$(11,11)=" " THEN FILE$=FILE$(1,11):GOTO 380
370 FILE$(K,K)=".":FILE$(K+1)=FILE$(11,13)
380 POSITION X,Y:PRINT FILE$(3):X=4+(X=4)*16:Y=Y+1*(X=4):GOTO 310
390 TRAP 40000:CLOSE #1
400 POSITION 5,4:POKE 82,5:POKE 752,1
410 ? "Please enter filename:"
420 X=9:Y=6
430 FILENAME$="D1:------------":POSITION X-3,Y:? FILENAME$
440 FILE$=""
450 IF PEEK(764)<>255 THEN 500
460 IF PEEK(53279)<>3 THEN 450
470 GOSUB 940
480 IF PEEK(53279)<>6 THEN 480
490 GOSUB 1000:GOTO 450
500 GET #2,A
510 IF A=155 THEN 590
520 IF LEN(FILE$)=12 AND A<>ASC("◀") THEN ? "↰":GOTO 500
530 OKAY=0:IF (A>64 AND A<91) OR A=46 OR (A>47 AND A<58) THEN OKAY=1
540 IF OKAY THEN POSITION X,Y:? CHR$(A);:FILE$(LEN(FILE$)+1)=CHR$(A):X=X+1:GOTO 500
550 IF A<>ASC("◀") THEN 500
560 IF LEN(FILE$)=1 THEN X=9:FILE$="":POSITION X,Y:? #6;"-";:GOTO 500
570 IF NOT LEN(FILE$) THEN 500
580 X=X-1:POSITION X,Y:? #6;"-";:POSITION X,Y:FILE$=FILE$(1,LEN(FILE$)-1):GOTO 500
590 FILENAME$(4)=FILE$
600 TRAP 260:OPEN #1,4,0,FILENAME$:TRAP 40000
610 X=USR(ADR(BGET$),16,FIRSTSC,7680)
620 P0=0:P1=52:P2=136:P3=162
630 IF X>128 THEN 650
640 GET #1,P0:GET #1,P1:GET #1,P2:GET #1,P3
650 CLOSE #1
660 P0$=CHR$(P0):P0$(192)=P0$:P0$(2)=P0$
670 P1$=CHR$(P1):P1$(192)=P1$:P1$(2)=P1$
680 P2$=CHR$(P2):P2$(192)=P2$:P2$(2)=P2$
690 P3$=CHR$(P3):P3$(192)=P3$:P3$(2)=P3$
700 X=4
710 X=X+1:IF X>LEN(FILENAME$) THEN 740
720 IF FILENAME$(X,X)="." THEN 740
730 IF X<12 THEN 710
740 FILENAME$(X)=".P0":X=X+2:POT=ASC("0")
750 K=ADR(P0$):GOSUB 850:POKE 1566,LO:POKE 1567,HI
760 K=ADR(P1$):GOSUB 850:POKE 1545,LO:POKE 1546,HI
770 K=ADR(P2$):GOSUB 850:POKE 1554,LO:POKE 1555,HI
780 K=ADR(P3$):GOSUB 850:POKE 1560,LO:POKE 1561,HI
790 GOSUB 940
800 IF PEEK(53279)<>6 THEN 800
810 POKE 54286,64:POKE 560,SECONDL:POKE 561,SECONDH:GOTO 260
830 REM FILL COLOR POTS
850 TRAP 870
860 OPEN #1,4,0,FILENAME$:A=USR(ADR(BGET$),16,K,192)
870 CLOSE #1:TRAP 40000
880 POT=POT+1:FILENAME$(X,X)=CHR$(POT)
890 RESTORE K:LO=PEEK(183):HI=PEEK(184):RETURN
910 REM INSTALL DLI, PUT PICTURE ON
920 REM SCREEN
940 POKE 712,P0:POKE 708,P1:POKE 709,P2:POKE 710,P3
950 POKE 560,FIRSTL:POKE 561,FIRSTH
960 POKE 512,0:POKE 513,6:POKE 54286,192:POKE 559,34:RETURN
980 REM TURN TEXT SCREEN ON
1000 POKE 710,146:POKE 712,144:POKE 709,14:POKE 752,1:? :POKE 560,SECONDL:POKE 561,SECONDH:RETURN
1030 REM (RELOCATABLE)
1050 DATA 72,138,72,162,191,141,10,212,189,204,204,141,10,212,141,22,208,189,204,204,141,23,208,189,204
1060 DATA 204,141,24,208,189,204,204,141,26,208,202,208,226,104,170,104,64
