Digitizer (DIGITIZE.BAS)
Digitizer by Charles Jackson and S. Chapman, 22
Description
Digitizer by Charles Jackson and S. Chapman, 22
From the Antic disk of April 1985 (Vol. 3 No. 12).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.7 KB
- Dialect
- Atari BASIC
- Lines
- 55
- Variables
PIC$,P$,Q$,J$,FN$,LO,HI,D,AD,B,X,TIME,C,V,N,IO,ADHI,ADLO,K,LF,CON
BASIC listing (55 lines)
10 REM DIGITIZER
20 REM BY C. JACKSON & S. CHAPMAN
30 REM ANTIC MAGAZINE
40 DIM PIC$(7680),P$(80),Q$(40),J$(1),FN$(20)
50 ? "↰Name of picture- <Dev:filename>":INPUT FN$
60 ? "↰Contrast setting--":? :? "(1) = Low Contrast":? " (20 minutes to process)"
70 ? :? "(2) = High Contrast":? " (60 minutes to process)":INPUT CON
80 IF CON=1 OR CON=2 THEN 100
90 GOTO 60
100 ? "↰Put a WHITE screen in front of the":? "sensor, press [RETURN].":INPUT J$
110 LO=PADDLE(0)
120 ? "↰Put a BLACK screen in front of the":? "sensor, press [RETURN].":INPUT J$
130 HI=PADDLE(0):D=(HI-LO)/15
140 IF CON=2 THEN LO=SQR(LO):HI=SQR(HI):D=(HI-LO)/15
150 ? "↰Press [RETURN] to begin":INPUT J$
160 CLOSE #1:OPEN #1,8,0,"P:"
170 ? #1;CHR$(27);CHR$(36);CHR$(1);:REM SELECT DOWNLOAD CHARACTER SET
180 ? #1;CHR$(27);CHR$(51);CHR$(0);:REM SET LINEFEED VALUE TO 0
190 ? #1;CHR$(15);:REM CHOOSE CONDENSED MODE
200 ? #1;CHR$(27);CHR$(77);CHR$(1);:REM SET LEFT MARGIN TO 1.
210 ? #1;CHR$(27);CHR$(56);:REM DISREGARD "PAPER-OUT" DETECTOR
220 ? #1;CHR$(27);CHR$(98);CHR$(1);".";
230 GRAPHICS 9:AD=PEEK(88)+PEEK(89)*256
240 FOR B=1 TO 7680 STEP 40
250 ? #1;CHR$(27);CHR$(98);CHR$(135);"␛J";CHR$(4);".":SOUND 0,66,14,14
260 FOR X=1 TO 80:P$(X,X)=CHR$(PEEK(624))
270 LET TIME=3*256
280 NEXT X:SOUND 0,0,0,0:? #1;".";
290 C=40:V=0
300 FOR N=1 TO 80 STEP 2
310 IF CON=2 THEN 350
320 V=16*INT((ASC(P$(N+1,N+1))-LO)/D+0.5)
330 V=V+INT((ASC(P$(N,N))-LO)/D+0.5)
340 GOTO 370
350 V=16*INT((SQR(ASC(P$(N+1,N+1)))-LO)/D+0.5)
360 V=V+INT((SQR(ASC(P$(N,N)))-LO)/D+0.5)
370 IF V>=256 THEN V=255
380 IF V<0 THEN V=0
390 V=255-V
400 POKE AD+B+C-2,V
410 Q$(C,C)=CHR$(V):C=C-1:NEXT N
420 PIC$(B)=Q$:NEXT B
430 CLOSE #1:OPEN #1,8,0,FN$
440 IO=848:AD=ADR(PIC$):ADHI=INT(AD/256):ADLO=AD-ADHI*256
450 POKE IO+2,11:POKE IO+4,ADLO:POKE IO+5,ADHI
460 POKE IO+8,0:POKE IO+9,30
470 K=USR(ADR("hhh*LVd"),16):CLOSE #1
480 GRAPHICS 0:? FN$;" saved to disk."
490 ? :? "Press [RETURN] to view picture.":INPUT J$
500 OPEN #1,4,0,FN$
510 GRAPHICS 9
520 POKE IO+2,7:POKE IO+4,PEEK(88):POKE IO+5,PEEK(89)
530 POKE IO+8,0:POKE IO+9,30
540 K=USR(ADR("hhh*LVd"),16):CLOSE #1
550 GOTO 550
