Address Label Maker (LABLMAKR.BAS)

Address Label Maker by William W. Watson, 37

Description

Address Label Maker by William W. Watson, 37

From the Antic disk of March 1985 (Vol. 3 No. 11).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 4.5 KB

Dialect
Atari BASIC
Lines
105
Variables
BD$, N$, S$, CZ$, TB$, TC$, QQ$, K, T, CHR, O, Z, QQ, Q, D
BASIC listing (105 lines)
1 REM ADDRESS LABEL MAKER
2 REM BY WILLIAM W. WATSON
3 REM ANTIC MAGAZINE
10 SETCOLOR 2,13,4
20 DIM BD$(1),N$(27),S$(27),CZ$(27),TB$(27),TC$(13),QQ$(3)
30 CLOSE #3:OPEN #3,4,0,"K"
40 POKE 752,0:POSITION 2,20:? "↰":? :? "FOR BORDER":? "    PRESS DESIRED KEY   >";:GET #3,K
50 IF K<32 OR K>122 THEN 40
60 BD$=CHR$(K)
70 PRINT "↰":POKE 752,1
80 FOR T=0 TO 39:POSITION T,0:PRINT BD$:NEXT T
90 FOR T=0 TO 16:POSITION 39,T:PRINT BD$:NEXT T
100 FOR T=39 TO 0 STEP -1:POSITION T,16:PRINT BD$:NEXT T
110 FOR T=16 TO 0 STEP -1:POSITION 0,T:PRINT BD$:NEXT T
120 FOR T=1 TO 13:TC$(T,T)=BD$:NEXT T
130 POSITION 5,3:PRINT TC$;"   ";TC$
140 FOR T=4 TO 6:POSITION 4,T:PRINT BD$;" 3 LINE      ";BD$;" ";BD$;"  25 LETTERS ";BD$:NEXT T
150 POSITION 5,7:PRINT TC$;"   ";TC$
160 POSITION 5,9:PRINT TC$;"   ";TC$
170 FOR T=10 TO 12:POSITION 4,T:PRINT BD$;" 4 TO  LABEL ";BD$;" ";BD$;" GEMINI 10X  ";BD$:NEXT T
180 POSITION 5,13:PRINT TC$;"   ";TC$
190 CLOSE #3:OPEN #3,4,0,"K"
200 TRAP 200:POSITION 2,20:PRINT "IS THIS ALL RIGHT (Y/N)":PRINT "FOR SPECIAL CHARACTER PRESS ESCAPE ";:GET #3,K
210 IF K=89 THEN 290
220 IF K=27 THEN 250
230 IF K=78 THEN 280
240 GOTO 200
250 POSITION 2,20:PRINT "                "
260 POSITION 2,20:PRINT "ENTER SPECIAL CHARACTER #XXX";:INPUT CHR
270 BD$=CHR$(CHR):GOTO 70
280 FOR T=1 TO 100:NEXT T:GOTO 40
290 GOSUB 840
300 POSITION 10,1:FOR T=1 TO 27:TB$(T,T)=BD$:NEXT T:PRINT TB$
310 POSITION 9,2:PRINT BD$;"                           ";BD$
320 POSITION 9,3:PRINT BD$;"                           ";BD$
330 POSITION 9,4:PRINT BD$;"                           ";BD$
340 POSITION 10,5:PRINT TB$
350 GOSUB 850:GOSUB 860:GOSUB 870:GOSUB 880
360 CLOSE #3:OPEN #3,4,0,"K"
370 POSITION 4,7:PRINT " TO EDIT PRESS ( 0 THRU (0=OK) 5 )";:GET #3,K
380 IF K<48 OR K>53 THEN 370
390 IF K=48 THEN 460
400 IF K=49 THEN GOSUB 850
410 IF K=50 THEN GOSUB 860
420 IF K=51 THEN GOSUB 870
430 IF K=52 THEN GOSUB 880
440 IF K=53 THEN 960
450 GOTO 370
460 POKE 82,7:POSITION 7,8
470 PRINT "╱▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔╲"
480 PRINT "▎   <>   PRINTER    <>   ▕"
490 PRINT "▎ 1 TO RETURN TO EDIT    ▕"
500 PRINT "▎ 2 TO PRINT       =>    ▕"
510 PRINT "▎ NUMBER REQUIRE   #>   <▕"
520 PRINT "▎ PRINTING         #>   <▕"
530 PRINT "▎ DO YOU WANT MORE   Y/N ▕"
540 PRINT "▎ WANT ANOTHER LABEL Y/N ▕"
550 PRINT "╲▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂╱":POKE 82,0
560 CLOSE #3:OPEN #3,4,O,"K":POSITION 28,11:PRINT " ";:GET #3,K
570 IF K<49 OR K>50 THEN 460
580 IF K=49 THEN 370
590 IF K=50 AND Z=0 THEN 610
600 GOTO 630
610 TRAP 980:Z=1:CLOSE #3:LPRINT ;CHR$(27);CHR$(36);CHR$(0);
614 REM ALTER THE FOLLOWING PRINTER   CODES TO MATCH YOUR PRINTER'S EQUIV-  ALENT OF:
615 REM CONDENSED, SUPERSCRIPT AND    LINE FEED OF 12/144
620 LPRINT ;CHR$(15);:LPRINT ;CHR$(27);CHR$(83);CHR$(0);:LPRINT ;CHR$(27);CHR$(51);CHR$(12);
630 TRAP 980:POSITION 27,12:PRINT "   ":POSITION 27,12:INPUT QQ$:POSITION 27,12:PRINT ">":QQ=VAL(QQ$):Q=0
635 IF QQ=0 THEN 460
640 CLOSE #3:OPEN #3,4,0,"K":POSITION 6,17:POKE 752,1:PRINT "SET PRINTER TOP OF LABEL AND PRESS ANY KEY TO RUN"
650 GET #3,K
660 POSITION 6,17:PRINT "                                                  "
670 FOR Q=QQ TO 1 STEP -1
680 POSITION 28,13:PRINT "   ":POSITION 28,13:PRINT Q
690 FOR D=1 TO 2
700 LPRINT
710 LPRINT " ";TB$;"   ";TB$
720 LPRINT BD$;N$;BD$;" ";BD$;N$;BD$
730 LPRINT BD$;S$;BD$;" ";BD$;S$;BD$
740 LPRINT BD$;CZ$;BD$;" ";BD$;CZ$;BD$
750 LPRINT " ";TB$;"   ";TB$
760 NEXT D
770 IF Q=1 THEN POSITION 28,13:PRINT "   ↰↰"
780 NEXT Q
790 POKE 752,0:CLOSE #3:OPEN #3,4,0,"K":POSITION 30,14:PRINT "N";:GET #3,K
800 IF K=89 THEN 630
810 CLOSE #3:OPEN #3,4,0,"K":POSITION 30,15:PRINT "N";:GET #3,K
820 IF K=89 THEN 30
830 LPRINT "␛@";CHR$(27);CHR$(36);CHR$(0):CLOSE #3:PRINT "↰":END
840 PRINT "↰":POSITION 10,0:PRINT "3210987654321X1234567890123":RETURN
850 POKE 752,0:POSITION O,2:PRINT "1 NAME =>";:INPUT N$:RETURN
860 POSITION O,3:PRINT "2 STREET>";:INPUT S$:RETURN
870 POSITION O,4:PRINT "3 CITY,=>":POSITION 0,5:PRINT "ST,ZIP":POSITION 9,4:INPUT CZ$:RETURN
880 POSITION 0,6:PRINT "4 BORDER=>";" ";BD$;"   5 SPECIAL CHR.=>";:POSITION 10,6:INPUT BD$
890 POSITION 10,6:PRINT BD$;" "
900 FOR T=1 TO 27:TB$(T,T)=BD$:NEXT T
910 POSITION 10,1:PRINT TB$
920 POSITION 9,2:PRINT BD$;N$;BD$
930 POSITION 9,3:PRINT BD$;S$;BD$
940 POSITION 9,4:PRINT BD$;CZ$;BD$
950 POSITION 10,5:PRINT TB$:RETURN
960 POSITION 30,6:INPUT CHR
970 BD$=CHR$(CHR):GOSUB 890:GOTO 370
980 FOR T=1 TO 6:POSITION 6,18:PRINT "SOMETHING  OFF↰":NEXT T
990 POSITION 6,18:PRINT "                       ":GOTO 460