Quick Dump (KWIKDUMP.BAS)
Quick Dump by Jerry Allen, 26
Description
Quick Dump by Jerry Allen, 26
From the Antic disk of March 1985 (Vol. 3 No. 11).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 3.1 KB
- Dialect
- Atari BASIC
- Lines
- 45
- Variables
LOD$,A$,PRNT$,GRAF$,J$,FILE$,KLR$,T,N,SLOC,X,START,A,B,C
BASIC listing (45 lines)
10 REM QUICK DUMP
20 REM (c) 1984 BY JERRY ALLEN
30 REM P.O. BOX 2205, REDONDO BEACH
40 REM CALIF. 90278
100 REM INITIALIZATION
110 TRAP 500:DIM LOD$(28),A$(81),PRNT$(192),GRAF$(6),J$(18),FILE$(18),KLR$(6)
120 GOTO 1010:REM ****DON'T TYPE THIS LINE OR 1000 TO END IF YOU DON'T NEED HELP WITH THE NEXT TWO LINES********
130 LOD$="h)╲▔R┘h▔U┘h▔T┘h▔Y┘h▔X┘"♣ Vd◆"
140 A$="hh┐Lh┐Kh┐Nh┐M ♥┤Ohh┐P ♥1KI␛P▕)└I▔P▕)▘$O┌MH┤O@@p %PI▕0▔8%Ki(┐K0VFL♣R┴%Ki(┐K♣IfL0E◆"
150 A$(27,27)=CHR$(155):PRNT$="♥":PRNT$(192)=PRNT$:PRNT$(2)=PRNT$:POKE 710,0:POKE 709,40
160 ? "↰CHOOSE:":? "1 EPSON/GEMINI":? "2 NEC 8023":? "3 PROWRITER 8510":INPUT T:GOSUB 600+T
200 REM GET DIRECTORY
210 CLOSE #1:? "↰":POKE 710,0:POKE 709,40:? "INSERT DISK DRIVE #1, PRESS RETURN":INPUT J$:OPEN #1,6,0,"D:*.*"
220 ? "↰":TRAP 230:FOR N=0 TO 63:INPUT #1,FILE$:POSITION 2+19*((N/2)=INT(N/2)),INT(N/2):? FILE$;:NEXT N
230 TRAP 500:POP :CLOSE #1:? :? "ENTER FILENAME";:INPUT FILE$
240 IF FILE$(1,2)<>"D:" AND FILE$(1,3)<>"D1:" AND FILE$(1,3)<>"D2:" THEN J$=FILE$:FILE$(1,2)="D:":FILE$(3)=J$
300 REM FILL SCREEN
310 GRAPHICS 8+16:POKE 710,15:POKE 709,0:CLOSE #1:OPEN #1,4,0,FILE$:SLOC=PEEK(88)+PEEK(89)*256
320 X=USR(ADR(LOD$),SLOC,7680):CLOSE #1
400 REM PRINT ROUTINE
410 OPEN #1,8,0,"P:":SLOC=SLOC+START
420 FOR N=A TO B STEP C:X=USR(ADR(A$),SLOC+N,ADR(PRNT$),T):? #1;GRAF$;PRNT$:NEXT N:POKE 764,255
430 IF PEEK(764)=255 THEN 430
440 POKE 764,255:GOTO 210
500 REM ERROR ROUTINE
510 ? "↰":A=PEEK(195):IF A=170 THEN ? "BAD FILENAME!"
520 IF A=138 THEN ? "DEVICE TURNED OFF OR NOT CONNECTED!"
530 IF A=5 OR A=8 OR A=12 THEN ? "INPUT ERROR!"
540 ? "ERROR ";A;" @ ";PEEK(186)+PEEK(187)*256
550 FOR N=1 TO 500:X=USR(ADR("h%●▔E▕◆")):NEXT N:RUN
600 REM PRINTER CODES
601 GRAF$="␛K@♥":LPRINT "␛A◢":KLR$="␛@":A=0:B=39:C=1:START=7640:RETURN
602 GRAF$="␛S0192":LPRINT "␛>␛T16␛N":KLR$="␛<␛A␛N":A=39:B=0:C=-1:START=0:RETURN
603 GRAF$="␛S0192":LPRINT "␛[␛T16␛N":KLR$="␛]␛A␛N":A=39:B=0:C=-1:START=0:RETURN
1000 REM *****SELF DELETING STRING WRITER SECTION*****
1010 RESTORE :? "↰120"
1020 ? "130 LOD$=";CHR$(34);:POKE 766,1:FOR N=1 TO 28:READ A:? CHR$(A);:NEXT N:?
1030 ? "140 A$=";CHR$(34);:FOR N=1 TO 81:READ A:? CHR$(A);:NEXT N:?
1040 ? 1000:? 1010:? 1020:? 1030:? 1040:? 1050:? 1060:? 1070:? 1080:? 1090:? 1100
1050 ? :? "MOVE CURSOR TO LINE NUMBERS":? "THEN PRESS RETURN":? "THEN SAVE AND RUN AGAIN":POKE 766,0
1060 DATA 104,169,7,141,82,3,104,141,85,3,104,141,84,3,104,141,89,3,104,141,88,3,162,16,32,86,228,96
1070 DATA 104,104,133,204,104,133,203,104,133,206,104,133,205,160,0,132,207,104,104,133,208,160,0,177,203,201,0
1080 DATA 208,2,169,154,201,13,208,2,169,12,164,207,145,205,200,132,207,192,192,240,32,165,208,201,2,176,13,56
1090 DATA 165,203,233,40,133,203,176,214,198,204,144,210,24,165,203,105,40,133,203,144,201,230,204,176,197,96
1100 REM ␛=ESC,ESC ↰=ESC,SHIFT+CLEAR ◢=CTRL+H ●=CTRL+T ▕=CTRL+B ▔=INV,CTRL+M ◆=CTRL+. ♥=CTRL+,
