Gemini 10X Font Maker (FONTMAKR.BAS)

Gemini 10X Font Maker by James Duffin, 109

Description

Gemini 10X Font Maker by James Duffin, 109

From the Antic disk of March 1985 (Vol. 3 No. 11).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 13.3 KB

Dialect
Atari BASIC
Lines
301
Variables
S, PX, X, PY, Y, PZ, Z, SPV, SDV, SVV, STV, IN, D, CHORG, C, T(, SUM, SCL, SCH, OX, OY, TEXTL, TEXTH, FILE$, IN$, INP$, ORG, E, CIO$, N$, I, E$, DLL, DLH, RAMTOP, DL, TEXT, SC
BASIC listing (301 lines)
10 REM GEMINI 10X FONT MAKER
15 REM BY JAMES DUFFIN
20 REM ANTIC MAGAZINE
30 GOSUB 2690:REM EXPLANATION
40 GOSUB 2190:REM MEMORY MAP
50 GOSUB 2290:REM IOCB'S AND DIM'S
60 GOSUB 2340:REM SCREEN SETUP
70 POKE 731,90:GOTO 640
80 REM MAIN LOOP
90 REM (1) MOVE CURSOR
100 S=STICK(0):IF S=15 THEN GOTO 240
110 PX=X:PY=Y:PZ=Z
120 X=X+(S=5 OR S=6 OR S=7)-(S=9 OR S=10 OR S=11):Y=Y+(S=5 OR S=9 OR S=13)-(S=6 OR S=10 OR S=14)
130 IF X>11 THEN X=3
140 IF X<3 THEN X=11
150 IF Y>9 THEN Y=3
160 IF Y<3 THEN Y=9
170 LOCATE X,Y,Z
180 IF PZ=43 THEN POSITION PX,PY:? "+"
190 IF PZ=20 THEN POSITION PX,PY:? "●"
200 IF Z=20 THEN POSITION X,Y:? CHR$(148)
210 IF Z=43 THEN POSITION X,Y:? CHR$(171)
220 SPV=60:SDV=4:SVV=4:STV=2:GOSUB 2650
230 GOTO 80
240 REM (2) TRIGGER INPUT
250 IF STRIG(0)=1 THEN GOTO 300
255 GOSUB 3000
260 IF Z=20 THEN Z=43:POSITION X,Y:? CHR$(Z):GOTO 280
270 IF Z=43 THEN Z=20:POSITION X,Y:? CHR$(Z)
280 SPV=6:SDV=6:SVV=10:STV=1:GOSUB 2650:GOSUB 3000:GOSUB 3000
290 GOTO 80
300 REM (3) KEYBOARD INPUT
310 IN=PEEK(764):POKE 764,255:IF IN=255 THEN 360
320 IF IN=58 THEN D=1*(D=0):GOSUB 3000:GOSUB 1490
330 IF IN=42 THEN SPV=60:SDV=10:STV=2:GOSUB 2650:GOSUB 1360:GOTO 640:REM "E"=EDIT
340 IF IN=62 THEN GOSUB 1360:GOSUB 960:GOTO 640:REM "S"=SAVE
350 IF IN=0 THEN GOSUB 1360:GOSUB 1120:GOTO 640:REM "L"=LOAD
360 REM START PRESSED
370 IF PEEK(53279)=6 THEN GOSUB 1360:GOSUB 1560:GOTO 660:REM "START"=LOAD PRINTER
380 GOTO 100
390 REM READ CHAR. TO GRID
400 X=3:D=PEEK(CHORG+10*(C-32))
410 Y=9:RESTORE 480:IF X>11 THEN SOUND 0,0,0,0:RETURN
420 T(X-2)=PEEK(CHORG+10*(C-32)+X-2)
430 IF Y<3 THEN X=X+1:GOTO 410
440 READ SUM
450 IF T(X-2)>=SUM THEN T(X-2)=T(X-2)-SUM:POSITION X,Y:? "●"
460 IF T(X-2)<=0 THEN X=X+1:GOTO 410
470 Y=Y-1:GOTO 430
480 DATA 64,32,16,8,4,2,1
490 REM PLOT CHAR POINTS
500 POKE 88,SCL:POKE 89,SCH:POKE 87,8:FOR X=3 TO 11:FOR Y=3 TO 12:COLOR 0:PLOT OX+X,OY+Y:NEXT Y:NEXT X:X=3
510 Y=9:RESTORE 580:IF X>11 THEN POKE 88,TEXTL:POKE 89,TEXTH:POKE 87,0:COLOR 32:PLOT 1,1:RETURN
520 T(X-2)=PEEK(CHORG+10*(C-32)+X-2)
530 IF Y<3 THEN X=X+1:GOTO 510
540 READ SUM
550 IF T(X-2)>=SUM THEN T(X-2)=T(X-2)-SUM:COLOR 1:PLOT OX+X,OY+Y+2*D
560 IF T(X-2)<=0 THEN X=X+1:GOTO 510
570 Y=Y-1:GOTO 530
580 DATA 64,32,16,8,4,2,1
590 REM CHAR. LINE?
600 IF C>=32 AND C<=62 THEN X=3+C-32:Y=15:OX=10*(C-32):OY=-1:D=PEEK(CHORG+10*(C-32))
610 IF C>=63 AND C<=93 THEN X=3+C-63:Y=16:OX=10*(C-63):OY=9:D=PEEK(CHORG+10*(C-32))
620 IF C>=94 AND C<=124 THEN X=3+C-94:Y=17:OX=10*(C-94):OY=19:D=PEEK(CHORG+10*(C-32))
630 RETURN
640 REM SELECT CHAR. TO EDIT
650 POSITION 16,5:? "*":POSITION 16,7:? " ":POSITION 16,9:? " ":POSITION 16,11:? " "
660 X=3:Y=15:LOCATE X,Y,Z
670 POSITION X,Y:? CHR$(Z+128*(Z<128)):GOSUB 2680
680 S=STICK(0):IF S=15 THEN GOTO 800
690 PX=X:PY=Y:PZ=Z
700 X=X+(S=5 OR S=6 OR S=7)-(S=9 OR S=10 OR S=11):Y=Y+(S=5 OR S=9 OR S=13)-(S=6 OR S=10 OR S=14)
710 IF X>33 THEN X=3
720 IF X<3 THEN X=33
730 IF Y>17 THEN Y=15
740 IF Y<15 THEN Y=17
750 LOCATE X,Y,Z
760 POSITION PX,PY:? CHR$(PZ)
770 SPV=60:SDV=10:SVV=6:STV=2:GOSUB 2650
780 POSITION X,Y:? CHR$(Z+128*(Z<128))
790 GOTO 680
800 REM EXIT CHAR. SELECT
810 IF STRIG(0)=1 THEN GOTO 880
815 GOSUB 3000
820 SPV=81:SDV=10:SVV=6:STV=2:GOSUB 2650
830 C=Z-128*(Z>128):GOSUB 590:GOSUB 390:GOSUB 490
840 X=3:Y=3:LOCATE X,Y,Z:POSITION X,Y:SPV=47:SDV=10:SVV=6:STV=2:GOSUB 2650
850 ? CHR$(Z+128*(Z<128))
860 IF STRIG(0)=0 THEN GOTO 860
870 GOTO 80
880 REM START PRESSED
890 IF PEEK(53279)=6 THEN GOSUB 1560:REM "START"=LOAD PRINTER
900 REM KEYBOARD INPUT
910 IN=PEEK(764):POKE 764,255:IF IN=255 THEN 950
920 IF IN=62 THEN POSITION X,Y:? CHR$(Z):GOSUB 960:GOTO 640:REM "S"=SAVE
930 IF IN=0 THEN POSITION X,Y:? CHR$(Z):GOSUB 1120:GOTO 640:REM "L"=LOAD
940 IF IN=58 THEN D=1*(D=0):GOSUB 1490
950 GOTO 680
960 REM SAVE FONT
970 POKE 712,218
980 POSITION 16,5:? " ":POSITION 16,7:? " ":POSITION 16,9:? "*":POSITION 16,11:? " ":POSITION 16,13:? " "
990 FILE$="":IN$="":INP$=" Save Filename   ":GOSUB 1990
1000 POSITION 18,13:? "START Load Printer"
1010 TRAP 2140
1020 OPEN #1,8,0,FILE$:GOSUB 3000:POKE 850,11
1030 POSITION 4,19:? "Saving Font...Please Stand By.   "
1040 POKE 852,0:POKE 853,ORG:POKE 710,8:POKE 712,8
1050 POKE 856,0:POKE 857,4
1060 E=USR(ADR(CIO$),16)
1070 POKE 852,SCL:POKE 853,SCH
1075 GOSUB 3000
1080 POKE 856,0:POKE 857,5
1090 E=USR(ADR(CIO$),16)
1095 GOSUB 3000
1100 CLOSE #1:POKE 712,12:POKE 710,12:TRAP 40000:POSITION 4,19:? "                                     "
1110 GOSUB 2840:RETURN
1120 REM LOAD FONT
1130 POKE 712,218:N$=""
1140 POSITION 16,5:? " ":POSITION 16,7:? " ":POSITION 16,9:? " ":POSITION 16,11:? "*":POSITION 16,13:? " "
1150 FILE$="":IN$="":INP$=" Load Filename   ":GOSUB 1990
1160 POSITION 18,13:? "START Load Printer"
1170 TRAP 2140
1180 OPEN #1,4,0,FILE$:GOSUB 3000:POKE 850,7
1185 N$=FILE$(3)
1190 POSITION 4,19:? "Loading Font...Please Stand By.  "
1200 POKE 852,0:POKE 853,ORG:POKE 710,8:POKE 712,8
1210 POKE 856,0:POKE 857,4
1220 E=USR(ADR(CIO$),16)
1230 POKE 852,SCL:POKE 853,SCH
1240 POKE 856,0:POKE 857,5
1250 E=USR(ADR(CIO$),16)
1255 GOSUB 3000
1260 REM SHOW EDITED CHAR'S
1270 C=32
1280 GOSUB 590:IF C>124 THEN 1340
1290 POSITION X,Y:? CHR$(C)
1300 FOR I=1 TO 9:T(I)=PEEK(CHORG+10*(C-32)+I)
1310 IF T(I)<>0 THEN POSITION X,Y:? CHR$(C+128):I=9
1320 NEXT I
1330 C=C+1:GOTO 1280
1340 CLOSE #1:POKE 710,12:POKE 712,12:TRAP 40000:POSITION 4,19:? "                                     "
1350 GOSUB 2840:RETURN
1360 REM CHAR. TO RAM
1370 FOR I=1 TO 9:T(I)=0:NEXT I
1380 X=3
1390 Y=3:IF X>11 THEN GOTO 1470
1400 IF Y>9 THEN GOTO 1450
1410 LOCATE X,Y,Z:IF Z=20 OR Z=148 THEN GOTO 1430
1420 POSITION X,Y:? "+":Y=Y+1:GOTO 1400
1430 T(X-2)=T(X-2)+(Y=3)+2*(Y=4)+4*(Y=5)+8*(Y=6)+16*(Y=7)+32*(Y=8)+64*(Y=9)
1440 POSITION X,Y:? "+":Y=Y+1:GOTO 1400
1450 POKE CHORG+10*(C-32)+X-2,T(X-2)
1460 X=X+1:GOTO 1390
1470 GOSUB 590:GOSUB 490
1480 RETURN
1490 REM DESCENDER
1500 POSITION 16,5:? " ":POSITION 16,7:? "*":POSITION 16,9:? " ":POSITION 16,11:? " ":POSITION 16,13:? " "
1510 SPV=60-D*20:SDV=10:SVV=6:STV=2:GOSUB 2650
1520 IF D=1 THEN POSITION 30,7:? "on/off":POKE CHORG+10*(C-32),1
1530 IF D=0 THEN POSITION 30,7:? "on/off":POKE CHORG+10*(C-32),0
1540 POSITION 16,5:? "*":POSITION 16,7:? " ":POSITION 16,9:? " ":POSITION 16,11:? " ":POSITION 16,13:? " "
1550 RETURN
1560 REM LOAD PRINTER
1570 POSITION 16,5:? " "
1580 POKE 712,56:POSITION 5,13:? "Is The Printer Ready (Y/N) ?      ":GOSUB 2680
1590 POKE 764,255
1600 IN=PEEK(764):IF IN=255 THEN GOTO 1600
1610 GOSUB 2680
1620 IF IN=43 THEN POKE 764,255:GOTO 1650:REM "Y"
1630 IF IN=35 THEN POKE 764,255:GOTO 1970:REM "N"
1640 GOTO 1590
1650 TRAP 1910:OPEN #4,8,0,"P:":POSITION 5,13:? " Downloading Font...Please Wait "
1660 REM LOAD PRINTER RAM NORMAL CHAR
1670 PRINT #4;E$;CHR$(42);CHR$(0);
1680 C=32:REM DOWNLOAD NEW CHAR'S
1690 IF C>124 THEN GOTO 1750
1700 FOR I=1 TO 9:T(I)=PEEK(CHORG+10*(C-32)+I):NEXT I:D=PEEK(CHORG+10*(C-32))
1710 SUM=T(1)+T(2)+T(3)+T(4)+T(5)+T(6)+T(7)+T(8)+T(9):IF SUM=0 THEN C=C+1:GOTO 1690:REM CHAR. THERE?
1720 PRINT #4;E$;CHR$(42);CHR$(1);CHR$(C);CHR$(D);
1730 PRINT #4;CHR$(T(1));CHR$(T(2));CHR$(T(3));CHR$(T(4));CHR$(T(5));CHR$(T(6));CHR$(T(7));CHR$(T(8));CHR$(T(9));
1740 C=C+1:GOTO 1690
1750 REM SELECT DOWNLOADED CHAR'S
1760 PRINT #4;E$;CHR$(36);CHR$(1);
1770 REM PRINT CHARACTERS?
1780 POKE 712,102:POSITION 5,13:? "Print Characters? (Y/N):         ":GOSUB 2680
1790 POKE 764,255
1800 IN=PEEK(764):IF IN=255 THEN GOTO 1800
1810 IF IN=43 THEN POKE 764,255:GOTO 1840:REM "Y"
1820 IF IN=35 THEN POKE 764,255:GOTO 1960:REM "N"
1830 GOTO 1800
1840 REM PRINT
1850 PRINT #4:PRINT #4,FILE$:PRINT #4
1860 PRINT #4,:FOR I=32 TO 94:PRINT #4;CHR$(I);:NEXT I
1870 PRINT #4
1880 PRINT #4,:FOR I=95 TO 124:PRINT #4;CHR$(I);:NEXT I
1890 PRINT #4:PRINT #4
1900 GOTO 1960
1910 REM TRAP PRINTER
1920 FOR I=1 TO 3
1930 POKE 712,0:POSITION 9,19:? "PRINTER NOT CONNECTED !":GOSUB 2680
1940 POKE 712,66:POSITION 5,19:? "                                   ":GOSUB 3000
1950 NEXT I:TRAP 40000
1960 CLOSE #4
1970 POKE 712,12:POSITION 5,13:? "             START Load Printer ":GOSUB 2840
1980 POSITION 16,5:? "*":GOSUB 2680:RETURN
1990 REM DISK DIRECTORY
2000 GRAPHICS 0:POKE 710,218:POKE 712,218:POKE 709,0:POKE 752,1:TRAP 2080
2010 POSITION 13,0:? "DISK DIRECTORY"
2020 OPEN #1,6,0,"D:*.FNT"
2030 INPUT #1,IN$
2050 IF ASC(IN$(1,1))>46 THEN 2030
2060 IF IN$(3,9)="AUTORUN" THEN 2030
2070 ? :? "           ";IN$(1,14);:GOTO 2030
2080 CLOSE #1:TRAP 2140:GOSUB 2840
2090 POSITION 7,22:? INP$;
2095 POSITION 25,22:? N$:POSITION 24,22
2100 INPUT IN$:IF IN$(1,2)<>"D:" THEN FILE$(1,2)="D:":FILE$(3,20)=IN$
2110 IF IN$(1,2)="D:" THEN FILE$=IN$
2115 FOR I=1 TO LEN(FILE$):IF FILE$(I,I)="." THEN FILE$(I)=".FNT":POP :GOTO 2120
2116 NEXT I
2117 FILE$(I-1)=".FNT"
2120 POKE 560,DLL:POKE 561,DLH:POKE 88,TEXTL:POKE 89,TEXTH:POKE 710,12:IN$=""
2130 POKE 709,4:RETURN
2140 POKE 560,DLL:POKE 561,DLH:POKE 88,TEXTL:POKE 89,TEXTH:POKE 710,8:POKE 712,8:IN$="":POKE 709,4
2150 CLOSE #1
2160 POSITION 4,19:? "     Cannot ";INP$(2,5);" Font!               ":GOSUB 2680
2170 GOSUB 3000:GOSUB 3000:POKE 710,12:POKE 712,12
2180 POP :TRAP 40000:POSITION 4,19:? "                               ":GOTO 640
2190 REM MEMORY MAP
2200 RAMTOP=PEEK(106):ORG=RAMTOP-48
2210 CHORG=256*ORG
2220 POKE 88,0:POKE 89,ORG:? CHR$(125):REM CLEAR CHARACTER MEMORY
2230 DLL=0:DLH=RAMTOP-44:DL=DLL+256*DLH
2240 TEXTL=0:TEXTH=RAMTOP-40:TEXT=TEXTL+256*TEXTH
2250 POKE 88,0:POKE 89,TEXTH:? CHR$(125):REM CLEAR TEXT MEMORY
2260 SCL=0:SCH=RAMTOP-32:SC=SCL+256*SCH
2270 POKE 88,0:POKE 89,SCH:? CHR$(125):REM CLEAR SCREEN MEMORY
2280 RETURN
2290 REM IOCB'S AND DIM'S
2300 DIM T(9):DIM E$(5):E$=CHR$(27)
2310 DIM IN$(20),FILE$(20),CIO$(7),N$(17)
2320 CIO$="hhh*LVd":D=0
2330 RETURN
2340 REM SCREEN SETUP
2350 GRAPHICS 0:POKE 709,4:POKE 710,12:POKE 712,12:POKE 752,1:GOSUB 2840
2360 POKE DL,112:POKE DL+1,112:POKE DL+2,112:POKE DL+3,66:POKE DL+4,TEXTL:POKE DL+5,TEXTH
2370 FOR I=6 TO 24:POKE DL+I,2:NEXT I
2380 POKE DL+25,79:POKE DL+26,SCL:POKE DL+27,SCH
2390 FOR I=28 TO 59:POKE DL+I,15:NEXT I
2400 POKE DL+58,65:POKE DL+59,DLL:POKE DL+60,DLH
2410 POKE 560,DLL:POKE 561,DLH:POKE 88,TEXTL:POKE 89,TEXTH:POKE 87,0
2420 FOR I=39968 TO 40000:POKE I,0:NEXT I
2430 ? :? :? " ◢         "
2440 ? "▕+++++++++ "
2450 ? "▕+++++++++ "
2460 ? "▕+++++++++ "
2470 ? "▕+++++++++ "
2480 ? "▕+++++++++ "
2490 ? "▕+++++++++ "
2500 ? "▕+++++++++◢"
2510 ? " ▔▔▔▔▔▔▔▔▔ "
2520 POSITION 18,3:? "KEYBOARD COMMANDS"
2530 POSITION 18,5:? "E Edit Next Character"
2540 POSITION 18,7:? "D Descender on/off"
2550 POSITION 18,9:? "S Save Font"
2560 POSITION 18,11:? "L Load Font"
2570 POSITION 3,11:? "Dot Matrix"
2580 POSITION 5,13:? "                              "
2590 POSITION 9,0:? "GEMINI 10X FONT MAKER":POSITION 15,1:? "by James Duffin"
2600 POSITION 3,15:FOR I=32 TO 62:? CHR$(I);:NEXT I
2610 POSITION 3,16:FOR I=63 TO 93:? CHR$(I);:NEXT I
2620 POSITION 3,17:FOR I=94 TO 124:? CHR$(I);:NEXT I
2630 DIM INP$(17)
2640 RETURN
2650 SOUND 0,SPV,SDV,10:POKE 20,0
2660 IF PEEK(20)<STV THEN 2660
2670 SOUND 0,0,0,0:RETURN
2680 POKE 544,100
2682 SOUND 0,35,14,INT(PEEK(544)/15):IF PEEK(544)>0 THEN 2682
2684 SOUND 0,0,0,0:POKE 66,0:RETURN
2690 REM EXPLANATION
2700 GRAPHICS 0:POKE 712,30:POKE 710,30:POKE 709,0:POKE 752,1:GOSUB 2840
2710 ? :? "The Gemini 10X Font Maker":? "             by JAMES DUFFIN":? "   is a program which allows you to"
2720 ? "make your own character sets and":? "download them to a Gemini 10X printer."
2730 ? "Once downloaded, the printer will use this font until switched off."
2740 ? :? "IMPORTANT! When making the dot image":? "of a character, horizontal dots must"
2750 ? "have one space between them, but":? "vertical dots need not."
2760 ? :? "Use the joystick and button to select":? "the character to edit, and then use"
2770 ? "the joystick and button to make the":? "dot image. Press D to toggle the"
2780 ? "descender mode on/off, and E to store"
2790 ? "the image and edit the next character."
2800 ? "      PRESS ANY KEY TO BEGIN"
2810 IF PEEK(764)=255 THEN 2810
2830 POKE 764,255:RETURN
2840 REM DISABLE BREAK KEY
2850 I=PEEK(16):IF I>127 THEN I=I-128:POKE 16,I:POKE 53774,I
2860 POKE 77,0
2870 RETURN
3000 POKE 20,0
3010 IF PEEK(20)<3 THEN 3010
3020 RETURN