Custom Print (CUSTOM.BAS)

Custom Print by Matthew Ratcliff, 54

Description

Custom Print by Matthew Ratcliff, 54

From the Antic disk of March 1985 (Vol. 3 No. 11).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 6.6 KB

Dialect
Atari BASIC
Lines
146
Variables
CS, CST$, PROG$, CSET, OSET, A$, B$, C$, F$, TTL$, DRV$, A, CL, DENS, VS, CRCTL, PG, LINES, HI, LO, I, LN, ER
BASIC listing (146 lines)
1 REM CUSTOM PRINT
2 REM BY MATTHEW J.W. RATCLIFF
3 REM ANTIC MAGAZINE
5 CS=PEEK(106)-8:POKE 106,CS:GRAPHICS 0:DIM CST$(20):CST$=""
10 DIM PROG$(182):CSET=0:GRAPHICS 0:OSET=PEEK(756)
20 DATA 104,240,10,201,2,240,7,170,104,104,202,208,251,96
30 DATA 104,133,213,104,133,212,104,104,133,216,160,0,177,212
40 DATA 230,212,208,2,230,213,160,0,132,217,201,128,144,4
50 DATA 41,127,198,217,170,133,218,224,96,176,11,169,64,224
60 DATA 32,144,2,169,224,24,101,218,133,214,169,0,133,215
70 DATA 162,3,6,214,38,215,202,208,249,24,173,244,2,101
80 DATA 215,133,215,160,0,240,2,208,187,162,0,177,214,230
90 DATA 214,208,2,230,215,69,217,149,228,232,224,8,208,239
100 DATA 162,0,22,228,42,232,224,8,208,248,153,220,0,200
110 DATA 192,8,208,238,162,0,181,220,201,155,208,4,169,151
120 DATA 149,220,232,224,8,208,241,162,112,169,11,157,66,3
130 DATA 169,220,157,68,3,169,0,157,69,3,169,0,157,73
140 DATA 3,169,8,157,72,3,32,86,228,198,216,208,166,96
150 RESTORE 20:FOR I=1 TO 182:READ A:PROG$(I,I)=CHR$(A):NEXT I:PROG$(136,136)=CHR$(155)
160 DIM A$(480),B$(240),C$(240),F$(20),TTL$(120),DRV$(8):OPEN #2,4,0,"K:"
170 ? "↰":POKE 710,114:? "↓||CUSTOM PRINT || By Mat Rat "
175 GOSUB 900
180 ? "Directory of  TEXT-FILES  DISK":GOSUB 2400
190 ? "Text filename to  CUSTOM-PRINT...":GOSUB 2510
250 ? "↰":? "CHARACTERS PER LINE:"
260 ? "[1] 60 [2] 120 [3] 240 ";:GET #2,A:? CHR$(27);CHR$(A)
270 A=A-48:IF A<1 OR A>3 THEN ? "↰VALUE ERROR!":GOTO 260
280 CL=A*60:IF A=3 THEN CL=CL+60
290 ON A GOTO 300,310,320
300 DENS=ASC("K"):GOTO 330:REM NORMAL DENSITY GFX
310 DENS=ASC("L"):GOTO 330:REM DUAL DENSITY GFX
320 DENS=ASC("z"):REM QUAD DENSITY GFX
330 ? "↰":? "VERTICAL LINE SPACING:"
340 ? "[1] Stacked [2] Single"
350 ? "(Stacked will appear"
360 ? "exactly as ATARI screen) ";:GET #2,A:? CHR$(27);CHR$(A)
370 A=A-48:VS=8*A:IF A<1 OR A>2 THEN ? "↰RANGE ERROR":GOTO 340
380 ? "↰":? "TEXT CONTROL:"
390 ? "[1] Center Text [2] Block Left"
400 ? "[3] Block Right (block left normal)";:GET #2,A:? CHR$(27);CHR$(A)
410 A=A-48:IF A<1 OR A>3 THEN ? "↰RANGE ERROR":GOTO 390
420 CRCTL=A:? :? "Type a TITLE & press RETURN key ":INPUT TTL$:PG=1
422 IF LEN(TTL$)>0 THEN GOTO 428
424 ? "Skip Perforations (Y/N) ";:TRAP 424:GET #2,A:IF A=ASC("N") THEN PG=0:GOTO 430
425 IF A=ASC("Y") THEN PG=-1:GOTO 430
426 GOTO 424
428 IF PG THEN TTL$(LEN(TTL$)+1)="  PG "
430 ? "↰":? "* GET PRINTER READY *"
440 ? "AND BE SURE DISK WITH LISTED"
450 ? "FILE ";F$;" IS READY "
460 ? "AND PRESS RETURN KEY ";:GET #2,A:? :?
462 ? "PRESS  ESCAPE KEY  TO ABORT "
465 IF CSET<>0 THEN POKE 756,CSET
470 TRAP 800:CLOSE #1:OPEN #1,4,0,F$
480 CLOSE #7:OPEN #7,8,0,"P:"
490 ? #7;"␛A";CHR$(VS);:REM SET VERTICAL SPACING
500 ? #7;"␛N";CHR$(0);:? #7;"␛O":REM SET FORM SKIP FEATURE TO 0, COUNT FORMS
510 TRAP 800:LINES=0:IF PG THEN GOSUB 2200
520 IF LINES>=48*(VS=16)+96*(VS=8)-8 AND PG<>0 THEN GOSUB 2180
522 IF PEEK(764)<>255 THEN GET #2,A:IF A=27 THEN GOTO 830
525 INPUT #1,A$:B$="":LINES=LINES+1:IF LEN(A$)>CL THEN LINES=LINES+1:B$=A$(CL+1):A$(CL+1)=""
530 IF A$="" THEN GOTO 665
540 REM SET UP A$ ACCORDING TO PRINT CONTROL
550 ON CRCTL GOTO 560,640,600
560 A=INT((CL-LEN(A$))/2):IF A=0 THEN 640
570 C$(1)=" ":C$(240)=" ":C$(2)=C$
580 C$(A)=A$:A$="":A$=C$:GOTO 640
600 IF LEN(A$)=CL THEN 640
610 C$=A$:A$(1)=" "
620 A$(480)=" ":A$(2)=A$
630 A$(CL-LEN(C$))=C$
640 A=8*LEN(A$):HI=INT(A/256):LO=A-256*HI
650 ? #7;CHR$(27);CHR$(DENS);CHR$(LO);CHR$(HI);
660 A=USR(ADR(PROG$),ADR(A$),LEN(A$))
665 ? #7
670 IF B$<>"" THEN A$=B$:B$="":GOTO 550
680 GOTO 520
800 IF PEEK(195)=136 THEN GOTO 850
810 ? "* ERROR ";PEEK(195);" AT LINE ";PEEK(186)+256*PEEK(187);" *"
820 CLOSE #1:CLOSE #7:GOTO 175
830 POKE 756,OSET:CLOSE #1:CLOSE #7:? " * PRINT ABORTED *"
840 GOTO 860
850 POKE 756,OSET:? :? "* END OF FILE REACHED *"
860 ? :? "[1] More lists [2] Quit ";:GET #2,A:A=A-48
870 IF A<1 OR A>2 THEN ? "↰RANGE ERROR":GOTO 860
875 CLOSE #1:CLOSE #7
880 ON A GOTO 170,890
890 POKE 106,PEEK(106)+8:GRAPHICS 0:? "* END *":END
900 ? :? "[1] Load & Print with"
910 ? "    custom character set."
920 ? "[2] Print with ATARI Set."
922 IF CST$<>"" THEN ? "[3] Use ";CST$;" to print."
930 TRAP 960:GET #2,A:A=A-48:? A
940 IF A=1 THEN 970
950 IF A=2 THEN CSET=0:RETURN
955 IF A=3 THEN CSET=CS:RETURN
960 ? "↰INPUT ERROR, 1 OR 2 ?":GOTO 930
970 ? "Directory of C-SET disk:":GOSUB 2400
980 ? " C-SET  Filename to load...":GOSUB 2500
1100 CSET=CS:? "↰":FOR I=0 TO 255:? CHR$(27);CHR$(I);:NEXT I:?
1110 ? "Working..."
1120 TRAP 2000
1130 CLOSE #3:OPEN #3,4,0,F$:CST$=F$
1140 POKE 756,CSET
1150 POKE 882,7:POKE 884,0:POKE 885,CSET
1160 POKE 888,0:POKE 889,128
1170 A=USR(ADR("h"0LVd"))
1180 LN=256*PEEK(889)+PEEK(888):ER=PEEK(883):CLOSE #3:POKE 756,OSET
1190 IF LN<>1024 THEN ? "↰↰ NOT VALID CHARACTER SET >";F$:GOTO 900
1200 IF ER<>136 THEN ? "* I/O ERROR ";ER;" *":GOTO 900
1210 POKE 756,OSET:RETURN
2000 ? "↰I/O ERROR ";PEEK(195);
2010 ? " AT LINE ";PEEK(186)+256*PEEK(187):CLOSE #1:CLOSE #2:CLOSE #3:END
2100 TRAP 2130
2110 CLOSE #5:OPEN #5,4,0,F$
2120 CLOSE #5:RETURN
2130 CLOSE #5:F$="":RETURN
2180 IF LINES=VS*6-8 OR LINES=0 THEN ? #7
2190 FOR I=1 TO 6+(VS=8):? #7:NEXT I:? #7;"␛A";CHR$(8):? #7;"␛A";CHR$(VS);
2200 ? #7:? #7:IF PG<0 THEN GOTO 2270
2210 A=LEN(TTL$)*8:HI=INT(A/256):LO=A-256*HI
2220 ? #7;CHR$(27);CHR$(DENS);CHR$(LO);CHR$(HI);
2230 A=USR(ADR(PROG$),ADR(TTL$),LEN(TTL$))
2240 A$=STR$(PG):PG=PG+1:A=8*LEN(A$):HI=INT(A/256):LO=A-256*HI
2250 ? #7;CHR$(27);CHR$(DENS);CHR$(LO);CHR$(HI);
2260 A=USR(ADR(PROG$),ADR(A$),LEN(A$))
2270 ? #7:? #7
2290 LINES=1:RETURN
2400 TRAP 2400:? "DRIVE # (1-4) ";:GET #2,A:A=A-48:? A
2410 IF A<1 OR A>4 THEN 2400
2420 DRV$="D":DRV$(2,2)=STR$(A):DRV$(3,3)=":"
2430 F$=DRV$:F$(4)="*.*"
2440 CLOSE #1:TRAP 2000:OPEN #1,6,0,F$:I=1:? "↰":? "   DISK DIRECTORY FOR DRIVE #(";CHR$(A+176);")    "
2450 INPUT #1,A$:? A$;:IF A$(4,5)=" F" THEN 2490
2460 IF INT(I/2)=I/2 THEN ? :GOTO 2480
2470 ? " |";
2480 I=I+1:GOTO 2450
2490 CLOSE #1:? :? "           > END O↑|↓←F FILE <          ":RETURN
2500 ? "From drive # ";DRV$
2510 ? "<TYPE filename.ext ONLY & PRESS RTN>"
2520 ? "Press RTN only for another DIRECTORY"
2530 TRAP 2530:INPUT A$:IF LEN(A$)=0 THEN GOSUB 2400:GOTO 2500
2540 F$=DRV$:F$(4)=A$
2550 TRAP 2560:CLOSE #5:OPEN #5,4,0,F$:CLOSE #5:GOTO 2570
2560 CLOSE #5:? "↰File ";F$;" does not exist":GOTO 2510
2570 RETURN