Home Loan Analysis v1.1 (APX) (HOMELOAN.BAS)

Home Loan Analysis v1.1 (APX) by Jim F. Skinner, 107

Description

Home Loan Analysis v1.1 (APX) by Jim F. Skinner, 107

From the Antic disk of February 1985 (Vol. 3 No. 10).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 13.0 KB

Dialect
Atari BASIC
Lines
369
Variables
M, LNS, I$, E, LN, A, B, C, D, T(, Y, TI, MM, LINECNT, PA$, SYEARS, SFFINT, ABAL, DASH$, II$, II, X$, FINT, P$, FESS, BAL, B$, JJ, TP$, TOTP, TI$, TOTI, BORDR$, GSND, P, Q, FINISH, X, G, LINEPRINT$, BEGIN, SJJ, SELECT, FFINT, YEARS, SII, I, J, R, PAY, KEY1, ADJ, BAMT, SBAL, BCALC, DPMT, MPMT, AVAL, AYEAR, ARATE, FVAL, FYEAR, PVBAMT, KSND, BSND, Y(, KEY, RETRN$, F
BASIC listing (369 lines)
10 REM <<<     HOME LOAN      >>>
20 REM <<<     ANALYSIS       >>>
30 REM <<<   COPYRIGHT 1982   >>>
40 REM <<<   J. F. SKINNER    >>>
50 REM <<<     VERSION 1.1    >>>
60 REM <<< FOR ANTIC MAGAZINE >>>
70 GOTO 3350
80 REM INPUT ROUTINE
82 IF M=13 THEN GOTO 1180
84 IF M=19 THEN GOTO 2330
90 TRAP 3460:OPEN #1,4,0,"K:":LNS=1:POSITION 28,M:? "1          ":POKE 752,0:POSITION 28,M:I$="1"
100 GET #1,E:POKE 694,0
110 IF E=155 THEN POKE 764,255:POKE 752,1:CLOSE #1:GOTO 290
120 IF E=126 AND LNS>1 THEN LNS=LNS-1:I$(LNS)=" ":PRINT CHR$(E);
130 IF LNS>LN THEN 100
140 IF E<46 OR E=47 OR E>57 THEN 100
150 I$(LNS,LNS)=CHR$(E):? CHR$(E);:LNS=LNS+1
160 GOTO 100
170 REM MOVE CURSOR
180 A=PEEK(53279):B=STRIG(0):C=PEEK(632):D=PEEK(764)
190 IF A=6 OR B=0 THEN GOTO 320
200 IF D<>255 THEN LN=T(M):GOTO 80
210 POSITION 26,M:? "  "
220 IF A=5 OR C=13 THEN M=M+1
230 IF A=3 OR C=14 THEN M=M-1
240 IF M>19 THEN M=4
250 IF M<4 THEN M=19
260 POSITION 26,M:? "=>"
270 FOR Y=1 TO 45:NEXT Y
280 GOTO 170
290 ON M GOTO 170,170,170,1670,2000,1720,2050,1780,2090,1890,1830,1950,1180,2130,2180,2230,2280,2380,2330
300 POKE 764,255:GOTO 170
310 REM CALCULATE
320 IF M=19 THEN GOTO 2330
330 IF M=18 THEN GOSUB 2920:GOSUB 2430:GOSUB 2760:GOTO 170
340 IF M=4 THEN GOSUB 2920:GOSUB 2590:GOTO 170
350 GOSUB 2920:GOSUB 2430:GOSUB 2690
360 IF M=13 THEN GOTO 1180
370 GOTO 170
380 RETURN :REM POKE 77,0: POKE 580,1:ZZZ=PEEK(16):IF PEEK(16)>128 THEN POKE 16,ZZZ-128:POKE 53774,ZZZ-128
390 POKE 764,255:POKE 702,64:POKE 694,0:RETURN
400 SOUND 1,55,10,5:FOR TI=1 TO 75:NEXT TI:SOUND 1,0,0,0:RETURN :REM KSND
410 SETCOLOR 4,4,6:SOUND 1,100,12,5
420 FOR TI=1 TO 100:NEXT TI:SOUND 1,0,0,0:FOR TI=1 TO 500:NEXT TI:SETCOLOR 4,0,12:RETURN :REM BSND
430 SOUND 1,100,100,100:FOR TI=1 TO 75:NEXT TI:SOUND 1,0,0,0:RETURN :REM GSND
440 REM PRINT SCREEN
450 MM=0
460 IF LINECNT>=17 THEN GOTO 490
470 LINECNT=LINECNT+1
480 GOTO 580
490 LINECNT=6
500 GRAPHICS 0:POKE 752,1:GOSUB 380
510 SETCOLOR 1,14,12:SETCOLOR 2,10,5:SETCOLOR 4,0,12
520 ? "        AMORTIZATION SCHEDULE"
530 ? ,"    $";PA$;" Month"
540 ? "     ";SYEARS;" YEARS    ";SFFINT;"%";"     $";ABAL
550 ? DASH$
560 ? " DATE","PRIN","INT","BAL"
570 ? DASH$
580 REM PRINT SCREEN LINE
590 II$=STR$(II):IF LEN(II$)=1 THEN II$(1,1)=" ":II$(2,2)=STR$(II)
600 TRAP 640
610 X$=STR$(FINT):IF X$(LEN(X$)-1,LEN(X$)-1)="." THEN X$(LEN(X$)+1)="0"
620 IF X$(LEN(X$)-2,LEN(X$)-2)<>"." THEN X$(LEN(X$)+1)=".00"
630 GOTO 645
640 X$(LEN(X$)+1)=".00"
645 TRAP 665
650 TRAP 664
652 P$=STR$(FESS):IF P$(LEN(P$)-1,LEN(P$)-1)="." THEN P$(LEN(P$)+1)="0"
660 IF P$(LEN(P$)-2,LEN(P$)-2)<>"." THEN P$(LEN(P$)+1)=".00"
662 GOTO 670
664 P$(LEN(P$)+1)=".00"
665 P$(LEN(P$)+1)=".00"
670 IF BAL=0 THEN B$="0.00":GOTO 700
675 TRAP 695
680 B$=STR$(BAL):IF B$(LEN(B$)-1,LEN(B$)-1)="." THEN B$(LEN(B$)+1)="0"
690 IF B$(LEN(B$)-2,LEN(B$)-2)<>"." THEN B$(LEN(B$)+1)=".00"
692 GOTO 700
695 B$(LEN(B$)+1)=".00"
700 POSITION 1,LINECNT:? II$;"-";JJ;:POSITION 10,LINECNT:? P$;
705 POSITION 19,LINECNT:? X$;:POSITION 28,LINECNT:? B$;
710 IF LINECNT>=17 THEN GOSUB 730
720 RETURN
730 TRAP 775
740 POKE 764,255
750 ? " ":? DASH$
760 TP$=STR$(TOTP):IF TP$(LEN(TP$)-1,LEN(TP$)-1)="." THEN TP$(LEN(TP$)+1)="0"
770 IF TP$(LEN(TP$)-2,LEN(TP$)-2)<>"." THEN TP$(LEN(TP$)+1)=".00"
772 GOTO 777
775 TP$(LEN(TP$)+1)=".00"
777 TRAP 795
780 TI$=STR$(TOTI):IF TI$(LEN(TI$)-1,LEN(TI$)-1)="." THEN TI$(LEN(TI$)+1)="0"
790 IF TI$(LEN(TI$)-2,LEN(TI$)-2)<>"." THEN TI$(LEN(TI$)+1)=".00"
792 GOTO 797
795 TI$(LEN(TI$)+1)=".00"
797 TRAP 40000
800 POSITION 1,19:? "TOTAL":POSITION 8,19:? TP$:POSITION 19,19:? TI$
810 ? "┌────────────────────────────────────┐ ";
820 ? BORDR$;
830 ? BORDR$;
840 ? "└────────────────────────────────────┘";
850 POSITION 2,21:? " P=print RETURN=go to the next year";
860 POSITION 2,22:? "   START=return to the MAIN MENU   ";
870 IF BAL=0 THEN POSITION 11,21:? " This is the last year.    ";
880 POKE 764,255:POKE 53279,7
890 A=PEEK(53279):B=STRIG(0):D=PEEK(764)
900 IF A=6 THEN POP :GOSUB GSND:GOTO 3080
910 IF B=0 THEN GOTO 940
920 IF D=10 THEN GOSUB GSND:TRAP 3300:P=0:Q=20:GOSUB 960:GOTO 800
930 IF D<>12 THEN GOTO 890
940 IF JJ>=FINISH THEN POP :GOSUB GSND:GOTO 3080
950 RETURN
960 REM COPY SCREEN TO PRINTER
970 POKE 764,255:D=255:A=7
980 POSITION 2,21:? " Position Paper and press SPACE-BAR ";
990 POSITION 2,22:? " (Press OPTION to Exit Print Mode)  ";
1000 D=PEEK(764):A=PEEK(53279)
1010 IF D=33 THEN POKE 764,255:D=255:GOTO 1040
1020 IF A=3 THEN POKE 53279,7:A=7:GOTO 1160
1030 GOTO 1000
1040 POKE 764,255
1050 POSITION 2,21:? "                                   ";
1060 IF MM=1 THEN LPRINT "       HOME LOAN ANALYSIS"
1070 FOR Y=P TO Q
1080 FOR X=1 TO 38
1090 POSITION X,Y
1100 GET #5,G
1110 LINEPRINT$(X+1,X+1)=CHR$(G)
1120 NEXT X
1130 A=PEEK(53279):IF A=3 THEN POKE 53279,7:POP :GOTO 1160
1140 LPRINT LINEPRINT$
1150 NEXT Y
1160 POKE 764,255
1170 RETURN
1180 REM SCREEN OUTPUT
1190 BEGIN=SJJ:FINISH=SJJ+SYEARS+2
1200 POKE 752,0:POKE 764,255
1210 IF SELECT<SJJ THEN SELECT=SJJ
1220 TRAP 3080
1230 POKE 201,9:LINECNT=20:GOSUB 380
1240 GOSUB 2430
1250 FFINT=SFFINT:YEARS=SYEARS:II=SII:JJ=SJJ
1260 POSITION 3,21:? "         CALCULATING               ";:POSITION 24,21:? JJ;
1270 POSITION 2,22:? " (Press OPTION to Exit Calculation) ";
1280 II=II-1
1290 FOR I=1 TO YEARS+1
1300 FOR J=1 TO 12
1310 II=II+1
1320 IF II<13 THEN GOTO 1340
1330 II=1:JJ=JJ+1
1340 FINT=R*BAL
1350 FINT=INT((FINT+5E-03)*100)/100
1360 FINT=FINT*100:FINT=INT(FINT):FINT=FINT/100
1370 FESS=PAY-FINT:TOTP=TOTP+FESS:TOTI=TOTI+FINT
1380 KEY1=PEEK(53279):IF KEY1<6 THEN POP :KEY1=7:GOTO 3080
1390 IF FESS>=BAL THEN GOTO 1450
1400 BAL=BAL-FESS:POKE 752,1
1410 IF JJ<SELECT THEN POSITION 3,21:? "         CALCULATING ";JJ;"         ";:SOUND 1,5,10,5:SOUND 1,0,0,0
1420 IF JJ>=SELECT AND JJ<=FINISH THEN GOSUB 440
1430 NEXT J
1440 NEXT I
1450 ADJ=FESS-BAL:FESS=BAL:BAL=0:TOTP=TOTP-ADJ
1460 GOSUB 440:IF LINECNT<17 THEN GOSUB 730
1470 POSITION 1,20:? "LAST PAYMENT   ";FESS+FINT;
1480 IF BAMT>0 THEN ? " + ";BAMT;" BALLOON";
1490 GOTO 3080
1500 RETURN
1510 REM START
1520 GRAPHICS 2+16:GOSUB 380
1530 SETCOLOR 0,9,4:SETCOLOR 1,13,4
1540 SETCOLOR 2,4,6:SETCOLOR 3,0,0
1550 SETCOLOR 4,12,12
1560 PRINT #6:PRINT #6
1570 PRINT #6;"        HOME  "
1575 PRINT #6;"        LOAN  "
1580 PRINT #6;"      ANALYSIS":PRINT #6
1590 PRINT #6;"   COPYRIGHT 1982 "
1600 PRINT #6;"   BY JIM SKINNER "
1610 PRINT #6
1620 PRINT #6;"     press start  "
1630 COLOR 4:PLOT 0,0:DRAWTO 0,11:DRAWTO 19,11:DRAWTO 19,0:DRAWTO 0,0
1640 IF PEEK(53279)<>6 THEN GOTO 1640
1650 TRAP 4:POKE 764,255
1660 GOTO 3080
1670 REM ENTER PURCHASE PRICE
1710 SBAL=VAL(I$):GOTO 3250
1720 REM ENTER INTEREST RATE
1750 IF I$>"50" THEN GOTO 3460
1755 SFFINT=VAL(I$):I$=""
1760 R=SFFINT/1200:BCALC=1
1770 GOTO 3250
1780 REM ENTER LENGTH
1810 SYEARS=VAL(I$):BCALC=1
1820 GOTO 3250
1830 REM ENTER FIRST MONTH
1860 SII=VAL(I$)
1870 IF SII<1 OR SII>12 THEN SII=1
1880 GOTO 3250
1890 REM ENTER FIRST YEAR
1920 SJJ=VAL(I$)
1930 GOTO 3250
1950 REM ENTER AMORTIZATION YEAR
1980 SELECT=VAL(I$)
1990 GOTO 3250
2000 REM ENTER DOWN PAYMENT
2030 DPMT=VAL(I$):IF SBAL<DPMT THEN GOTO 3460
2040 GOTO 3250
2050 REM ENTER BALLOON PAYMENT
2080 BAMT=VAL(I$):BCALC=1:GOTO 3250
2090 REM ENTER MONTHLY PAYMENT
2120 MPMT=VAL(I$):PA$=I$:GOSUB 2920:GOSUB 2590:GOTO 3250
2130 REM ENTER APPRAISED VALUE
2160 AVAL=VAL(I$)
2170 GOTO 3250
2180 REM <<<ENTER APPRAISED YEAR>>>
2210 AYEAR=VAL(I$)
2220 GOTO 3250
2230 REM ENTER RATE OF APPRECIATION
2260 ARATE=VAL(I$):GOSUB 2760
2270 GOTO 3250
2280 REM ENTER RESALE VALUE
2310 FVAL=VAL(I$)
2320 GOTO 3250
2330 REM SELECT PRINT SCREEN
2340 TRAP 3300:P=4:Q=18:MM=1
2350 GOSUB 960
2360 MM=0
2370 GOTO 3250
2380 REM ENTER RESALE YEAR
2410 FYEAR=VAL(I$)
2420 GOTO 3250
2430 REM CALC MONTHLY PAYMENT
2440 TRAP 2560
2450 BAL=(SBAL-DPMT)-PVBAMT:R=SFFINT/1200
2460 ABAL=BAL:FINISH=SYEARS+SJJ
2470 IF BAMT=0 THEN PAY=(1+R)^(SYEARS*12):GOTO 2490
2480 PAY=(1+R)^((SYEARS*12)-1)
2490 PAY=R*PAY*BAL/(PAY-1)
2492 TRAP 2527
2500 PAY=INT((PAY+5E-03)*100)/100
2510 PA$=STR$(PAY):IF PA$(LEN(PA$)-1,LEN(PA$)-1)="." THEN PA$(LEN(PA$)+1)="0"
2520 IF PA$(LEN(PA$)-2,LEN(PA$)-2)<>"." THEN PA$(LEN(PA$)+1)=".00"
2525 GOTO 2528
2527 PA$(LEN(PA$)+1)=".00"
2528 TRAP 40000
2530 POSITION 28,9:? "          "
2540 POSITION 28,9:? PA$
2550 RETURN
2560 TRAP 3460:IF PEEK(195)=11 THEN GOTO 3460
2570 PA$(LEN(PA$)+1)=".00"
2580 GOTO 2530
2590 REM CALCULATE PURCHASE PRICE
2600 R=SFFINT/1200
2610 IF BAMT=0 THEN PAY=(1+R)^(SYEARS*12):GOTO 2630
2620 PAY=(1+R)^((SYEARS*12)-1)
2630 BAL=(MPMT*(PAY-1))/(R*PAY)
2640 BAL=INT(BAL+0.5)
2650 SBAL=BAL+PVBAMT+DPMT
2660 POSITION 28,4:? "          ";
2670 POSITION 28,4:? SBAL;
2680 RETURN
2690 REM CALC APPRECIATION RATE
2700 ARATE=(FVAL-AVAL)/(FYEAR-AYEAR)
2710 ARATE=(ARATE/AVAL)*100
2720 ARATE=INT((ARATE+5E-03)*100)/100
2730 POSITION 28,16:? "          ";
2740 POSITION 28,16:? ARATE;
2750 RETURN
2760 REM CALC FUTURE RE VALUE
2770 FVAL=AVAL:IF FYEAR=AYEAR THEN GOTO 2890
2780 IF FVAL=0 THEN GOTO 2890
2790 IF FYEAR<AYEAR THEN GOTO 2850
2800 FOR X=1 TO (FYEAR-AYEAR)
2810 FVAL=FVAL+(FVAL*(ARATE/100))
2820 FVAL=INT(FVAL)
2830 NEXT X
2840 GOTO 2890
2850 FOR X=1 TO (AYEAR-FYEAR)
2860 FVAL=FVAL-(FVAL*(ARATE/100))
2870 FVAL=INT(FVAL)
2880 NEXT X
2890 POSITION 28,17:? "          ";
2900 POSITION 28,17:? FVAL;
2910 RETURN
2920 REM CALCULATE PV OF BALLOON
2930 POKE 752,1:POKE 53279,7:IF BAMT=0 THEN PVBAMT=0:GOTO 3050
2940 IF BCALC=0 THEN GOTO 3050
2950 POSITION 3,21:? "   Calculating Present Value       ";
2960 POSITION 3,22:? "     of Balloon Payment            ";
2970 PVBAMT=BAMT
2980 FOR X=1 TO (SYEARS*12):SOUND 1,5,10,5:SOUND 1,0,0,0
2990 POSITION 27,22:? ((SYEARS*12)-X);"  ";
3000 A=PEEK(53279)
3010 PVBAMT=(PVBAMT-(PVBAMT*R))
3020 IF PVBAMT<0 OR A=3 THEN PVBAMT=0:POP :GOTO 3040
3030 NEXT X:BCALC=0
3040 PVBAMT=INT((PVBAMT+5E-03)*100)/100
3050 POSITION 3,21:? "OPTION=up SELECT=down START=compute";
3060 POSITION 3,22:? "Type a number and then press RETURN";
3070 RETURN
3080 REM FORMAT AT SCREEN
3090 TOTP=0:TOTI=0:MM=1
3100 POKE 82,1:POKE 83,39:GRAPHICS 0:GOSUB 380
3110 POKE 752,1:POKE 764,255
3120 SETCOLOR 1,14,12:SETCOLOR 2,10,5:SETCOLOR 4,0,12
3130 ? "┌────────────────────────────────────┐ ";
3140 ? BORDR$;
3150 ? BORDR$;
3160 ? "└────────────────────────────────────┘";
3170 POSITION 6,1:? "     HOME LOAN ANALYSIS"
3180 POSITION 6,2:? "  (c) 1982 by Jim Skinner"
3190 GOSUB 3530
3200 POSITION 1,20
3210 ? "┌────────────────────────────────────┐ ";
3220 ? BORDR$;
3230 ? BORDR$;
3240 ? "└────────────────────────────────────┘";
3250 GOSUB KSND
3260 POKE 752,1
3270 POSITION 3,21:? "OPTION=up SELECT=down START=compute";
3280 POSITION 3,22:? "Type a number and then press RETURN";
3290 GOTO 170
3300 REM PRINTER OFF LINE
3310 POSITION 2,22:? "    Please turn your printer on.   ";:GOSUB BSND
3320 POKE 764,255
3330 IF MM=1 THEN GOTO 3080
3340 GOTO 850
3350 REM INITIALIZE
3360 CLR :POKE 65,1:POKE 764,255
3370 OPEN #5,4,0,"S:"
3380 SETCOLOR 1,0,0:SETCOLOR 2,0,0
3390 KSND=400:BSND=410:GSND=430
3400 DIM I$(10),II$(2),Y(3),LINEPRINT$(40),X$(13),P$(13),B$(13),PA$(13),TP$(13),TI$(13)
3410 SBAL=55000:DPMT=5000:SFFINT=12.5:SYEARS=30:SII=1:SJJ=1980:KEY=255:KEY1=7:LN=7:AYEAR=1980:FYEAR=1990
3420 BEGIN=1980:FINISH=SJJ+SYEARS:SELECT=1985:TOTP=0:TOTI=0:AVAL=55000:FVAL=90000:M=4:MPMT=533.63
3425 DIM BORDR$(39),RETRN$(35),DASH$(38),T(19)
3430 LINEPRINT$(1)=" ":LINEPRINT$(40)=" ":LINEPRINT$(2)=LINEPRINT$
3432 BORDR$="|                                    | "
3434 RETRN$="       then press RETURN           "
3436 DASH$="--------------------------------------"
3440 GOSUB 380:GOSUB 3710:GOSUB 2690:GOSUB 2430
3450 GOTO 1510
3460 REM INPUT ERROR
3470 I$="0":POP
3480 POSITION 3,21:? "  I couldn't read the last number  ";
3490 POSITION 3,22:? "  you typed...  Please try again.  ";
3500 CLOSE #1
3510 GOSUB BSND:TRAP 40000
3520 GOTO 3080
3530 REM MAIN SCREEN
3540 POSITION 3,4:? "Purchase Price.........  ";SBAL
3550 POSITION 3,5:? "Down Payment...........  ";DPMT
3560 POSITION 3,6:? "Interest  Rate.........  ";SFFINT
3570 POSITION 3,7:? "Balloon Payment........  ";BAMT
3580 POSITION 3,8:? "Length of Loan in Years  ";SYEARS
3590 POSITION 3,9:? "Monthly Payment........  ";PA$
3600 POSITION 3,10:? "Year  of First Payment.  ";SJJ
3610 POSITION 3,11:? "Month of First Payment.  ";SII
3620 POSITION 3,12:? "Amortization Year......  ";SELECT
3630 POSITION 3,13:? "Calculate  Amortization  Schedule "
3640 POSITION 3,14:? "Appraised Value........  ";AVAL
3650 POSITION 3,15:? "Appraised Year.........  ";AYEAR
3660 POSITION 3,16:? "Appreciation rate......  ";ARATE
3670 POSITION 3,17:? "Resale Value...........  ";FVAL
3680 POSITION 3,18:? "Resale Year............  ";FYEAR
3690 POSITION 3,19:? "Print  This Information  Print"
3700 RETURN
3710 RESTORE :FOR X=1 TO 19:READ F:T(X)=F:NEXT X:RETURN
3720 DATA 1,1,1,7,7,5,7,2,6,4,2,4,1,7,4,5,7,4,1