Currency Capers (CURRCAPE.BAS)

Currency Capers by John W. Goolevitch, 45

Description

Currency Capers by John W. Goolevitch, 45

From the Antic disk of February 1985 (Vol. 3 No. 10).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 5.5 KB

Dialect
Atari BASIC
Lines
119
Variables
PLACE1$, PLACE2$, CUR1$, CUR2$, R, V, P, OPTION, C, A, B, NUM, N1, N2, RATE1, RATE2, AMOUNT, TOTAL, T, N, ADD
BASIC listing (119 lines)
5 REM CURRENCY CAPERS
6 REM BY JOHN W. GOOLEVITCH
7 REM ANTIC MAGAZINE
10 DIM PLACE1$(15),PLACE2$(15),CUR1$(8),CUR2$(8)
100 GRAPHICS 17
110 POSITION 2,3:? #6;"CURRENT"
120 POSITION 5,6:? #6;"FOREIGN"
130 POSITION 8,9:? #6;"EXCHANGE"
140 POSITION 11,12:? #6;"PROGRAM"
150 POSITION 6,14:? #6;"by"
160 POSITION 1,18:? #6;"john w. goolevitch"
170 POSITION 3,22:? #6;"<PRESS ANY KEY>"
180 SETCOLOR 2,4,6:SETCOLOR 0,10,6:GOSUB 200
190 SETCOLOR 0,4,6:SETCOLOR 2,10,6:GOSUB 200:GOTO 180
200 R=INT(RND(0)*150)+75:FOR V=13 TO 1 STEP -2:SOUND 0,R,10,V:NEXT V:SOUND 0,0,0,0:FOR P=1 TO 30:NEXT P
210 IF PEEK(764)=255 THEN RETURN
220 POP :POKE 764,255:SOUND 0,0,0,0
230 GRAPHICS 0:POKE 752,1:SETCOLOR 2,0,0:? :? "      CURRENT FOREIGN EXCHANGE   "
240 ? :? " FOR THIS PROGRAM, YOU WILL NEED"
250 ? "TODAY'S NEWSPAPER."
260 ? :? " THERE, YOU WILL FIND THE LIST OF"
270 ? "CURRENT FOREIGN EXCHANGES."
280 ? :? " WITH THIS LIST AND THIS PROGRAM."
290 ? "WE WILL BE ABLE TO CALCULATE AND"
300 ? "EXCHANGE MONEYS TO AND FROM ANY"
310 ? "CURRENCY YOU WISH."
320 ? :? "          PRESS ANY KEY   ":GOSUB 440
330 IF PEEK(764)=255 THEN 330
340 POKE 764,255:? "↰"
350 POKE 752,1:SETCOLOR 2,0,0:? :? "         EXCHANGE OPTIONS   "
360 ? :? "1. HOME COUNTRY TO FOREIGN COUNTRY"
370 ? :? "2. FOREIGN COUNTRY TO HOME COUNTRY"
380 ? :? "3. FOREIGN COUNTRY TO FOREIGN COUNTRY"
390 ? :? "     SELECT (1, 2  OR 3):";:GOSUB 440:INPUT OPTION
400 POKE 764,255:GOSUB 410:GOTO 530
410 REM SCROLL OFF SCREEN WITH SOUND
420 FOR R=1 TO 23:? " ":SOUND 0,R*8,8,10:NEXT R:SOUND 0,0,0,0:RETURN
440 REM INPUT SOUND
450 C=INT(RND(1)*20)*10+40
460 FOR A=C TO C-15 STEP -2
470 SOUND 0,A,10,A-C+15:SOUND 1,A+10,10,A-C+15
480 NEXT A
490 FOR R=1 TO 2:FOR B=12 TO 0 STEP -3
500 SOUND 0,A,10,B:SOUND 1,A+10,10,B
510 NEXT B:NEXT R
520 RETURN
525 REM DISPLAY 44 COUNTRIES
530 GRAPHICS 0:SETCOLOR 2,13,2:SETCOLOR 4,13,2
540 POKE 752,1:RESTORE 2000
550 READ NUM,PLACE1$,CUR1$:SOUND 0,(NUM+10)*1.5,10,10:SOUND 1,(NUM+10)*3,10,10
560 IF NUM<10 THEN POSITION 3,NUM-1
570 IF NUM>9 THEN POSITION 2,NUM-1
580 ? NUM;".";PLACE1$
590 IF NUM<22 THEN SOUND 0,0,0,0:SOUND 1,0,0,0:GOTO 550
620 READ NUM,PLACE1$,CUR1$:SOUND 0,(NUM+10)*1.5,10,10:SOUND 1,(NUM+10)*3,10,10
630 POSITION 20,NUM-23
640 ? NUM;".";PLACE1$
650 IF NUM<44 THEN SOUND 0,0,0,0:SOUND 1,0,0,0:GOTO 620
660 GOSUB 440
670 IF OPTION=1 THEN GOSUB 790:GOTO 690
680 ? "     COUNTRY TO EXCHANGE FROM  :";
690 INPUT N1
700 RESTORE 2000:GOSUB 440
710 READ NUM,PLACE1$,CUR1$:IF NUM=N1 THEN 730
720 GOTO 710
730 IF OPTION=2 THEN GOSUB 790:GOTO 750
740 ? "      COUNTRY TO EXCHANGE TO   :";
750 INPUT N2
760 RESTORE 2000:GOSUB 410:? "↰"
770 READ NUM,PLACE2$,CUR2$:IF NUM=N2 THEN 800
780 GOTO 770
790 ? "         YOUR HOME COUNTRY     :";:RETURN
800 GOSUB 1140
810 IF OPTION=1 THEN RATE1=1:GOTO 860
820 ? "WHAT IS THE CURRENT EXCHANGE RATE"
830 ? "OF THE ";PLACE1$;" ";CUR1$;:INPUT RATE1
840 GOSUB 1140
850 IF OPTION=2 THEN RATE2=1:GOTO 890
860 ? "WHAT IS THE CURRENT EXCHANGE RATE"
870 ? "OF THE ";PLACE2$;" ";CUR2$;:INPUT RATE2
880 GOSUB 1140
890 ? "HOW MANY ";PLACE2$;" ";CUR2$;"'S"
900 ? "WOULD YOU LIKE TO BUY ";:INPUT AMOUNT:GOSUB 440
910 IF OPTION=1 THEN TOTAL=RATE1*RATE2*AMOUNT
920 IF OPTION=2 THEN TOTAL=AMOUNT/RATE1
930 IF OPTION=3 THEN T=AMOUNT/RATE1:TOTAL=T*RATE2
940 TOTAL=INT(100*TOTAL+0.5)/100
950 ? :? :? AMOUNT;" ";PLACE2$;" ";CUR2$;"'S"
960 ? :? "WILL COST YOU":? :?
970 IF TOTAL<10 THEN N=0.1:GOTO 1010
980 IF TOTAL<100 THEN N=1:GOTO 1010
990 IF TOTAL<1000 THEN N=11:GOTO 1010
1000 N=251
1010 FOR ADD=0 TO TOTAL STEP N:? "↑";ADD:SOUND 0,2,12,10:SOUND 0,0,0,0:FOR P=1 TO 5:NEXT P:NEXT ADD
1020 ? "↑";TOTAL;" ";PLACE1$;" ";CUR1$;"'S"
1030 POSITION 2,21:? "PRESS OPTION FOR DIFFERENT COUNTRIES"
1040 POSITION 2,22:? "PRESS SELECT TO ALTER AMOUNT ENTERED"
1070 POSITION 8,21:? "OPTION":FOR P=1 TO 5:NEXT P
1080 POSITION 8,22:? "SELECT":FOR P=1 TO 5:NEXT P:POKE 53279,0
1090 FOR R=1 TO 25:IF PEEK(53279)=3 THEN RESTORE 2000:GOSUB 410:GRAPHICS 0:SETCOLOR 2,13,2:GOTO 340
1100 IF PEEK(53279)=5 THEN GOSUB 410:? "↰":GOTO 880
1110 NEXT R:GOTO 1030
1140 POKE 82,0:GOSUB 440
1150 ? :? "┌──────────────────────────────────────┐"
1160 ? :? "└──────────────────────────────────────┘"
1170 POKE 82,2:? "↑↑↑↑↑":RETURN
1990 REM DATA FOR 44 COUNTRIES
2000 DATA 1,AUSTRALIA,DOLLAR,2,AUSTRIA,SHILLING,3,BAHAMAS,DOLLAR,4,BARBADOS,DOLLAR,5,BELGIUM,FRANC,6,BERMUDA
2010 DATA DOLLAR,7,CANADA,DOLLAR,8,CAYMAN,DOLLAR,9,CHINA,RENMINBI,10,CZECHOSLOVAKIA,CROWN,11,DENMARK,KRONER,12
2020 DATA EAST CARIBBEAN,DOLLAR,13,FIJI,DOLLAR,14,FINLAND
2025 DATA FINNMARK,15,FRANCE,FRANC,16,GERMANY(WEST),MARK,17,GREECE
2030 DATA DRACHMA,18,GUYANA,DOLLAR,19,HONG KONG,DOLLAR,20
2035 DATA INDIA,RUPEE,21,INDONESIA,RUPIAH,22,IRELAND,PUNT,23,ITALY
2040 DATA LIRE,24,JAMAICA,DOLLAR,25,JAPAN,YEN,26,KUWAIT,DINAR,27,MALAYSIA,DOLLAR,28,MEXICO,PESO,29,NETHERLANDS
2050 DATA GUILDER,30,NEW ZEALAND,DOLLAR,31,NORWAY,KRONER,32
2055 DATA PAKISTAN,RUPEE,33,PORTUGAL,ESCUDO,34,SAUDI ARABIA,RIYA
2060 DATA 35,SINGAPORE,DOLLAR,36,SOUTH AFRICA,RAND,37,SPAIN,PESETA,38,SWEDEN,KRONER,39,SWITZERLAND,FRANC
2070 DATA 40,TANZANIA,SCHILLING,41,TRINIDAD&TOBAGO,DOLLAR,42,UNITED STATES,DOLLAR,43,UNITED KINGDOM,POUND
2080 DATA 44,VENEZUELA,BOLIVAR