programming demo (SAVER.BAS)

programming demo (BASIC with ASM source)

Description

programming demo (BASIC with ASM source)

From the Antic disk of December 1984 (Vol. 3 No. 8).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 1.1 KB

Dialect
Atari BASIC
Lines
28
Variables
NAME$, N$, X, A, BEGIN, LENGTH, C, FILL$, FIND$, DD
BASIC listing (28 lines)
0 DIM NAME$(1000),N$(100),FIND$(57)
1 GOSUB 8999
5 ? :? "ENTER TOTAL NUMBER OF WORDS":? "AND/OR PHRASES":INPUT DD
9 REM STORE WORDS IN STRING
10 ? "↰TYPE IN ";DD;" WORDS OR PHRASES:":? "MAXIMUM LENGTH OF EACH IS 100 --"
11 ? "MAXIMUM TOTAL LENGTH IS 1000 CHARS"
12 FOR X=1 TO DD
13 INPUT N$
14 N$(1,1)=CHR$(128+ASC(N$)):REM CONVERT 1ST CHAR TO INVERSE
15 NAME$(LEN(NAME$)+1)=N$
20 NEXT X
24 REM STORE INVERSE CHAR AT END OF STRING
25 NAME$(LEN(NAME$)+1)=CHR$(128)
100 ? :? NAME$
101 REM SEARCH AND OUTPUT AN ITEM
102 ? :? "LOCATE WHICH WORD?(1-";DD;")"
103 INPUT C
105 BEGIN=USR(ADR(FIND$),ADR(NAME$),C)
110 LENGTH=PEEK(1)
115 ? :? CHR$(ASC(NAME$(BEGIN,BEGIN))-128);:BEGIN=BEGIN+1
116 IF LENGTH=1 THEN 102
120 ? NAME$(BEGIN,BEGIN+LENGTH-2)
999 GOTO 102
8998 REM STORE ML PROGRAM IN A STRING
8999 RESTORE 9000:FOR X=1 TO 57:READ A:FIND$(X,X)=CHR$(A):NEXT X:RETURN
9000 DATA 104,104,133,1,104,133,0,104,133,3,104,133,2,169,1,133,212,160,0,132,213,177,0,16,18
9005 DATA 198,2,208,14,165,3,208,8,200,177,0,16,251,132,1,96,198,3,230,212,208,2,230
9010 DATA 213,230,0,208,224,230,1,208,220