Bannertizer, print utility (BANNER.BAS)

Bannertizer, print utility by John Bauman, 30

Description

Bannertizer, print utility by John Bauman, 30

From the Antic disk of December 1984 (Vol. 3 No. 8).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 3.6 KB

Dialect
Atari BASIC
Lines
92
Variables
BINCOD(, P$, S$, X$, PIXMAP(, BANR(, BANNR$, ROWMAP(, HV, C$, CS, L, C, CRVAL, OFSET, START, P, PIXPOS, FST, S, VPOS, LST, HPOS, ST, PRT, PIXL, HPIX, VPIX, VPIS, X, ROWSUM, Y, H, DL, N, INV
BASIC listing (92 lines)
5 REM BANNERTIZER
6 REM BY JOHN BAUMAN
7 REM ANTIC MAGAZINE
10 DIM BINCOD(8),P$(80),S$(1),X$(1),PIXMAP(64),BANR(255),BANNR$(255),ROWMAP(8)
20 REM TITLE SCREEN
30 GOSUB 4000
40 TRAP 40
50 REM GET BANNER
60 GRAPHICS 0:SETCOLOR 2,0,0
65 PRINT "INPUT 0 FOR A HORIZONTAL BANNER":PRINT "INPUT 1 FOR A VERTICAL BANNER":INPUT HV
70 IF HV<>0 AND HV<>1 THEN GOTO 10
80 TRAP 80
90 GRAPHICS 0:SETCOLOR 2,0,0:PRINT "ENTER VALUE FROM 1 (SMALL) TO 10 (BIG) TO DETERMINE CHARACTER SIZE. ":INPUT CS
100 IF CS<1 OR CS>10 THEN GOTO 12
110 TRAP 110
120 GRAPHICS 0:SETCOLOR 2,0,0:PRINT "INPUT LINE TO BANNERTIZE.":? "THEN PRESS RETURN."
130 ? :INPUT BANNR$:L=LEN(BANNR$)
140 POSITION 13,10:? "NOW PRINTING:":POSITION 1,12:? "  ";
145 FOR C=1 TO L
150 CRVAL=ASC(BANNR$(C,C))
160 REM ADJUST CHARACTER VALUE
170 GOSUB 1000
180 REM CALCULATE OFFSET OF CHAR FROM START OF CHARACTER SET AND THEN CALCULATE ACTUAL START OF CHAR IN SET
190 OFSET=CRVAL*8
200 START=57344+OFSET
210 REM STORE THE BINARY VALUES FOR THE CHARACTER IN ARRAY BINCOD
220 FOR P=1 TO 8
230 BINCOD(P)=PEEK(START+P-1)
240 NEXT P
250 REM CREATE A PIXEL MAP OF THE CHARACTER
260 GOSUB 3000
280 REM PRINT OUT THE CHARACTER
290 ? BANNR$(C,C);
300 GOSUB 2000
310 NEXT C
320 GOTO 40
1000 REM CHARACTER VALUE ADJUCTMENT ROUTINE
1005 INV=0:IF CRVAL>127 THEN CRVAL=CRVAL-128:INV=1
1010 IF (CRVAL>=32 AND CRVAL<96) THEN CRVAL=CRVAL-32:GOTO 1040
1030 IF (CRVAL>=0 AND CRVAL<32) THEN CRVAL=CRVAL+64
1040 RETURN
1045 RETURN
2000 REM PRINTING ROUTINE
2010 PIXPOS=(FST*8-7):S=1
2020 FOR VPOS=FST TO LST
2030 FOR HPOS=1 TO 8
2039 REM IF THE BIT IS A 1 THEN STORE 10 ASTERISKS IN ARRAY S$, OTHERWISE STORE 10 BLANKS IN ARRAY S$
2040 IF (PIXMAP(PIXPOS)+INV=1) THEN S$="*":GOTO 2060
2050 S$=" "
2059 REM LOOP TO STORE ASTERISKS OR BLANKS IN S$
2060 FOR ST=S TO S+9:P$(ST)=S$:NEXT ST
2070 PIXPOS=PIXPOS+1:S=S+10
2080 NEXT HPOS
2090 FOR PRT=1 TO CS:LPRINT P$:NEXT PRT
2100 S=1
2110 NEXT VPOS
2120 RETURN
3000 REM ROUTINE TO CREATE A PIXEL MAP OF THE CHARACTER
3009 REM INITIALIZE POSITION POINTER FOR PIXMAP ARRAY AND SET PIXL TO VALUE OF FIRST BIT TO TEST
3010 PIXPOS=1:PIXL=128
3019 REM LOOP TO GET VALUES OF PIXELS HORIZONTALLY
3020 FOR HPIX=1 TO 8
3029 REM LOOP TO GET VALUES OF PIXELS VERTICALLY
3030 FOR VPIX=8 TO 1 STEP -1
3035 IF HV=1 THEN PIXPOS=((VPIX-1)*8+HPIX)
3039 REM TEST PIXEL: IF THE BIT IS A ONE, THEN STORE A ONE IN PIXMAP; OTHERWISE, STORE A ZERO IN PIXMAP
3040 IF BINCOD(VPIX)-PIXL>=0 THEN BINCOD(VPIX)=BINCOD(VPIX)-PIXL:PIXMAP(PIXPOS)=1:GOTO 3060
3050 PIXMAP(PIXPOS)=0
3059 REM INCREMENT PIXPOS
3060 PIXPOS=PIXPOS+1
3070 NEXT VPIX
3079 REM SET PIXL VALUE TO NEXT BIT
3080 PIXL=PIXL/2
3090 NEXT HPIX
3095 REM DETERMINE IF EACH 8 BIT ROW IN PIXMAP IS BLANK OR NOT
3100 FOR X=0 TO 7
3105 ROWSUM=0
3110 FOR Y=1 TO 8:ROWSUM=ROWSUM+PIXMAP(Y+(X*8)):NEXT Y
3120 IF ROWSUM>0 THEN ROWMAP(X+1)=1:GOTO 3140
3130 ROWMAP(X+1)=0
3140 NEXT X
3145 REM DETERMINE WHERE THE CHARACTER'S FIRST AND LAST ROWS TO BE PRINTED ARE LOCATED
3150 IF CRVAL=0 THEN FST=1:LST=8:GOTO 3190
3155 FOR X=1 TO 8:IF ROWMAP(X)<>1 THEN NEXT X
3160 FST=X-(X<>1)
3170 FOR Y=8 TO 1 STEP -1:IF ROWMAP(Y)<>1 THEN NEXT Y
3180 LST=Y
3190 RETURN
4000 GRAPHICS 2:SETCOLOR 2,0,0:DL=PEEK(560)+PEEK(561)*256:POKE DL+11,6
4010 POSITION 2,4:? #6;"THE BANNERTIZER":POSITION 2,6:? #6;"by  john bauman":POSITION 4,9:? #6;"push  start"
4020 IF PEEK(53279)=6 THEN POKE (53279),8:RETURN
4030 GOTO 4020