Omniventure (OMNIVENT.BAS)

Omniventure, game by Jerry Lemaitre, 50

Description

Omniventure, game by Jerry Lemaitre, 50

From the Antic disk of November 1984 (Vol. 3 No. 7).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 6.0 KB

Dialect
Atari BASIC
Lines
92
Variables
S, MOV, P, POS, MOV(, A$, CARRY, B$, SC, MAN, F, I, SWG, T, SK, POS(, FLAG(, CH, CH(, MST, M, M1, P1, COL(, MEN, HS, I1, MOV$, A, C$, D, B, SCR, TOP
BASIC listing (92 lines)
1 REM     ANTIC MAGAZINE
2 REM       OMNIVENTURE
3 REM    BY JERRY LEMAITRE
4 REM
80 GOSUB 9000
90 GOTO 9270
100 S=PEEK(632):MOV=0:P=PEEK(POS+MOV(S)):IF  NOT P THEN MOV=1:POKE 77,0:GOTO 300
110 IF P=141 THEN MOV=0:GOSUB 10040
120 IF P=2 OR P=3 THEN 6000
130 IF P=198 THEN POSITION 10,22:? #6;A$:CARRY=1:MOV=1:SOUND 0,12,12,8
140 IF P=199 THEN POSITION 10,22:? #6;B$:CARRY=2:MOV=1:SOUND 0,12,12,8
150 IF P=136 THEN SC=SC+100:POSITION 4,22:? #6;SC:MOV=1:SOUND 0,10,10,10
300 IF MOV THEN POKE POS,0:POS=POS+MOV(S):POKE POS,MAN
310 F=PEEK(644):IF F OR CARRY<>1 THEN 400
320 FOR I=5 TO 14:SWG=POS+MOV(I)
330 SOUND 0,I+50,8,8:IF PEEK(SWG)=2 OR PEEK(SWG)=3 THEN POKE SWG,204:SC=SC+25:POSITION 4,22:? #6;SC
340 FOR T=1 TO SK*2:IF POS(T)=SWG THEN FLAG(T)=0
350 NEXT T:NEXT I:POSITION 10,22:? #6;" NOTHING ":CARRY=0:FOR I=5 TO 14:P=POS+MOV(I):IF PEEK(P)=204 THEN POKE P,0
360 NEXT I:SOUND 0,0,0,0
400 SOUND 0,0,0,0:IF F OR CARRY<>2 THEN 500
410 FOR I=5 TO 14:SWG=POS+MOV(I)
420 SOUND 0,I+50,8,8:IF PEEK(SWG)=68 OR PEEK(SWG)=69 THEN POKE SWG,204
430 NEXT I:POSITION 10,22:? #6;" NOTHING ":CARRY=0:FOR I=5 TO 14:IF PEEK(POS+MOV(I))=204 THEN POKE POS+MOV(I),0
440 NEXT I:SOUND 0,0,0,0
500 CH=CH+1:POKE 756,CH(CH):FOR I=SK*7 TO 70:NEXT I:IF CH=1 THEN CH=-1
510 MST=MST+1:IF MST>SK*2 THEN MST=1
520 IF  NOT FLAG(MST) THEN 600
530 M=POS(MST):M1=INT(M/20):P1=INT(POS/20):MOV=(POS-P1*20>M-M1*20)-(POS-P1*20<M-M1*20)+20*(P1>M1)-20*(P1<M1)
540 P=PEEK(POS(MST)+MOV):IF P AND P<>MAN THEN 600
550 POKE POS(MST),0:POS(MST)=POS(MST)+MOV:POKE POS(MST),COL(MST)
570 IF POS=POS(MST) THEN 6000
600 GOTO 100
6000 P=0:SOUND 0,72,12,10:MEN=MEN-1:COLOR 0:PLOT 16+MEN,0:POKE POS,204:FOR I=1 TO 111:NEXT I
6010 POKE POS,203:FOR I=1 TO 222:NEXT I:SOUND 0,0,0,0:IF MEN THEN 6200
6020 POSITION 5,4:? #6;"GAME OVER":POSITION 4,6:? #6;"PRESS FIRE!"
6030 IF PEEK(644) THEN 6030
6040 IF SC>HS THEN HS=SC
6050 GOTO 90
6200 POSITION 5,5:? #6;"YOU DIED!":FOR I=0 TO 10:FOR I1=0 TO 70:SOUND 0,I1,10,10-I:NEXT I1:NEXT I:GOTO 10040
9000 DIM MOV$(39):RESTORE 9001:FOR I=1 TO 39:READ A:MOV$(I,I)=CHR$(A):NEXT I
9001 DATA 104,104,133,215,104,133,214,104,133,217,104,133,216,104,133,218,104,170,160,0,177,214,145,216
9002 DATA 200,208,4,230,215,230,217,202,208,242,198,218,16,238,96
9008 DIM A$(9),B$(9),C$(7),CH(1),MOV(15),FLAG(20),POS(20),COL(20)
9010 A$="  CLUB   ":B$=" MACHETTE":C$=" DINO"
9020 GRAPHICS 18:POSITION 7,4:? #6;C$;"-":POSITION 7,6:? #6;"VENTURE"
9030 CH(0)=PEEK(106)-8:CH(1)=CH(0)-8:D=USR(ADR(MOV$),57344,CH(0)*256,1023)
9040 FOR A=1 TO 13:FOR I=0 TO 7:READ B:POKE CH(0)*256+A*8+I,B:POKE 708,B:NEXT I:NEXT A
9050 DATA 7,15,30,56,48,0,192,192
9060 DATA 6,15,12,15,157,156,158,119
9070 DATA 0,0,195,102,60,24,0,0
9080 DATA 102,255,189,153,24,24,24,60
9090 DATA 0,4,10,20,10,30,63,0
9100 DATA 6,15,15,31,30,56,96,192
9110 DATA 16,24,24,24,24,60,24,24
9120 DATA 40,2,152,61,28,129,40,0
9130 DATA 24,60,24,60,90,24,36,36
9140 DATA 255,255,255,255,255,255,255,255
9150 DATA 0,0,24,60,60,60,60,60
9160 DATA 137,74,36,192,3,36,82,145
9170 DATA 0,32,80,136,5,2,0,0
9200 D=USR(ADR(MOV$),CH(0)*256,CH(1)*256,1023)
9210 READ A:IF A=-1 THEN RETURN
9220 FOR I=0 TO 7:READ B:POKE CH(1)*256+A*8+I,B:POKE 708,B:NEXT I:GOTO 9210
9230 DATA 2,24,60,12,15,93,156,158,119
9240 DATA 3,0,0,0,126,219,129,0,0
9250 DATA 8,20,64,25,188,29,64,18,0
9260 DATA 9,24,60,24,126,24,24,36,66
9266 DATA 13,0,2,5,136,80,32,0,0,-1
9270 MOV(5)=21:MOV(6)=-19:MOV(7)=1:MOV(9)=19:MOV(10)=-21:MOV(11)=-1:MOV(13)=20:MOV(14)=-20
9300 GRAPHICS 1:POKE 710,0:POKE 756,CH(0):POSITION 6,0:? #6;"welcome!":POSITION 6,1:? #6;"********"
9310 ? #6:? #6;" )-this is you!"
9320 ? #6:? #6;" &-club-for animals"
9330 ? #6:? #6;" '-knife-for plants"
9340 ? #6:? #6;" (-diamond-100 pts."
9350 ? #6:? #6;" ";CHR$(34);"-tyrannosaurus-25"
9360 ? #6:? #6;" #-pterodactyl-25"
9370 ? #6:? #6;" $-cypress tree"
9380 ? #6:? #6;" %-ginkgo plant"
9390 TRAP 9390:? CHR$(125);"Select Skill Level.1-10";:INPUT SK:IF SK<1 OR SK>10 OR INT(SK)<>SK THEN 0
10000 TRAP 44444:GRAPHICS 17:POKE 756,CH(0):COLOR 173:PLOT 1,1:DRAWTO 18,1:COLOR 10:PLOT 0,20:DRAWTO 19,20
10010 PLOT 0,0:DRAWTO 0,23:DRAWTO 19,23:DRAWTO 19,0:POSITION 1,21:? #6;"hs:";HS:POSITION 1,22:? #6;"sc:0"
10020 POSITION 1,0:? #6;C$;"VENTURE!":POSITION 10,21:? #6;"carrying:":POSITION 11,22:? #6;"NOTHING"
10030 POKE 708,103:POKE 709,215:POKE 710,31:POKE 711,40:POKE 712,192
10035 COLOR 137:PLOT 17,0:PLOT 18,0:MEN=3:SC=0
10040 COLOR 32:FOR I=2 TO 19:PLOT 1,I:DRAWTO 18,I:NEXT I:FOR I=0 TO 20:FLAG(I)=1:POS(I)=77:NEXT I
10050 FOR I=0 TO 150:COLOR INT(2*RND(0)+4):PLOT INT(18*RND(0)+1),INT(18*RND(0)+2):NEXT I:COLOR 32:PLOT 5,19
10060 DRAWTO 15,19:FOR I=0 TO 10-SK:COLOR INT(2*RND(0)+134):PLOT INT(18*RND(0)+1),INT(18*RND(0)+2):NEXT I
10070 COLOR 168:FOR I=0 TO 6-SK/2:PLOT INT(18*RND(0)+1),INT(18*RND(0)+2):NEXT I
10080 SCR=PEEK(88)+256*PEEK(89):TOP=SCR+40:POS=SCR+389:MAN=201:POKE POS,MAN
10090 FOR I=1 TO SK*2:COL(I)=INT(2*RND(0)+2)
10100 POS(I)=INT(360*RND(0)+40+SCR):P=PEEK(POS(I)):IF P=74 OR P=2 OR P=3 OR P=MAN THEN 10100
10110 POKE POS(I),COL(I):NEXT I:GOTO 100