Adventure Island (ADVNTISL.BAS)
Adventure Island, game by Robert Lee, 194
Description
Adventure Island, game by Robert Lee, 194
From the Antic disk of November 1984 (Vol. 3 No. 7).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 23.6 KB
- Dialect
- Atari BASIC
- Lines
- 677
- Variables
V,O,W1,A,U,T,S,N1,X,N2,X$,Y,ZZ,Z,H,B,C,D,E,F,G,I,J,K,R,Q,DS,A1,SY,YS,OX,OY,C$,E(,F(,W(,S(,TM(,T1$,T2$,M$,MX$,LL,CS,CI,CW,CO,CD,CH,GP,OLDHP,HP,X1,Y1,L,SCD,CN,FC,DC,C1,C2,W,II,F2,AC,SAC,MH,MAC,MA,MD,SCI,DR,F1,V1,V2,Z1,Z2,SCW,P,WS,MM,MN,MS,F3,VX,SCS,CT,NR,L1,OP,OCH,SG,EP,OLDLL,JX,FB,TS,QK
BASIC listing (677 lines)
0 REM ADVENTURE ISLAND BY ROBERT LEE ANTIC MAGAZINE
1 GOTO 10
2 ? :? "PRESS RETURN TO CONTINUE";:INPUT C$:? "↰":RETURN
3 V=O:FOR W1=A TO U:V=V+INT(RND(O)*T):NEXT W1:V=V+U:RETURN
4 GOSUB 340:GOTO 149
5 ? :RESTORE S+N1:FOR X=A TO N2:READ X$,Y,ZZ:? X;")";X$;:FOR Z=A TO 15-LEN(X$):? ".";:NEXT Z
6 ? Y;:IF Y<H THEN ? " ";
7 ? " GP":NEXT X
8 ? :? "'TELL ME THE # OF ITEM YOU WANT. SAY NONE IF YOU'RE DONE.'":RETURN
10 O=0:A=1:B=2:C=3:D=4:E=6:F=8:G=9:H=10:I=B*H:J=H*H:K=J*J:R=F*J:S=G*J:Q=C*E:A1=171:SY=660:YS=430
12 OX=12:OY=13:DIM C$(I),E(I),F(B),W(A),S(D),TM(A1,D),X$(120),T1$(I),T2$(I),M$(D),MX$(D)
13 GRAPHICS Q:POSITION A,D:? #E," ADVENTURE ISLAND":FOR X=A TO S:NEXT X
14 GRAPHICS O:POKE 710,254:POKE 709,244:POKE 83,37
15 ? :? "RESTORE OLD GAME(Y/N)";:INPUT C$:IF C$<>"Y" THEN GOTO Q
16 GOSUB 2950:GOSUB 2920:? :? "EXPERIENCE LEVEL: ";LL:GOSUB 640:GOSUB 630:GOSUB B:GOSUB 450:GOSUB B
17 GOSUB 92:GOSUB 380:GOTO 150
18 GOSUB 750
19 TRAP 19:? :? "EXPERIENCE LEVEL";:INPUT LL:IF LL<A THEN 19
20 T=E:U=C:GOSUB C:CS=V:GOSUB C:CI=V:GOSUB C:CW=V:GOSUB C:CO=V:GOSUB C:CD=V:GOSUB C:CH=V
40 GOSUB 640:? :? "TRY ANOTHER CHARACTER(Y/N)";:INPUT C$:IF C$="Y" THEN 20
59 GOSUB 759
64 T=F:U=C:GOSUB C:GP=V+C:GP=INT(GP*D)
65 GOSUB 630:OLDHP=HP
66 GOSUB B
90 RESTORE K+J*X1+Y1:READ L,M$,X$:GOSUB I*J
91 GOSUB 92:GOTO 130
92 RESTORE K+J*X1+Y1:READ L,M$,X$:IF LEN(X$)<>A THEN ? X$:RETURN
93 ON ASC(X$)-64 GOTO 94,95,96,97,98,99,100,101,102,103,104,106,108,109,110,111
94 ? "JELLO BRICK ROAD":RETURN
95 ? "DIMLY-LIT CAVES":RETURN
96 ? "SEEMINGLY ENDLESS ROWS OF RED DORIC COLUMNS.":RETURN
97 ? "GHOULISH COOLISH GREENISH FOREST":RETURN
98 ? "HOT MUGGY SWAMPLANDS":RETURN
99 ? "BENEATH A GREAT PINK SANDSTONE WALL":RETURN
100 ? "CURIOUS GARDEN OF WILD FLOWERS":RETURN
101 ? "A CUBICLE INSIDE THE TEMPLE":RETURN
102 ? "HALL OF MIRRORS":RETURN
103 ? "GLOWING UNDERGROUND RIVER":RETURN
104 ? "IN A NARROW CRACK-LIKE TUNNEL":RETURN
106 ? "ANCIENT WEED-OVERGROWN ROAD PAVED WITH HUGE BLOCKS OF GRANITE.":RETURN
108 ? "GOLDEN BEACH":RETURN
109 ? "HIGH WHITE CHALK CLIFFS":RETURN
110 ? "THE SHINING SEA":RETURN
111 ? "BARREN ROCKY ISLET":RETURN
120 INPUT X$:? :RESTORE 999:FOR C1=A TO Q-A:READ C$
121 IF X$=C$ THEN RETURN
122 NEXT C1:GOSUB C*J:C1=O:RETURN
125 IF CN=DC THEN ? "THIRSTY?":HP=O:GOTO 350
126 IF CN=FC THEN ? "HUNGRY?":HP=O:GOTO 350
127 CN=CN+A:RETURN
130 GOSUB 380:GOSUB H*J:IF TM(L,D)>O AND INT(RND(O)*(CD+SCD)/F)=O THEN GOSUB 340
149 GOSUB 560
150 ? :? "ENTER COMMAND: MOVE NUMBER ";CN
151 ? "EAT BY MOVE ";FC;" ";"DRINK BY MOVE ";DC:IF CN>=FC-A OR CN>=DC-A THEN ? "↰";
153 GOSUB 120:IF C1<A THEN 150
154 C2=C1:ON C1 GOSUB SY,SY,SY,SY,380,470,530,450,580,YS,YS,YS,YS,1100,1200,625,2900
155 GOSUB 125:ON C2 GOTO D,90,O,O,D,D,D,D,D,D,D,D,D,D,D,601,150
199 ? "A MAID ASKS 'WOULD YOU BE WANTIN' ANY FOOD OR DRINK'(Y/N)";:INPUT C$:IF C$="N" THEN 213
200 ? "SHE SHOWS YOU A MENU."
201 ? :? "FOOD & DRINK":GOSUB 5
205 TRAP 213:INPUT T:IF T<A OR T>N2 THEN 205
206 IF W=H THEN 211
207 RESTORE S+T+N1-A:READ X$,Y,ZZ:IF GP-Y<O THEN 210
208 FOR II=H TO I:IF E(II)<>O THEN NEXT II
209 GP=GP-Y:E(II)=N1+T-A:W=W+A:? "'O.K.'":? "'YOU HAVE ";GP;" GP CREDITS LEFT.'":F2=A:GOSUB 500:GOTO 211
210 GOSUB 629
211 GOSUB 627:GOTO 201
213 ? "THE MAID LEAVES YOU...":RETURN
270 ? "THE BLACKSMITH ASKS 'DO YOU WANT ARMOR OR WEAPONS'(Y/N)";:INPUT C$:IF C$="N" THEN 285
271 ? "HE SHOWS YOU A LIST."
272 ? :? "ARMOR & WEAPONS":GOSUB 5
277 TRAP 285:INPUT T:IF T<A OR T>G THEN 277
278 IF W=H THEN 283
279 RESTORE S+T:READ X$,Y:IF GP-Y<O THEN 281
280 GP=GP-Y:E(T)=E(T)+A:W=W+A:? "'O.K.'":? "'YOU HAVE ";GP;" GP CREDITS LEFT.'":GOTO 283
281 GOSUB 629
283 GOSUB 627:GOTO 272
285 ? "HE LEAVES YOU...":RETURN
300 ? :? "N NORTH":? "S SOUTH":? "E EAST":? "W WEST":? "X EXAMINE":? "G GET":? "D DROP"
305 ? "I INVENTORY & STATUS":? "F ????":? "A ATTACK WITH SWORD/SPEAR":? "T THROW SPEAR"
310 ? "FP FIRE POISON ARROW":? "FS FIRE SILVER ARROW":? "ET EAT":? "DK DRINK":? "QT QUIT":? "SG SAVE"
315 RETURN
340 IF TM(L,D)=O THEN 353
341 ? "YOU'RE UNDER ATTACK!":AC=G+SAC:IF E(G)>O THEN AC=AC-A
342 Z=O:FOR X=E TO F:IF E(X)>O THEN Z=(X-5)*B
344 NEXT X:AC=AC-Z
346 RESTORE R+TM(L,C):READ X$,MH,MAC,MA,MD:X=I-AC-MH:FOR Y=A TO INT(RND(O)*MA)+A
348 IF INT(RND(O)*I)+A+SCD<X THEN ? "CRUNCH! A GLANCING BLOW!":GOTO 352
349 ? "OW! YOU'VE BEEN HURT!":HP=HP-(INT(RND(O)*MD)+A):? "HIT POINTS LEFT: ";HP
350 IF HP<A THEN ? "↰YOU'RE DEAD.↰":FOR X=A TO J:NEXT X:POP :GOTO 601
352 NEXT Y
353 RETURN
360 MX$=M$:X=O:IF INT(RND(O)*(CI+SCI)/B)>O THEN 370
362 FOR Y=A TO D:IF M$(Y,Y)<>"O" THEN X=X+A
363 NEXT Y:IF X=O THEN 370
366 FOR Y=A TO INT(RND(O)*X)+A
367 Z=INT(RND(O)*D)+A:IF MX$(Z,Z)="O" THEN 367
369 MX$(Z,Z)="O":NEXT Y
370 ? "YOU CAN MOVE: ";
371 FOR DR=A TO D:IF MX$(DR,DR)="O" THEN 377
372 ON DR GOTO 373,374,375,376
373 ? " N ";:GOTO 377
374 ? " S ";:GOTO 377
375 ? " E ";:GOTO 377
376 ? " W";
377 NEXT DR
378 IF MX$="OOOO" THEN ? "NOWHERE";
379 ? " ":RETURN
380 GOSUB 400:GOSUB 420:GOSUB 360:RETURN
400 F1=O:T1$="":T2$="":V1=O:V2=O:Z1=O:Z2=O
402 IF TM(L,A)<>O AND INT(RND(O)*(C+SCW))>O THEN RESTORE S+TM(L,A):READ T1$,V1,Z1:? "OBJECTS: ";T1$:F1=A
403 IF TM(L,B)<>O AND INT(RND(O)*(C+SCW))>O THEN RESTORE S+TM(L,B):READ T2$,V2,Z2:? "OBJECTS: ";T2$:F1=F1+B
404 IF F1=O THEN ? "OBJECTS: NONE":GOTO 407
405 IF INT(RND(O)*((CW+SCW)/C))=O THEN 407
406 IF Z1+Z2>O THEN ? "BEWARE OF THE OBJECTS!"
407 RETURN
420 ? "MONSTERS: ";:IF TM(L,D)=O THEN ? "NONE":GOTO 423
421 RESTORE R+TM(L,C):READ X$:GOSUB 490:? P;" ";X$;:IF P>A THEN ? "S"
422 IF P=A THEN ? ""
423 RETURN
430 IF TM(L,D)=O THEN 420
431 WS=O:ON C1-G GOTO 432,435,437,437
432 MM=A:MN=A:IF W(A)>O THEN WS=A:? "CHOP!":GOTO 442
433 IF E(A)+E(B)=O THEN GOSUB 449:? "SWORDS OR SPEARS.":RETURN
434 ? "KILL!!!":GOTO 442
435 IF E(B)=O THEN GOSUB 449:? "SPEARS.":RETURN
436 MM=0.75:MN=1.5:X=B:Y=B:GOSUB 539:? "SWISH!":GOTO 442
437 IF E(C)=O THEN GOSUB 449:? "BOW.":RETURN
438 IF C1-G=C AND E(D)=O THEN GOSUB 449:? "POISON ARROWS.":RETURN
439 IF C1-G=C THEN MM=0.5:MN=1.5:X=D:Y=D:GOSUB 539:? "TWANG!":GOTO 442
440 IF E(5)=O THEN GOSUB 449:? "SILVER ARROWS.":RETURN
441 MM=0.5:MN=0.75:X=5:Y=5:WS=WS+B:GOSUB 539:? "TWANG!"
442 RESTORE R+TM(L,C):READ X$,MH,MAC,MA,MD,MS
443 ON MS GOTO 444,445,447,448
444 GOSUB 670:RETURN
445 IF WS=A OR WS=C THEN GOSUB 670:RETURN
446 GOTO 448
447 IF WS=B OR WS=C THEN GOSUB 670:RETURN
448 ? "NO EFFECT.":RETURN
449 ? "YOU HAVE NO ";:RETURN
450 ? "INVENTORY":? :? GP;" GP CREDITS":FOR X=A TO I:IF E(X)=O THEN 455
452 Z=E(X):Y=X:IF X>G THEN Y=E(X):Z=A
453 RESTORE S+Y:READ X$:? Z;" ";X$;:IF Z>A THEN ? "S"
454 IF Z=A THEN ? " "
455 NEXT X
457 ? :? "HIT POINTS":? :? HP;" HIT POINTS (";:? INT(HP*J/OLDHP);"% OF TOTAL)":RETURN
470 GOSUB 627:IF W=H THEN 482
472 ? "GET WHAT";:INPUT X$:IF X$="" THEN 472
473 IF X$<>T1$ AND X$<>T2$ THEN ? "IT'S NOT HERE.":GOTO 482
474 ? "GOT IT.":IF X$=T1$ THEN X=TM(L,A):TM(L,A)=O:T1$="":F1=F1-A
475 IF X$=T2$ THEN X=TM(L,B):TM(L,B)=O:T2$="":F1=F1-B
476 IF X<H THEN E(X)=E(X)+A:W=W+A:GOTO 481
477 RESTORE S+X:READ X$,Z,ZZ:IF ZZ=A THEN 482
478 IF ZZ>A THEN F2=A:F3=O:GOSUB 500:IF F3=A THEN 476
479 FOR Y=H TO I:IF E(Y)=O THEN E(Y)=X:W=W+A:GOTO 481
480 NEXT Y
481 GOSUB 627
482 RETURN
490 P=INT(TM(L,D)):IF INT(TM(L,D)*J)-P*J>O THEN P=P+A
491 RETURN
500 TRAP 501:GOSUB 500+ZZ:RETURN
501 POP :RETURN
502 VX=X-I:S(VX)=S(VX)+F2:RETURN
505 VX=X-24:S(VX)=S(VX)+F2*H:RETURN
506 F3=A:X=INT(RND(O)*67)+A:IF X=44 THEN 506
507 RETURN
508 SCW=SCW+J*F2:RETURN
509 SCW=SCW-J*F2:RETURN
510 SCI=SCI+J*F2:RETURN
511 SCI=SCI-J*F2:RETURN
512 W(A)=W(A)+F2:SCS=SCS-F2:RETURN
513 SAC=SAC+J*F2:RETURN
514 W(A)=W(A)+F2:SCS=SCS+F2:RETURN
517 SAC=SAC-J*F2:RETURN
518 F(A)=F(A)+F2:RETURN
519 F(B)=F(B)+F2:RETURN
520 IF F2=A THEN HP=HP-INT(RND(O)*OLDHP):GOSUB 624
521 RETURN
522 IF F2=-A THEN X1=OX:Y1=OY:GOTO 526
523 RETURN
524 IF F2=-A THEN X1=19:Y1=H:GOTO 526
525 RETURN
526 POP :POP :? "TELEPORTED!":GOTO 90
530 ? "DROP WHAT";:INPUT C$:IF C$="" THEN 530
532 FOR Y=A TO I:IF E(Y)=O THEN 536
533 X=E(Y):IF Y<H THEN X=Y
534 RESTORE S+X:READ X$,Z,ZZ
535 IF X$=C$ THEN 538
536 NEXT Y
537 ? "YOU DON'T HAVE ONE.":GOTO 547
538 ? "THUD."
539 CT=O:IF TM(L,A)=O THEN TM(L,A)=X:GOTO 544
540 IF TM(L,B)=O THEN TM(L,B)=X:GOTO 544
541 Z1=INT(RND(O)*A1)+A:IF TM(Z1,A)=O THEN TM(Z1,A)=X:GOTO 544
542 IF TM(Z1,B)=O THEN TM(Z1,B)=X:GOTO 544
543 CT=CT+A:IF CT<H THEN 541
544 W=W-A:IF Y<H THEN E(Y)=E(Y)-A:GOTO 547
545 E(Y)=O:IF ZZ>A THEN F2=-A:GOSUB 500
547 RETURN
560 FOR Z=A TO D:IF M$(Z,Z)="O" THEN 572
562 IF INT(RND(O)*CH/C)>O THEN 572
563 X=O:Y=O:ON Z GOTO 564,565,566,567
564 Y=A:NR=B:GOTO 568
565 Y=-A:NR=A:GOTO 568
566 X=A:NR=D:GOTO 568
567 X=-A:NR=C
568 RESTORE K+J*(X1+X)+Y+Y1:READ L1,X$:IF TM(L1,D)=O OR X$(NR,NR)="O" THEN 572
569 IF TM(L,D)>O AND TM(L,C)<>TM(L1,C) THEN 572
570 TM(L,C)=TM(L1,C):TM(L,D)=TM(L,D)+TM(L1,D):TM(L1,C)=O:TM(L1,D)=O
571 IF TM(L,D)>O THEN ? "INCOMING MONSTERS!":GOSUB 420
572 NEXT Z
573 RETURN
580 OP=O:? :? "YOU HEAR A LOUD NOISE."
581 IF TM(L,D)=O THEN OCH=CH:CH=O:GOSUB 560:CH=OCH:GOTO 596
582 IF INT(RND(O)*(E+SG))=O THEN 596
583 Y=O:IF OP>D THEN 596
584 Z=INT(RND(O)*D)+A:IF M$(Z,Z)<>"O" THEN 587
585 Y=Y+A:IF Y>E THEN 596
586 GOTO 584
587 X=O:Y=O:ON Z GOTO 588,589,590,591
588 Y=A:GOTO 592
589 Y=-A:GOTO 592
590 X=A:GOTO 592
591 X=-A
592 RESTORE K+J*(X+X1)+(Y+Y1):READ Z:IF TM(Z,C)<>O AND TM(Z,C)<>TM(L,C) THEN OP=OP+A:GOTO 583
594 TM(Z,C)=TM(L,C):TM(Z,D)=TM(Z,D)+TM(L,D):TM(L,C)=O:TM(L,D)=O:GOSUB 420
596 RETURN
601 FOR II=A TO G:RESTORE S+II:READ X$,Y:GP=GP+E(II)*Y:NEXT II
602 FOR II=H TO I:IF E(II)>O THEN RESTORE S+E(II):READ X$,Y:GP=GP+Y
603 NEXT II:? :? "YOUR WEAPONS AND TREASURES HAVE ALL BEEN SOLD."
614 GP=INT(GP):EP=EP+GP:EP=INT(EP*CS/G):OLDLL=LL:LL=LL+INT(EP/C/J)
615 GOSUB 640:GOSUB 630:? :? "EXPERIENCE POINTS: ";EP:? :? "LEVEL: ";LL
617 ? :? "START OVER WITH THIS CHARACTER(Y/N)";:INPUT C$:IF C$="N" THEN END
620 GOSUB 750:GOSUB 640:IF LL>OLDLL THEN GOSUB 759:GOTO 64
621 HP=OLDHP:GOTO 64
624 IF HP<A THEN POP :POP :POP :GOTO 350
625 RETURN
627 IF W=H THEN ? "YOU CAN'T CARRY ANYMORE."
628 RETURN
629 ? "'YOU HAVE ";GP;" GP CREDITS LEFT.'":? "'YOU DON'T HAVE ENOUGH GOLD.'":RETURN
630 ? :? "HIT POINTS : ";HP:? :? "GOLD PIECES : ";GP:RETURN
640 ? :? "CHARACTER TRAITS":? :? "STRENGTH.......";CS:? "INTELLIGENCE...";CI:? "INTUITION......";CW
641 ? "CONSTITUTION...";CO:? "SPEED..........";CD:? "VISAGE.........";CH:RETURN
660 IF MX$(C1,C1)="O" THEN ? "YOU CAN'T.":C2=A:GOTO 667
661 X=O:Y=O:ON C1 GOTO 662,663,664,665
662 Y=A:GOTO 666
663 Y=-A:GOTO 666
664 X=A:GOTO 666
665 X=-A
666 X1=X1+X:Y1=Y1+Y:C2=B
667 RETURN
670 X=INT((19-MAC-(CD+SCD)/D)*MM):IF INT(RND(O)*I)+A<X THEN ? "YOU MISSED!":GOTO 678
671 ? "A HIT!":Y=INT(RND(O)*(E+CS/H+SCS)*MN)+A:IF Y<A THEN Y=INT(RND(O)*C)+A
672 Z=Y/MH:IF Z>A THEN Z=A
673 GOSUB 490:OP=P:TM(L,D)=TM(L,D)-Z:IF TM(L,D)<0.01 THEN TM(L,D)=O
674 GOSUB 490:GOSUB 420:? "MONSTER TYPE'S HIT DICE: ";MH:? "POINTS OF DAMAGE DONE: ";Y
675 IF OP>P THEN ? "YOU KILLED THE ";X$;"!":EP=EP+MH^B*F:GOTO 678
676 ? "YOU WOUNDED THE ";X$;"."
678 RETURN
680 ? "THE PAWNBROKER ASKS,'YOU WANNA SELL SOMETHING'(Y/N)";:INPUT C$:IF C$="N" THEN 699
681 ? "SELL WHAT";:INPUT C$:IF C$="" THEN 681
682 FOR Y=A TO I:IF E(Y)=O THEN 686
683 X=E(Y):IF Y<H THEN X=Y
684 RESTORE S+X:READ X$,Z,ZZ
685 IF X$=C$ THEN 688
686 NEXT Y
687 ? "'YOU DON'T HAVE ONE.'":GOTO 698
688 Z=Z-INT(RND(O)*Z*0.4):IF Z=O THEN ? "'I CAN'T USE THAT.'":GOTO 698
689 ? "'I'LL GIVE YOU ";Z;" GOLD PIECES":? "FOR IT.'(Y/N)";:INPUT C$
690 ? "'O.K.'":IF C$<>"Y" THEN 698
691 GP=GP+Z:W=W-A:IF Y<H THEN E(Y)=E(Y)-A:GOTO 697
692 E(Y)=O:IF ZZ>A THEN F2=-A:GOSUB 500
697 ? "'YOU GOT A TOTAL OF ";GP;" CREDITS.'"
698 ? "'ANYTHING ELSE TO SELL'(Y/N)";:INPUT C$:IF C$<>"N" THEN 681
699 GOTO 285
750 ? :? "INITIALIZING...":W=O:SCS=O:SAC=O:SCW=O:SCI=O:SCD=O:EP=O:CN=A:FC=30:DC=I:SG=O
751 X1=OX:Y1=OY:FOR X=A TO I:E(X)=O:NEXT X:RESTORE K
752 TRAP 754:READ X,X$,X$,X$
753 TM(X,A)=ASC(X$(A,A)):TM(X,B)=ASC(X$(B,B)):TM(X,C)=ASC(X$(C,C)):TM(X,D)=ASC(X$(D,D)):GOTO 752
754 F(A)=O:F(B)=O:W(A)=O:FOR II=A TO D:S(II)=O:NEXT II
757 ? "↰";:RETURN
759 T=F:U=LL:GOSUB C:HP=V:IF CO=Q THEN HP=HP*D
761 IF CO=17 THEN HP=HP*C
762 IF CO=15 OR CO=16 THEN HP=HP*B
763 IF CO<7 THEN HP=LL
764 RETURN
801 DATA BLACK ORC,7,7,1,5,1
802 DATA SKELETON,5,6,1,5,3
803 DATA MAMMOTH,12,5,2,8,1
804 DATA SABER TOOTH TIGER,11,5,2,7,1
805 DATA MONK,6,7,1,3,1
806 DATA MONK-EY,4,4,1,2,1
807 DATA RAINBOW WORM,16,7,1,8,1
808 DATA METAL STATUE,9,0,1,7,1
809 DATA ORC CHIEFTAIN,8,6,1,5,1
810 DATA FOUR-HEADED HYDRA,24,4,4,6,2
811 DATA SILVER DRAGON,40,1,3,9,1
812 DATA HORRID WES-LEY,1,1,1,1,4
813 DATA CEREBUS,19,5,3,6,1
814 DATA NASTY DOGGIE,4,5,1,3,1
815 DATA LAVA TROLL,9,0,1,6,4
816 DATA VAMPIRE BAT,2,1,2,1,1
817 DATA WALKING PIRANHA,2,0,3,2,1
818 DATA WERE-BEAR,13,5,1,5,3
819 DATA WERE-WOLF,9,4,1,6,3
820 DATA WERE-RABBIT,6,3,1,7,3
821 DATA SILVER KNIGHT,8,1,1,6,1
822 DATA IGOR,6,6,1,4,1
823 DATA GHOULISH DEMON,9,5,1,6,2
824 DATA RUBBER KNIGHT,8,1,1,6,2
825 DATA WRAITH,7,4,1,3,3
826 DATA CYCLOPS,15,5,1,7,1
827 DATA FOOT-SOLDIER,6,6,1,4,1
828 DATA LOCH NESS MONSTER,14,4,1,6,1
829 DATA TOAD,3,2,1,1,1
830 DATA BOA CONSTRICTOR,5,4,1,2,1
831 DATA WHITE UNICORN,13,4,3,7,2
832 DATA OSTRICH,5,5,1,3,1
833 DATA WOOD GNOME,9,4,1,7,3
834 DATA SKELETAL HORSE,9,4,2,5,3
835 DATA SUNDAY DRIVER,6,6,1,4,1
836 DATA DINOSAUR,20,3,1,8,1
837 DATA CYBERNETIC TANK,999,0,6,50,4
838 DATA LAND-SEA SHARK,7,4,1,7,1
844 DATA 59,54,71,73,58,71,60,54,72
901 DATA PLAIN SWORD,15,0
902 DATA SPEAR,17,0
903 DATA LONG BOW,20,0
904 DATA POISON ARROW,2,0
905 DATA SILVER ARROW,5,0
906 DATA LEATHER ARMOR,20,0
907 DATA CHAIN MAIL,30,0
908 DATA PLATE ARMOR,40,0
909 DATA IRON SHIELD,10,0
910 DATA RADIUM STATUETTE,26,0
911 DATA GOLD NUGGET,12,0
912 DATA IVORY DRAUGHTS SET,42,0
913 DATA GOLD BAR,46,0
914 DATA POT OF GOLD,33,0
915 DATA BAG OF SILVER,17,0
916 DATA CASKET OF GEMS,66,0
917 DATA DEAD ATARI 400,40,6
918 DATA FIRESTONE,50,0
919 DATA BAG OF ORICHALCS,100,0
920 DATA BLACK PEARL NECKLACE,15,0
921 DATA BLUE SPHERE,5,2
922 DATA RED PYRAMID,5,2
923 DATA YELLOW CUBE,5,2
924 DATA GREEN BOX,5,2
925 DATA FIRESTONE,50,5
926 DATA AMETHYST,50,5
927 DATA RUBY,50,5
928 DATA TOPAZ,50,5
929 DATA BLUE HOPE DIAMOND,75,0
930 DATA SILLY PUTTY,1,6
931 DATA CANNONBALL,9,0
932 DATA BATS BREATH,6,6
933 DATA CHARIOT WHEEL,25,0
934 DATA FLAMING DRAGON SWORD,25,14
935 DATA WHITE HAIR,0,8
936 DATA BLACK WOOD SPEAR,19,1
937 DATA 16K GOLD CHIP,13,0
938 DATA CRACKED CLAY PITCHER,0,20
939 DATA GREEN ORB,29,9
940 DATA JADE NECKLACE,33,13
941 DATA PHILOSOPHERS STONE,7,1
942 DATA 7 LAYERED SHIELD,15,17
943 DATA IRON PINCERS,3,0
945 DATA SUNKINGS CROWN,70,11
946 DATA CUNYS SKULL,0,10
947 DATA ROCK,0,18
948 DATA KNISH,4,18
949 DATA STEW,5,18
950 DATA MUTTON,6,18
951 DATA PORK CHOPS,7,18
952 DATA STEAK,8,18
953 DATA CIDER,4,19
954 DATA ALE,5,19
955 DATA WINE,6,19
956 DATA MEAD,7,19
957 DATA LEADEN LIQUID,33,19
958 DATA SACK OF MAGIC BEANS,2,18
959 DATA PUDDLE,0,19
960 DATA DOM PERIGNON,4,19
961 DATA MERCURY PUDDLE,1,19
962 DATA FUNGUS BREAD,0,18
963 DATA FORBIDDEN FRUIT,2,18
964 DATA OSTRICH MCNUGGET,0,18
965 DATA YELLOW RIBBON,5,18
966 DATA ROCK,0,0
967 DATA PEBBLE,0,6
968 DATA DOUGHNUT HOLE,0,22
969 DATA CUTLASS,20,12
970 DATA SILVER OVOID,15,24
971 DATA HONDA,100,0
972 DATA PLUMED HELMET,18,0
999 DATA N,S,E,W,X,G,D,I,F,A,T,FP,FS,ET,DK,QT,SG
1000 IF L=73 THEN N1=A:N2=G:GOSUB 270:RETURN
1001 IF L=89 THEN GOSUB 680:RETURN
1002 IF L=58 THEN HP=OLDHP:N1=48:N2=G:GOSUB 199:RETURN
1008 IF L=136 AND TM(134,D)+TM(136,D)<A THEN GOSUB 1300:POP :C1=16:GOTO 601
1050 RETURN
1100 IF F(A)<A THEN ? "YOU HAVE NO FOOD.":GOTO 1199
1105 ? "EAT WHAT";:INPUT C$:IF C$="" THEN 1105
1106 FOR X=H TO I:IF E(X)=O THEN 1111
1109 Y=E(X):RESTORE S+Y:READ X$,Z,ZZ
1110 IF X$=C$ THEN 1113
1111 NEXT X
1112 ? "YOU DON'T HAVE ONE.":GOTO 1199
1113 IF Y=58 THEN HP=OLDHP:SG=E
1114 IF Y=63 THEN ? "SINNER!":GOTO 1120
1115 IF Y=62 THEN ? "YEECH! TASTES LIKE POISON!":HP=O:GOTO 350
1118 IF ZZ=Q THEN FC=CN+Y:JX=A:GOTO 1120
1119 ? "YOU CAN'T EAT THAT.":GOTO 1199
1120 F(JX)=F(JX)-A:E(X)=O:W=W-A
1130 ? "AAHHH! THAT WAS SO,SO GOOD!"
1199 RETURN
1200 IF F(B)<A THEN ? "YOU HAVE NO DRINK.":GOTO 1299
1205 ? "DRINK WHAT";:INPUT C$:IF C$="" THEN 1205
1206 FOR X=H TO I:IF E(X)=O THEN 1211
1209 Y=E(X):RESTORE S+Y:READ X$,Z,ZZ
1210 IF X$=C$ THEN 1213
1211 NEXT X
1212 ? "YOU DON'T HAVE ONE.":GOTO 1299
1213 IF Y=61 THEN ? "GURGLE,GURGLE.":HP=O:GOTO 350
1214 IF Y=57 THEN HP=OLDHP
1216 IF ZZ=19 THEN DC=CN+Y-23:JX=B:GOTO 1120
1219 ? "YOU CAN'T DRINK THAT.":GOTO 1299
1299 RETURN
1300 ? :? "THE WALLS BEGIN TO GLOW. SUDDENLY, FIERY RUNES APPEAR IN THE AIR!!!!":?
1301 RESTORE 844:QK=E:GOSUB 1304:? " IS YOUR NAME AND ";:QK=C:GOSUB 1304:? :? "IS THE SECRET OF YOUR POWER!"
1303 ? :FOR X=A TO J:NEXT X:RETURN
1304 FOR II=A TO QK:READ X:X=X+S(B):? CHR$(X);:NEXT II:RETURN
1600 IF S(C)/B<>INT(S(C)/B) AND S(A)<H THEN GOSUB 1650:GOTO 1660
1610 IF TM(A,D)+TM(B,D)>O THEN GOTO 1650
1620 IF S(A)<A THEN GOTO 1650
1635 GOSUB 3000
1639 IF LEN(C$)<>E THEN 1649
1640 IF C$(E,E)<>CHR$(80) THEN 1649
1645 RETURN
1649 ? "'GNORW!'"
1650 ? "A BLUE FORCE FIELD PUSHES YOU BACK!":X1=X1+A:RETURN
1660 ? "THE GUARDIAN RIPS YOU TO SHREDS!"
1661 HP=O:POP :GOTO 350
1800 IF S(D)/B<>INT(S(D)/B) AND S(B)<H THEN GOSUB 1850:GOTO 1660
1810 IF TM(53,D)+TM(68,D)+TM(84,D)+TM(67,D)>O THEN GOTO 1850
1820 IF S(A)<H OR S(B)<A THEN GOTO 1850
1835 GOSUB 3000
1839 IF LEN(C$)<>E THEN 1849
1840 IF C$(5,5)<>CHR$(90) THEN 1849
1845 RETURN
1849 ? "'GNORW!'"
1850 ? "A RED FORCE FIELD SLAMS YOU BACK!":X1=X1+A:RETURN
2000 IF L=1 THEN GOSUB 1600:RETURN
2002 IF L=67 THEN GOSUB 1800:RETURN
2004 IF L=135 THEN GOSUB 2100:RETURN
2006 IF L=48 THEN GOSUB 2200:RETURN
2050 RETURN
2100 IF S(A)+S(B)+S(C)+S(D)=44 THEN ? "TELEPORTED!":X1=X1-A:RETURN
2101 IF S(A)/B<>INT(S(A)/B) AND S(C)<H THEN GOSUB 2150:GOTO 1660
2110 IF TM(131,D)+TM(135,D)>O THEN GOTO 2150
2120 IF S(A)+S(B)<I OR S(C)<A THEN GOTO 2150
2135 GOSUB 3000
2140 IF LEN(C$)<>D THEN 2149
2141 IF C$(D,D)<>CHR$(80) THEN 2149
2145 RETURN
2149 ? "'GNORW!'"
2150 ? "A YELLOW FORCE FIELD SHOVES YOU BACKVIOLENTLY!":Y1=Y1+A:RETURN
2200 IF S(B)/B<>INT(S(B)/B) AND S(D)<H THEN GOSUB 2250:GOTO 1660
2210 IF TM(48,D)+TM(47,D)>O THEN GOTO 2250
2220 IF S(A)+S(B)+S(C)<30 OR S(D)<A THEN GOTO 2250
2235 GOSUB 3000
2239 IF LEN(C$)<>5 THEN 2249
2240 IF C$(C,C)<>CHR$(76) THEN 2249
2245 RETURN
2249 ? "'GNORW!'"
2250 ? "A GREEN FORCE FIELD CRUSHES YOUR FACE AND PUSHES YOU BACK!":X1=X1-A:RETURN
2900 CN=CN-A:TRAP 2914:GOSUB 2950:IF X$="D" THEN ? :? "INSERT DISK. PRESS RETURN";:INPUT X$:GOTO 2905
2904 ? :? "POSITION TAPE. PRESS RECORD & PLAY, THEN RETURN."
2905 X$=CHR$(155):OPEN #A,F,O,C$
2906 ? #A;X1;X$;Y1;X$;LL;X$;CS;X$;CI;X$;CW;X$;CO;X$;CH;X$;SG
2907 ? #A;CD;X$;OLDHP;X$;HP;X$;GP;X$;EP;X$;W(A);X$;F(A);X$;F(B)
2908 ? #A;W;X$;CN;X$;FC;X$;DC;X$;SCS;X$;SAC;X$;SCW;X$;SCI;X$;SCD
2909 FOR X=A TO D:? #A;S(X):NEXT X:FOR X=A TO I:? #A;E(X):NEXT X
2911 FOR X=A TO A1:FOR Y=A TO D:? #A;TM(X,Y):NEXT Y:NEXT X
2912 CLOSE #A:? :? "↰DONE.":RETURN
2914 CLOSE #A:? :? "↰ERROR.":RETURN
2920 TRAP 2930:IF X$="D" THEN ? :? "INSERT DISK. PRESS RETURN";:INPUT X$:GOTO 2924
2921 ? :? "POSITION TAPE. PRESS PLAY, THEN RETURN."
2924 OPEN #A,D,O,C$:INPUT #A;X1,Y1,LL,CS,CI,CW,CO,CH,SG
2925 INPUT #A;CD,OLDHP,HP,GP,EP,X,Y,Z:W(A)=X:F(A)=Y:F(B)=Z
2926 INPUT #A;W,CN,FC,DC,SCS,SAC,SCW,SCI,SCD:CN=CN+A
2927 FOR X=A TO D:INPUT #A;Y:S(X)=Y:NEXT X:FOR X=A TO I:INPUT #A;Y:E(X)=Y:NEXT X
2929 FOR X=A TO A1:FOR Y=A TO D:INPUT #A;Z:TM(X,Y)=Z:NEXT Y:NEXT X:GOTO 2912
2930 GOSUB 2914:POP :GOTO 15
2950 ? :? "CASS/DISK(C/D)";:INPUT X$:C$="C:":IF X$="D" THEN C$="D:AI.DAT"
2951 RETURN
3000 ? "THE VOICE OF THE GUARDIAN HISSES,":? "'TAHW SI EHT KIGAM DRUW'";:INPUT C$:RETURN
10513 DATA 67,OOEO,ALTAR-STONE SLAB UPHELD ON A DAIS BYKNEELING CHERUBS.,←└♥♥
10612 DATA 84,NOEO,H,♥;┤├
10613 DATA 68,NSOW,HALL OF STONED GIANTS. TO THE WEST IS A RED GLOW.,♥▖♥♥
10614 DATA 53,OSEO,H,♥/┘├
10711 DATA 97,NOEO,H,♥♥┐┤
10712 DATA 85,NSOW,H,♥♥┐◢
10713 DATA 69,NSOO,DOME-SHAPED ROOM. A HOT AMBER SPHEREFLOATS NEAR THE ROOF EMITTING RAYS.,B(♥♥
10714 DATA 54,NSOW,H,♥♥┐◢
10715 DATA 42,OSEO,H,♥B┐┤
10720 DATA 166,OOEO,O,♥♥&▗
10721 DATA 169,OSEO,PIRATE FRIGATE,♣E▕▕
10808 DATA 163,NOEO,M,♥B♥♥
10809 DATA 160,OSEO,AHZ FISSION BOMB CRATER EVERYTHING SHINES!,▔▖▌├
10810 DATA 101,NOEO,C,♥B╱┐
10811 DATA 98,NSEW,H,♥♥♥♥
10812 DATA 86,NSEO,H,♥♥╱┐
10813 DATA 70,NSEO,H,♥▔◢├
10814 DATA 55,NSEO,H,♥▔╱┐
10815 DATA 43,NSEW,H,<<♥♥
10816 DATA 28,OSEO,C,♥♥╱┐
10820 DATA 165,OOEW,M,♥▂♥♥
10821 DATA 168,NOOW,P,♥♥♥♥
10822 DATA 171,OSEO,P,♥C♥♥
10908 DATA 162,NOEW,M,"▝♥♥
10909 DATA 159,OSEW,A,♥♥♥♥
10910 DATA 102,NOOW,C,♥♥┐┘
10911 DATA 99,NSOW,C,/;╱┐
10912 DATA 87,NSOW,C,♥/◢├
10913 DATA 71,NSEW,C,♥◣♥♥
10914 DATA 56,NSOW,C,♥▖◢├
10915 DATA 44,NSOW,C,♥♥╱┐
10916 DATA 29,OSOW,C,B▖┐┘
10920 DATA 164,NOEW,ROCKY ROAD,♥;♥♥
10921 DATA 167,NSOO,CLIFF OVERLOOKING THE SHINING SEA,♥♥♥♥
10922 DATA 170,OOOW,O,♥♥&┘
11008 DATA 161,NOOW,M,♥♥♥♥
11009 DATA 158,NSOW,A,C/▕├
11010 DATA 157,NSOO,A,♥♥♥♥
11011 DATA 156,NSOO,A,♥;♥♥
11012 DATA 155,NSOO,A,♥B▕├
11013 DATA 72,NSEW,SIGN READS 3 MILES TO THE TEMPLE OF SEZEEN.,=/♥♥
11014 DATA 138,NSEO,SMALL ILL-KEPT CEMETARY. MUSHROOMS ABOUND HERE.,♥▂▌▕
11015 DATA 137,NSOO,L,;/♥♥
11016 DATA 30,NSEO,F,;→♥♥
11017 DATA 23,NSOO,F,B/─├
11018 DATA 17,NSOO,F,♥♥┼├
11019 DATA 11,NSOO,F,♥♥●├
11020 DATA 5,OSOW,N,♣▂♥♥
11106 DATA 127,NOEO,K,♥;♥♥
11107 DATA 121,NSOO,K,♥▖╲├
11108 DATA 115,OSOO,K,♥♥♥♥
11109 DATA 109,NSEO,K,;/├├
11110 DATA 103,OSEO,K,♥/♥♥
11112 DATA 88,NOEO,STRAW COTTAGES,B;♥♥
11113 DATA 73,NSEW,TWO EYE'S BLACKSMITH SHOP,♥♥♥♥
11114 DATA 57,OSEW,LACY MARBLE CATHEDRAL,♥♥♥♥
11116 DATA 31,OOEW,F,♥♥♥♥
11117 DATA 24,NOEO,STABLES. (PHEW!) THERE IS A GIGANTICWOODEN HORSE HERE!,♥/♥♥
11118 DATA 18,NSEO,SOUTHWEST TURRET ,♥♥♥♥
11119 DATA 12,NSEO,GUARDS' ROOMS,♥♥␛┐
11120 DATA 6,OSEO,NORTHEAST TURRET. THE SHINING SEA CAN BE SEEN THRU A SLIT WINDOW.,;▝♥♥
11121 DATA 1,OOEO,TINY WHITE CUBICLE WITH NICE THICK PADDING.,♥▌♥♥
11205 DATA 132,NOEO,J,♥▝┌┌
11206 DATA 128,OSOW,J,♥/┌┘
11207 DATA 122,OOEO,ORC STORE ROOM,▂▖├▕
11208 DATA 116,NOEO,ORC COMMON ROOM,;>├┐
11209 DATA 110,OSOW,ORC GUARD ROOM,♥♥├▗
11210 DATA 104,NOEW,DARK CAVERNOUS MOUTH--THE ENTRANCE TO THE CAVES!,←/▘├
11211 DATA 100,NSOO,SIGN READS 5 MILES TO THE CAVES OF PURB.,♥♥♥♥
11212 DATA 89,NSEW,THREE EYE'S PAWN SHOP,♥♥♥♥
11213 DATA 74,NSEW,TOWN SQUARE OF THE VILLAGE OF MAG. A LAUGHING MAD MAN CRIES 'BEWARE!'.,├♥♥♥
11214 DATA 58,NSEW,ONE EYE'S TAVERN,BD♥♥
11215 DATA 45,NSEO,SIGN READS 3 MILES TO THE CASTLE OFPICCUH.,▗╱▕├
11216 DATA 32,NSEW,OUTER GATE ROOM. THE 12-TON IRON GATES ARE AJAR!,♥;▄├
11217 DATA 25,NSEW,INNER GATE ROOM. THE INDESTRUCTIBLE INNER GATES HAVE BEEN SHATTERED!,♥♥▕├
11218 DATA 19,NSEW,MAIN HALL. ON THE WALL IS AN ANCIENT TAPESTRY DEPICTING A BLACK SWIRLING WHIRLAXY,9&♥♥
11219 DATA 13,NSEW,SERVANTS' QUARTERS,♥/▎├
11220 DATA 7,OSEW,EMPTY STORE ROOM. SPIDERS AND SLUGS DRIP VENOMOUS VITRIOL FROM THE RAFTERS.,B♥♥♥
11221 DATA 2,OOEW,TORTURE CHAMBER. TO THE WEST IS A BLUE GLOW. A BROKEN SKELETON LIES ON THE RACK.,+┬└├
11302 DATA 134,NOEO,I,♥♥♥♥
11303 DATA 134,NSEO,I,♥♥♥♥
11304 DATA 134,OSEO,I,♥♥♥♥
11305 DATA 133,NOOW,J,♥▝┌▂
11306 DATA 129,OSEO,J,♥B┌┐
11307 DATA 123,NOOW,ORC CHIEFTAIN'S QUARTERS. ON THE WALL IS A MURAL OF A PINK TROLL.,♥↓▗├
11308 DATA 117,OSEW,ORC LIVING QUARTERS,♥♥├┘
11309 DATA 111,NOEO,B,♥♥♥♥
11310 DATA 105,OSEW,B,♥;♥♥
11312 DATA 90,NOOW,BRICK COTTAGES,♥#♥♥
11313 DATA 75,NSEW,MARKET PLACE OF THE FOUR EYES,♥/♥♥
11314 DATA 59,OSOW,LOG CABINS,♥♥♥♥
11315 DATA 139,OOEW,L,♥/♥♥
11316 DATA 33,OOEW,F,♥♥♥♥
11317 DATA 26,NOOW,SOUTHEAST TURRET. YOU CAN SEE A DENSE FOREST THRU THE WINDOW.,♥;♥♥
11318 DATA 20,NSOW,GUARDS' ROOMS,♥♥␛┘
11319 DATA 14,NSEW,THE MINOR HALL. AN EVIL VIOLET FLAMEGYRATES ON THE MANTLEPLACE.,3─♥♥
11320 DATA 8,OSEW,LIVING QUARTERS. EVERYTHING IS STRANGELY WARPED.,♥♥♥♥
11321 DATA 3,OOEW,DUNGEON. THE BARS AND SHACKLES ARE ALL RUSTY AND CORRODED NOW.,♥♥▕┘
11402 DATA 136,NOEW,THE INFINIT CRYSTAL ROOM,♥▘♥♥
11403 DATA 134,NSEW,I,♥♥♥♥
11404 DATA 134,NSEW,I,♥♥♥♥
11405 DATA 134,OSOO,I,♥♥♥♥
11406 DATA 130,NOEW,B,♥;▂╲
11407 DATA 124,NSOO,B,♥♥♣␛
11408 DATA 118,OSEW,B,♥;├▕
11409 DATA 112,NOEW,B,♥♥♥♥
11410 DATA 106,OOOO,LAVA PIT. THERE SEEMS TO BE NO WAY OUT.,D'▖├
11413 DATA 76,OOEW,SIGN READS 3 MILES TO THE FOREST OF ELBCH.,B;♥♥
11414 DATA 141,NOEO,L,B;♥♥
11415 DATA 140,OSOW,L,♥♥┐├
11416 DATA 34,NOOW,F,;!"┤
11417 DATA 27,NSOO,F,♥$♥♥
11418 DATA 21,OSEO,F,*◢♥♥
11419 DATA 15,NOOW,GUARD'S ROOMS,♥♥♥♥
11420 DATA 9,NSOW,VAULT & ARMORY,┌%┴├
11421 DATA 4,OSOW,SHORT ARCHED TUNNEL,;▖♣▄
11502 DATA 134,NOOW,I,♥♥♥♥
11503 DATA 134,NSOW,I,♥♥♥♥
11504 DATA 134,OSOW,I,;/▝├
11505 DATA 135,NOOO,CHAMBER OF TEL-EPO,/␛♥♥
11506 DATA 131,OSOW,LEDGE IN FRONT OF A YELLOW CHAMBER,♥♥▔├
11507 DATA 125,NOOO,B,♥▄♥♥
11508 DATA 119,OSOW,B,B/♥♥
11509 DATA 113,NOOW,B,♥▔♥♥
11510 DATA 107,OSEW,B,B;♥♥
11511 DATA 143,NOEO,L,♥♥♥♥
11512 DATA 142,NSOO,L,♥♥♥♥
11513 DATA 77,NSOW,D,♥/♥♥
11514 DATA 60,OSEW,D,♥;!├
11515 DATA 46,NOEO,E,♥♥←╲
11516 DATA 35,OSEO,E,♥/↓▔
11518 DATA 22,NOOW,F,♥H♥♥
11519 DATA 16,NSOO,F,♥B♥♥
11520 DATA 10,OSOO,N,♥/♥♥
11607 DATA 126,NOOO,THE WIZARD'S SECRET ROOMS!, )┬├
11608 DATA 120,NSOO,DARKNESS. TO THE SOUTH IS A LIGHT!,♥;♥♥
11609 DATA 114,NSOO,B,♥♥♥♥
11610 DATA 108,OSEW,B,/▝♥♥
11611 DATA 144,OOEW,L,♥▂␛┤
11612 DATA 91,NOEO,G,-▖♥♥
11613 DATA 78,OSEO,G,♥.♥♥
11614 DATA 61,OOEW,WILD CRAB APPLE TREE ORCHARD,??←├
11615 DATA 47,OOEW,SWAMP. A GREENISH GLOW EMANATES FROMTHE EAST.,♥♥♥♥
11616 DATA 36,OOEW,E,♥♥♥♥
11709 DATA 153,NOEO,L,♥♥♥♥
11710 DATA 154,NSOW,CAVE MOUTH,♥♥♥♥
11711 DATA 145,OOEW,TIME PORT #1,/;♥♥
11712 DATA 92,OOEW,G,♥♥♥♥
11713 DATA 79,OOEW,G,♥♥♥♥
11714 DATA 62,OOEW,D,♥♥♥♥
11715 DATA 48,OOOW,A BRACKISH SPRING BUBBLES UP FROM A MOUND AT THE BASE OF A TREE.,;↑◣├
11716 DATA 37,OOEW,E,♥B♥♥
11809 DATA 152,OOEW,L,♥♥♥♥
11810 DATA 150,OOOO,CRATERED NUCLEAR BATTLEFIELD,♥B%├
11811 DATA 146,OOEW,ASPHALT PARKING LOT,♥G#├
11812 DATA 93,OOEW,G,♥♥♥♥
11813 DATA 80,NOOW,G,♥♥→├
11814 DATA 63,OSEW,D,♥♥♥♥
11815 DATA 49,NOEO,E,B/♥♥
11816 DATA 38,OSOW,E,♥♥♥♥
11909 DATA 151,OOOW,BACK GATE,♥♥♥♥
11910 DATA 148,NSEW,SILVER DOME. A SIGN READS OPERATOR REQUIRED FOR 2-WAY OPS.,♥F♥♥
11911 DATA 147,OSOW,WIERD BUILDINGS. ONE OF THEM IS AN ANTI-MATTER POWER PLANT.,♥♥♥♥
11912 DATA 94,NOOW,G,B:♥♥
11913 DATA 81,NSOO,G,♥;→├
11914 DATA 64,OSEW,D,C/␛▘
11915 DATA 50,NOEW,IMMENSE BLUE LAKE COVERED BY BLACK SWANS.,;●↑├
11916 DATA 39,OSEO,D,♥♥♥♥
12010 DATA 149,OOOO,PRIMEVAL RAIN-FOREST,♥┴$├
12012 DATA 95,NOEO,A BROKEN CIRCLE OF STANDING STONES,♥; ┐
12013 DATA 82,NSOO,FIELD OF SUNFLOWERS,♥B♥♥
12014 DATA 65,NSOW,D,♥▎♥♥
12015 DATA 51,OSEW,D,♥♥♥♥
12016 DATA 40,OOEW,D,♥♥♥♥
12112 DATA 96,NOOW,MEADOW OF EAT-YOU-ALIVE FLOWERS,@▝♥♥
12113 DATA 83,NSOO,MONOLITHIC STONE RUINS,▔▔ ╲
12114 DATA 66,NSOO,FIELD OF WHITE MOONFLOWERS,♥♥♥♥
12115 DATA 52,OSOW,D,/▖♥♥
12116 DATA 41,OOOW,AN OLD OAK TREE CASTS A DAPPLED SHADOW OVER A QUIET GLADE.,┼A!▕
