game (ADVENTX5.BAS)

game by J.D. Casten, 101 (BASIC, binary data)

Description

game by J.D. Casten, 101 (BASIC, binary data)

From the Antic disk of November 1984 (Vol. 3 No. 7).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 12.2 KB

Dialect
Atari BASIC
Lines
253
Variables
Z, O, H, C, A, B, Y, L, I$, J, O(, D, L$, D$, S$, S, F, F$, K, M$, Q, I, C$
BASIC listing (253 lines)
1 REM ADVENT X-5
2 REM BY J.D. CASTEN
3 REM ANTIC MAGAZINE
5 Z=O:O= NOT Z:H=100:C=O+O:A=150:B=C*H:GRAPHICS Z:POKE 559,Z:GOTO 1000
10 GOSUB 15000:GET #O,Y:IF (Y<32 OR Y>90) AND Y<>126 AND Y<>155 THEN POKE 702,64:POKE 694,Z:GOTO 10
15 IF Y=155 THEN RETURN
20 IF (Y=126 AND L=O) OR (L=31 AND Y<>126) THEN 10
25 IF Y=126 THEN L=L-O:I$=I$(O,L):? "◀";:GOTO 10
30 ? CHR$(Y);:I$(L)=CHR$(Y):L=L+O:GOTO 10
50 IF J>52 AND O(2)<255 OR J>58 THEN ? " (it's closed)":RETURN
55 ? " (it's open)":IF J>52 THEN L=O
60 RETURN
100 L=Z:POKE 82,O:D=Z:IF O(70)=Z AND O(0)>21 THEN ? "↰        It's too dark to see!!! ":D=O
105 IF O(Z)>28 AND O(Z)<33 AND O(16)<255 THEN ? "↰ Every thing is blurry!!! ":D=O
110 RESTORE 9000+O(Z):READ L$,D$:Y=Z:IF D THEN 145
112 ? "↰You're ";L$;".▶You see:":FOR J=O TO 62
115 IF O(J)=O(Z) THEN RESTORE J+9500:READ L$:? L$;".":Y=O:IF J<61 AND J>46 THEN GOSUB 50
117 NEXT J:IF  NOT Y THEN ? "Nothing special."
120 ? "Obvious exits:":L$="NorthSouthEast←West←Up←←←Down←":FOR J=O TO 6:IF ASC(D$(J))>99 THEN ? "-Out";:GOTO 130
125 IF ASC(D$(J)) THEN J=J-O:? "-";L$(J*5+O,J*5+5);:J=J+O
126 IF O(Z)=C THEN IF J=O THEN ? "-Out";
130 NEXT J:? "-"
145 POKE 82,Z:? "←──────────────────────────────────────── ";:POKE 82,O
147 IF L THEN ? "The card is glowing."
150 O(64)=O(64)+O:IF O(64)=60 THEN O(65)=O(65)+O:O(64)=Z:IF O(65)=12 THEN 9998
154 IF O(73)=30 THEN 160
155 IF O(Z)=7 AND O(15)=255 THEN ? "The barbell pulls you down!":FOR J=O TO 250:NEXT J:O(Z)=30:GOTO H
160 IF (O(Z)<21 AND O(Z)>17 AND O(6)<255) OR (O(Z)>28 AND O(Z)<33 AND O(18)<255) THEN 9997
165 IF O(Z)<>39 AND O(66) THEN ? "The alien devours you!!!":GOTO 8000
170 O(66)=Z:IF O(Z)=O(23) THEN ? "The alien is opening it's mouth.":O(66)=O
175 IF O(67) AND O(67)<9 THEN O(67)=O(67)+O:? "You're bleeding!":IF O(67)=8 THEN ? "You bled to death!":GOTO 8000
180 IF O(67)=Z AND O(Z)=32 THEN ? "The shark bit you.":O(67)=O
185 IF O(71) AND (O(9)>H AND O(9)<>110 AND O(9)<>131) THEN ? "The fuel bursts into flames!":GOTO 8000
190 O(71)=Z:IF O(9)=255 THEN O(71)=O:? "The fuel is VERY hot!"
200 O(73)=O(Z):S$="":S=Z:F=Z:L=O:I$="":? "Command:";:GOSUB 10:? :F$=I$:K=Z:L=Z
205 IF LEN(F$)<3 THEN F$(LEN(F$)+O)=" ":GOTO 205
210 L$="GO WALRUNENTCRASWICLIJUMSAYTELASKYELSCRDROLEAPUTRELI  LOOEXADESSEEREAGETTAKCRAPICHOLCATUSEPRETURCUTINV"
215 L$(103)="SAVPUSOPEQUISHONORSOUEASWESUP DOWOUTN  S  E  W  U  D  O  "
220 F=54-USR(ADR(M$),53,ADR(L$),ADR(F$)):IF F>46 THEN F=F-7
225 K=K+O:IF F=47 OR K=O+C THEN ? "I don't understand that.":GOTO B
230 L=Z:IF F>39 THEN L=S+O*(S=Z):S=F-39:F=L:IF L<14 THEN GOTO B+H
240 IF F=L THEN K=C:GOTO 225
250 Y=Z:Q=Z:FOR J=O TO LEN(I$):TRAP 260:IF I$(J,J)=" " THEN S$=I$(J+O):IF  NOT Y THEN Y=J+O
255 IF I$(J,J+C)="IN " OR I$(J,J+C)="FRO" THEN Q=J
260 NEXT J:I=Z:IF Y=Z THEN S=63:GOTO B+H
265 L$="WATCARBOOCONBANSUIPLAKEYFUEBAGKNIGUNPISBATBARMASPAPSNOTREFERSHASHAALIMONROBBOXBOXDIACABBUTTANSPESCRADV"
270 L$(103)="SHUAQUFISROOAQUPOOCHACAGVENVENVENVENELEELEELEELEELEELEDOODOODOODOODOODOODOODOOUNIKLY"
275 S=63-USR(ADR(M$),62,ADR(L$)+I,ADR(S$))+I/3
280 IF S=63 THEN S=F:F$=S$:TRAP 205:F$=S$(O,O):GOTO 205
285 IF S<63 THEN IF O(S)<>O(Z) AND O(S)<>255 THEN I=S*3:GOTO 275
290 IF S>62 THEN F$="-":GOTO 205
300 ON F GOTO 350,350,350,350,350,350,350,350,550,550,550,550,550,450,450,450,450,775,500,500,500,500,500,400,400
301 ON F-25 GOTO 400,400,400,400,800,800,800,650,775,1015,800,600,1015,650
350 IF S>7 THEN 375
352 IF S=7 THEN 365
355 IF D$(S,S)="♥" OR ASC(D$(S))>99 THEN ? "You can't go that way.":GOTO B
357 IF O(Z)=24 AND S=O+C AND O(7)<255 THEN ? "Robot says:▶Improper identification▶Passage denied.":GOTO A
360 O(Z)=ASC(D$(S)):GOTO H
365 IF O(Z)=C THEN O(Z)=O(69):GOTO H
367 FOR J=O TO 6:IF ASC(D$(J))>99 THEN O(Z)=ASC(D$(J))-H:GOTO H
370 NEXT J:? "You can't go that way.":GOTO B
375 IF S<53 AND S>46 THEN O(69)=O(Z):O(Z)=2:GOTO H
380 IF S=34 THEN O(Z)=39:GOTO H
381 IF S=35 THEN 900
382 IF S<47 AND S>42 THEN O(Z)=(S=43)*11+(S=44)*13+(S=45)*10+(S=46)*9:GOTO H
383 IF S<59 AND S>52 AND O(2)<255 THEN ? "It's closed":GOTO B
384 IF S<59 AND S>52 THEN O(Z)=(S=53)*6+(S=54)*4+(S=55)*15+(S=56)*14+(S=57)*27+(S=58)*38:GOTO H
390 IF S=40 THEN O(Z)=7:GOTO H
392 IF S=36 THEN O(Z)=33:GOTO H
393 IF S=38 THEN ? "a long way down▶Jump-wwhheee-THUD!!!▶You missed the swimming pool▶Broken neck!!!":GOTO 8000
399 ? "Nope.":GOTO B
400 IF Q THEN GOSUB 700:GOTO 725
405 IF S>20 THEN ? "You can't get that.":GOTO B
410 IF O(S)<>O(Z) THEN ? "I don't see it.":GOTO B
415 IF O(68)=O(72) THEN ? "You can't carry any more.":GOTO B
420 O(68)=O(68)+O:O(S)=255:GOTO H
450 IF Q THEN GOSUB 700:GOTO 750
455 IF O(S)<255 THEN ? "You don't have it.":GOTO B
460 O(68)=O(68)-O:O(S)=O(Z):GOTO H
500 IF S=63 THEN GOTO H
502 RESTORE S+9500-9*(S=41):READ L$,L$:IF LEN(L$)>O THEN ? L$
505 IF L$="+" THEN ? "Sharkit brand"
507 IF S=17 THEN ? "reads:▶shuttle code:";C$
510 IF S=O THEN L$="00":L$(3-LEN(STR$(O(64))))=STR$(O(64)):? "Time-";O(65);":";L$
517 IF L$="-" THEN ? "Nothing special."
522 IF S=42 THEN O(24)=35
525 IF S<>39 THEN 530
526 ? "You see:":FOR J=Z TO 37:IF O(J)=32 THEN RESTORE 9500+J:READ L$:? L$;"."
527 NEXT J
530 FOR J=O TO 28:IF O(J)=S+H THEN RESTORE 9500+J:READ L$:? L$;" is in it."
535 NEXT J
545 GOTO A
550 TRAP B:? I$(Y);".":IF S>6 OR O(Z)<>2 THEN GOTO A
555 O(69)=(S=O)+(S=2)*4+(S=3)*5+(S=4)*3+(S=5)*15+(S=6)*34:? "Speaker says:▶Yes sir.":GOTO A
600 IF S=26 AND O(8)<255 THEN ? "It's locked":GOTO B
605 IF S=26 THEN O(S)=Z:O(27)=8:O(28)=8:GOTO H
649 ? "Nope.":GOTO B
650 ? "USEing what?":GOTO B
700 S$="":I=Z:FOR J=O TO Q-2:IF I$(J,J)=" " THEN S$=I$(J+O)
705 NEXT J:IF S$="" THEN ? "Nope.":POP :GOTO B
710 L=63-USR(ADR(M$),62,ADR(L$),ADR(S$))
715 IF L=62 THEN ? "Nope.":POP :GOTO B
720 RETURN
725 IF O(L)<>S+H THEN ? "I don't understand.":GOTO B
730 S=L:GOTO 415
750 IF O(L)<255 THEN S=L:GOTO 455
755 O(L)=S+H:O(68)=O(68)-O:GOTO H
775 Y=Z:? "You have:":FOR J=O TO 20:IF O(J)=255 THEN RESTORE 9500+J:READ L$:? L$;".":Y=O
780 NEXT J:IF  NOT Y THEN ? "Nothing."
785 GOTO A
800 IF S=5 AND (O(5)<255 OR O(67)=Z) THEN ? "Nope.":GOTO B
805 IF S=5 THEN ? "O.K.":O(68)=O(68)-O:O(5)=Z:O(67)=20:GOTO A
810 IF S=22 AND O(11)<255 THEN ? "nothing to cut it with.":GOTO A
815 IF (S=11 OR S=22) AND O(22)=32 AND O(17)=Z THEN ? "a piece of paper plops out.":O(17)=32:GOTO A
820 IF S=13 AND ((O(Z)>28 AND O(Z)<33) OR O(14)<113) THEN ? "Pistol does not work.":GOTO A
825 IF S=13 AND O(Z)=O(23) THEN ? "Zzaaappp!!!":FOR J=O TO 250:NEXT J:O(23)=0:O(66)=Z:GOTO H
830 IF S=13 THEN ? "The laser beam is absorbed.":GOTO A
835 IF S=12 AND O(Z)<>O(21) THEN ? "The spear shoots out▶a rope pulls it back in":GOTO A
840 IF S=12 THEN ? "You hit the shark!":O(21)=Z:O(22)=32:FOR J=O TO 250:NEXT J:GOTO H
845 IF O(72)=5 AND S=15 THEN ? "You feel stronger!":O(72)=6:GOTO A
850 IF S=28 THEN ? "It clicks▶You hear a humming sound.":O(70)=O:GOTO A
855 IF S=30 AND O(9)<>131 THEN ? "reads:▶NO FUEL":GOTO A
860 IF S=30 THEN 9999
865 ? "Nope.":GOTO A
900 L=O:I$="":? "Enter shuttle code:";:GOSUB 10:IF I$<>C$ THEN ? "↰ FAULTY ":GOTO A
905 O(Z)=21:GOTO H
1000 DIM O(73),F$(C+O),S$(C+O),C$(C+O),L$(186),D$(6),I$(30),M$(60):OPEN #O,4,Z,"K":C$=STR$(INT(RND(Z)*900+H))
1005 M$="hh┐Uh┐Th┐Nh┐Mh┐Lh┐K ♥1KQMP╱H@┘Pu◆%M┴i┘┐M♣▕fN%TP╱%Up╲FUFT┴♣X◆":RESTORE 1025:FOR J=Z TO 73:READ L
1010 O(J)=L:NEXT J
1015 GOSUB 5000:L=PEEK(560)+256*PEEK(561):POKE L+8,7:POKE L+9,6:POKE 710,Z:POKE 708,70:POKE 711,26
1020 ? "▶▶▶   ADVENT X-5         by jd casten":CLOSE #2:POKE 82,14:? "▶1. Play game▶2. Load game▶3. Save game"
1025 ? "4. New game▶5. Quit▶▶  Choice:";:POKE 752,O:GET #O,Y:Y=Y-48:IF Y<O OR Y>5 THEN 1015
1030 GOSUB 5000:ON Y GOTO 100,2000,3000,8020
1035 GRAPHICS Z:END
1100 DATA 1,1,103,129,129,104,39,14,14,22,26,12,34,36,23,6,35,0,25,34,34,32,0,18,0,24,8,0,0,5,21,21,2,3,18,20,28
1105 DATA 32,17,34,6,2,35,3,5,22,36,1,3,4,5,15,34,4,6,14,15,28,36,38,27,17,1,2,-1,6,0,0,0,0,0,0,5,1
2000 L=2005:GOTO 4000
2005 CLOSE #2:OPEN #2,4,Z,I$:FOR J=Z TO 73:GET #2,K:O(J)=K:NEXT J:INPUT #2;C$:GOTO 1015
3000 L=3005:GOTO 4000
3005 CLOSE #2:OPEN #2,8,Z,I$:FOR J=Z TO 73:PUT #2,O(J):NEXT J:PRINT #2;C$:GOTO 1015
4000 I$="D:ADVENTX5.DTA":TRAP 4005:GOTO L
4005 IF PEEK(195)=138 THEN TRAP 4010:I$="C:":GOTO L
4010 ? " ERROR  ↰↰↰↰↰":GOTO 1015
5000 GRAPHICS Z:POKE 82,O+O:FOR J=675 TO 689:POKE J,Z:NEXT J:RETURN
8000 ? "You're dead."
8010 ? "▶please press  RETURN";:GET #O,Y:RUN
8020 RUN
9001 DATA on the ships bridge,♥♥♥♥♥'
9002 DATA in a voice activated elevator,♥♥♥♥♥♥
9003 DATA in a computer room,♥♥♥♥♥♥
9004 DATA in a cafeteria,♥♥♥♥♥♥
9005 DATA in a medical lab,♥♥♥♥♥♥
9006 DATA in a recreation room,♥◢♥♥♥♥
9007 DATA swimming in the pool,j♥♥♥♥♥
9008 DATA in the power control room,╱♥♥♥♥♥
9009 DATA in an air duct,◢♥♥♥▔♥
9010 DATA in an air duct,▝z♥♥♥♥
9011 DATA in an air duct,g◣▘♥♥♥
9012 DATA in an air duct,♥♥▔▝♥♥
9013 DATA in an air duct,i♥♥▘♥▗
9014 DATA in the captain's quarters,♥♥♥♥♥♥
9015 DATA in a crew's sleeping barracks,♥♣♥♥♥♥
9016 DATA in a tubular corridor,▖┌♥♥♥♥
9017 DATA on an observation deck,♣♥♥♥♥♥
9018 DATA on the surface of Klybex-7,┼♥┼●♥♥
9019 DATA on the surface of Klybex-7,┼─┼─♥♥
9020 DATA in a giant crater,♥♥─♥♥♥
9021 DATA in the escape shuttle,x♥♥♥♥♥
9022 DATA in a fuel storage area,♥♥♥♥♥┴
9023 DATA in an engine room,♥♥♥♥♥└
9024 DATA in the west cargo hold,♥♥▌♥▎♥
9025 DATA at a loading dock,␛♥└┴♥♥
9026 DATA in the east cargo hold,♥♥♥▌┬♥
9027 DATA in a tubular corridor,♥▌♥♥♥♥
9028 DATA in a compression chamber,♥♥♥♥♥♥
9029 DATA in an aqueduct,←!♥♥♥♥
9030 DATA at the bottom of the pool,→↓♥♥╲♥
9031 DATA in an aqueduct, ←♥♥♥♥
9032 DATA in an aquarium,♥→♥♥♥♥
9033 DATA at an aquaduct outlet,↓♥♥♥♥♥
9034 DATA in a giant terrarium,♥♥&%♥♥
9035 DATA in a primate room,%♥♥♥♥♥
9036 DATA in a water control room,♥♥♥♥♥♥
9037 DATA in a tubular corridor,♥#"♥♥♥
9038 DATA in a tubular corridor,♥♥♥"♥♥
9039 DATA in an air lock,v♥♥♥├♥
9501 DATA a wrist watch,-
9502 DATA a plastic card,It's red.▶reads:▶ DOOR
9503 DATA a book,reads:▶HOW TO KILL AN ALIEN▶Use a laser pistol (with a battery▶in it) on the alien.
9504 DATA a container,a red cross is on it
9505 DATA a bandage,+
9506 DATA a space suit,It has oxygen
9507 DATA an ID plate,reads:▶RoboID: CAP 594C53▶Carry at all times.
9508 DATA a key,reads:▶P.B.K.
9509 DATA puddy fuel,It's green & glowing
9510 DATA an asbestocine bag,-
9511 DATA a knife,+
9512 DATA a spear gun,+
9513 DATA a laser pistol,-
9514 DATA a battery,Dura-Sell brand
9515 DATA a barbell,300 lbs & water-proof
9516 DATA a swimming mask,+
9517 DATA a piece of paper,-
9518 DATA a snorkelizer,+
9519 DATA a tree,it's a baby oak
9520 DATA a fern,-
9521 DATA a shark,it's a great white
9522 DATA a dead shark,it's very dead
9523 DATA an alien,one mean dude
9524 DATA a monkey,it's a chimp▶it's head is shaved
9525 DATA a robot,Gaurd-O-Matic kind
9526 DATA a large box,reads:▶Power▶it's metal▶it's bolted to the floor▶it's locked
9527 DATA a large open box,reads:▶Lower level▶a dial is in it
9528 DATA a dial,it turns
9529 DATA an open cabinet,a red cross is on it
9530 DATA a button,it's flashing
9531 DATA a fuel tank,reads:▶Puddy Fuel Tank
9532 DATA a speaker/microphone,says:▶say deck name then exit
9533 DATA a computer screen,reads:▶asteroid collision-12:00▶shuttle code lost in pool▶shark is sick to stomach
9534 DATA the Advent X-5,-
9535 DATA the escape shuttle,-
9536 DATA an aqueduct outlet,-
9537 DATA a fish.▶some coral.▶sea weed,-
9538 DATA a rec. room 20 feet below,-
9539 DATA an aquarium,-
9540 DATA a swimming pool,it's deep
9541 DATA a chart:▶     Uplez     ▶       |╱▔Norec▶ Wesox─┼─Eafop ▶Sourk▂╱|       ▶     Dowes     ,-
9542 DATA a cage,a monkey is in it
9543 DATA a vent,It's open
9544 DATA a vent,It's open
9545 DATA a vent,It's open
9546 DATA a vent,It's open
9547 DATA an elevator,-
9548 DATA an elevator,-
9549 DATA an elevator,-
9550 DATA an elevator,-
9551 DATA an elevator,-
9552 DATA an elevator,-
9553 DATA a red door,-
9554 DATA a red door,-
9555 DATA a red door,-
9556 DATA a red door,-
9557 DATA a red door,-
9558 DATA a red door,-
9559 DATA a blue door,-
9560 DATA a blue door,-
9561 DATA the universe,lots of stars
9562 DATA the surface of Klybex-7,a shuttle is to the west
9997 ? "You can't breath!!!":GOTO 8000
9998 FOR J=O TO 7:? "BBOOOMMM!!!":NEXT J:? "An asteroid hit Klybex-7":GOTO 8000
9999 FOR J=O TO 10:? "Congratulations!!!":NEXT J:? "You blasted off and▶safely made it to a▶local star base."
10000 GOTO 8010
15000 POKE 16,64:POKE 53774,64:RETURN