Jacks (JACKS.BAS)

Jacks, game by Coy Ison, 45

Description

Jacks, game by Coy Ison, 45

From the Antic disk of October 1984 (Vol. 3 No. 6).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 3.4 KB

Dialect
Atari BASIC
Lines
101
Variables
SC, BM, CT, N, PU, H, OV, DO, S, DX, DY, A, LP, JV, JD, QQ, E$, RAMTOP, CHBAS, ADDR, PAGE, CHAR, POS, X
BASIC listing (101 lines)
10 REM JACKS
20 REM BY COY ISON
30 REM ANTIC MAGAZINE
100 GOSUB 1000:GOSUB 500:GOSUB 230:GOTO 260
110 REM MOVE BALL
120 POKE SC+2+20*BM,0
130 CT=1:BM=BM+N
140 IF BM<1 THEN BM=1:N=+1
150 IF BM>22 THEN BM=22:PU=PU-1:GOTO 440
160 POKE SC+2+20*BM,250
170 SOUND 0,10+BM,14,8
180 POKE 77,0
190 RETURN
200 REM GIVE # NEEDED TO PICK UP
210 H=H+1
220 POSITION 6,4:? #6;"holding=";H
230 POSITION 6,1:? #6;"pick up=";PU
240 POSITION 6,2:? #6;"_____________"
250 RETURN
260 REM JOYSTICK ROUTE
270 CT=0
280 OV=3:DO=22
290 S=STICK(0):SOUND 0,0,0,0
300 IF S<>15 THEN POSITION OV,DO:? #6;" "
310 DX=(S=5 OR S=6 OR S=7)-(S=9 OR S=10 OR S=11)
320 DY=(S=5 OR S=9 OR S=13)-(S=6 OR S=10 OR S=14)
330 LOCATE OV+DX,DO+DY,A
340 IF A=250 THEN 410
350 IF A=36 THEN GOSUB 200:GOTO 370
360 IF A<>32 THEN 380
370 OV=OV+DX:DO=DO+DY
380 POSITION OV,DO:? #6;"_"
390 GOSUB 120
400 GOTO 290
410 REM BALL CAUGHT, CLEAR JACKS
420 IF PU<>H THEN PU=PU-1:GOTO 440
430 PU=PU+1
440 H=0
450 IF PU<1 THEN PU=1
460 FOR LP=6 TO 20:POSITION 4,LP:? #6;"               ":NEXT LP
465 POSITION 6,4:? #6;"          "
470 POSITION 2,BM:? #6;" "
480 POSITION OV,DO:? #6;" "
485 IF PU=8 THEN 900
490 GOSUB 230:GOSUB 650:GOTO 260
500 REM DRAW FIELD
510 H=0:PU=1:SC=PEEK(88)+256*PEEK(89)
520 FOR LP=0 TO 18:POSITION LP,23:? #6;"!":NEXT LP
530 FOR LP=1 TO 19
540 POSITION LP,0:? #6;"!"
550 IF LP<5 THEN 570
560 POSITION LP,5:? #6;"!"
570 NEXT LP
580 FOR LP=1 TO 4
590 POSITION 5,LP:? #6;"!"
600 NEXT LP
610 FOR LP=0 TO 22
620 POSITION 0,LP:? #6;"!"
630 POSITION 19,LP:? #6;"!"
640 NEXT LP
650 REM THROW JACKS & BOUNCE BALL
660 POSITION 4,21:? #6;"HIT red BUTTON"
670 POSITION 4,22:? #6;"TO THROW JACKS"
680 IF STRIG(0)<>0 THEN 680
690 FOR LP=21 TO 22:POSITION 3,LP:? #6;"               ":NEXT LP:GOSUB 750
700 POSITION 4,21:? #6;"HIT red BUTTON"
710 POSITION 4,22:? #6;"TO BOUNCE BALL"
720 IF STRIG(0)<>0 THEN 720
730 FOR LP=21 TO 22:POSITION 3,LP:? #6;"               ":NEXT LP
740 RETURN
750 REM PLACE JACKS (RANDOM)
760 BM=22:N=-1
770 POSITION 2,22:? #6;"z"
780 FOR LP=1 TO 18:POSITION LP,23:? #6;"!":NEXT LP
790 FOR LP=1 TO 7
800 JV=INT(14*RND(1)+5):IF JV>14 THEN 800
810 JD=INT(20*RND(1)+6):IF JD>20 THEN 810
820 LOCATE JV,JD,QQ:IF QQ<>32 THEN 800
830 POSITION JV,JD:? #6;"$"
840 NEXT LP
850 RETURN
900 REM GAME OVER
920 POSITION 6,11:? #6;"game over"
930 POSITION 4,12:? #6;"play again(y/n)"
940 IF PEEK(764)=43 THEN PU=0:GOTO 430
950 IF PEEK(764)=35 THEN END
960 GOTO 940
1000 REM FAST DUMP
1010 GRAPHICS 1+16
1020 DIM E$(50):RAMTOP=PEEK(106)-8:POKE 106,RAMTOP:CHBAS=RAMTOP:ADDR=CHBAS*256:PAGE=4
1030 E$(1,41)="hh┐Oh┐Nhh┐T)♥┐L)◆┐M"├ ♥1L┌NHPyfMfOhdTPp◆♥":A=USR(ADR(E$),ADDR,PAGE)
1040 FOR LP=1 TO 3
1050 READ CHAR
1060 POS=ADDR+(CHAR*8)
1070 FOR X=0 TO 7:READ A:POKE (POS+X),A:NEXT X
1080 NEXT LP
1090 DATA 1,255,255,255,255,255,255,255,255
1100 DATA 58,0,0,56,108,84,108,56,0
1110 DATA 4,0,8,8,20,107,20,8,8
1120 POKE 756,CHBAS
1130 RETURN