Antic 4/5 Editor Animator, graphics program (DEMO.BAS)
Antic 4/5 Editor Animator, graphics program by Paul Chabot, 42
Description
Antic 4/5 Editor Animator, graphics program by Paul Chabot, 42
From the Antic disk of October 1984 (Vol. 3 No. 6).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 3.2 KB
- Dialect
- Atari BASIC
- Lines
- 92
- Variables
I,J,COPY,IO,LOD,SAV,RAM,ROM,CHW,CHS,K,DL,B$,XO,YO,X,Y,ET$,EB$,DT$,DB$,DS(,ES(,DW,EW,N,M,ST,Z
BASIC listing (92 lines)
1 REM DEMO
6 GOSUB 200:GOTO 20
10 REM **** ERASE/PRINT "EATER" ****
11 POSITION XO,YO:? #6;B$;
12 POSITION XO,YO+1:? #6;B$;
14 POSITION X,Y:? #6;ET$;
16 POSITION X,Y+1:? #6;EB$;
18 RETURN
20 REM **** MAIN LOOP ****
22 N=N+1:IF N>9 THEN N=0
24 I=USR(COPY,48,ES(N),EW)
26 M=M+1:IF M>4 THEN M=0
28 I=USR(COPY,48,DS(M),DW)
30 IF STRIG(0)=0 THEN GOSUB 150
40 ST=STICK(0)
42 IF ST=7 OR ST=11 THEN 50
44 IF ST=13 OR ST=14 THEN 60
46 GOTO 20
50 X=XO+(ST=7)-(ST=11):IF X<1 THEN X=1
52 IF X>36 THEN X=36
54 GOSUB 10:XO=X:GOTO 20
60 Y=Y+(ST=13)-(ST=14):IF Y<1 THEN Y=1
62 IF Y>18 THEN Y=18
64 GOSUB 10:YO=Y:GOTO 20
150 REM **** TRIGGER PRESSED ****
152 GOSUB 250
160 RETURN
200 REM **** INITIALIZE ****
202 GOSUB 300:GOSUB 400:GOSUB 500
210 DIM DT$(3),DB$(3),ET$(3),EB$(3)
212 DIM B$(3),DS(4),ES(9)
220 DT$(1)=CHR$(0):DT$(2)=CHR$(2):DT$(3)=CHR$(4)
222 DB$(1)=CHR$(1):DB$(2)=CHR$(3):DB$(3)=CHR$(5)
224 ET$(1)=CHR$(6):ET$(2)=CHR$(8):ET$(3)=CHR$(10)
226 EB$(1)=CHR$(7):EB$(2)=CHR$(9):EB$(3)=CHR$(11)
228 B$=" "
230 DW=CHW+512:EW=DW+48
232 FOR I=0 TO 4:DS(I)=CHS+512+48*I:NEXT I
234 FOR I=0 TO 9:ES(I)=CHS+32+48*I:NEXT I
240 FOR K=0 TO 8:GOSUB 250:NEXT K
242 X=20:Y=10:XO=20:YO=10
244 POSITION XO,YO:GOSUB 10
246 RETURN
250 REM **** PLACE A DOT ****
252 I=INT(36*RND(0))+1
254 J=INT(18*RND(0))+1
256 POSITION I,J:? #6;DT$;
258 POSITION I,J+1:? #6;DB$;
260 I=PEEK(712)+16:IF I>255 THEN I=0
262 POKE 712,I
270 RETURN
300 REM **** ANMAT.PG6 ****
302 RESTORE 330
304 FOR I=1536 TO 1607
306 READ J:POKE I,J:NEXT I
308 COPY=1536:IO=1561:LOD=7:SAV=11
310 RETURN
330 REM **** COPY.....1536
332 DATA 104,104,104,168,104,133,213
334 DATA 104,133,212,104,133,215,104
336 DATA 133,214,136,177,212,145,214
338 DATA 152,208,248,96
340 REM **** IO.......1561
342 DATA 169,64,133,212,169,3,133,213
344 DATA 104,104,104,10,10,10,10,170
346 DATA 216,24,105,9,168,104,145,212
348 DATA 136,104,145,212,136,136,136
350 DATA 104,145,212,136,104,145,212
352 DATA 136,136,104,104,145,212
354 DATA 76,86,228
360 REM **** 1608
400 REM **** LOAD CHARSETS ****
402 RAM=PEEK(106)
404 CHW=256*(RAM-8):CHS=256*(RAM-12)
410 OPEN #1,4,0,"D:ROM.SET"
412 I=USR(IO,1,1024,CHW,LOD):CLOSE #1
414 OPEN #1,4,0,"D:ROM.SET"
416 I=USR(IO,1,1024,CHS,LOD):CLOSE #1
420 RETURN
500 REM **** FIX DISPLAY LIST ****
502 GRAPHICS 0:POKE 752,1
504 ? " ANTIC 4 ANIMATION";
506 POKE 703,4:POKE 756,RAM-8
508 DL=PEEK(560)+256*PEEK(561)
510 FOR I=6 TO 24:POKE DL+I,4:NEXT I
520 FOR I=0 TO 11:POSITION 0,I+4
522 ? #6;CHR$(I);:POSITION 39,I+4
524 ? #6;CHR$(I);:NEXT I
530 ? :? " <trigger> - for more DOTS"
540 POKE 708,132:POKE 709,24
542 POKE 710,82:POKE 712,8*16
550 RETURN
