Rotate Your Player, assembly language tutorial (ROTATE.BAS)

Rotate Your Player, assembly language tutorial by Larry Parker, 64

Description

Rotate Your Player, assembly language tutorial by Larry Parker, 64

From the Antic disk of September 1984 (Vol. 3 No. 5).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 1.2 KB

Dialect
Atari BASIC
Lines
44
Variables
ROT$, I, A, RAM, U, X, PM, P0, S, DIR, D
BASIC listing (44 lines)
10 REM ANTIC MAGAZINE
20 REM PLAYER MISSILE ROTATOR
30 REM BY LARRY PARKER
40 REM
70 REM READ MACHINE LANGUAGE DATA
80 REM INTO ROT$
100 DIM ROT$(60)
110 FOR I=1 TO 57:READ A:ROT$(I,I)=CHR$(A):NEXT I
120 DATA 104,104,133,204,104,133,203
130 DATA 104,104,133,205,104,104,133
140 DATA 206,160,0,24,165,206,208
150 DATA 11,177,203,10,144,14,24
160 DATA 105,1,24,144,8,177,203
170 DATA 74,144,3,24,105,128,145
180 DATA 203,200,196,205,208,225,96
190 REM --------------------
200 REM PLAYER MISSILE SETUP
210 REM --------------------
220 RAM=PEEK(106):POKE 106,RAM-8:GRAPHICS 0:POKE 752,1:?
230 U=PEEK(106):X=120
240 POKE 704,14
250 POKE 54279,U
260 PM=256*U
270 FOR I=PM+512 TO PM+640:POKE I,0:NEXT I
280 P0=PM+512+80
290 RESTORE 360
300 FOR I=P0 TO P0+7
310 READ A
320 POKE I,A
330 NEXT I
340 POKE 559,46:POKE 53277,3
350 POKE 53248,X
360 DATA 60,126,219,255,189,195,126,60
370 REM -------------
380 REM ROTATE PLAYER
390 REM -------------
400 S=STICK(0)
410 IF S=7 THEN DIR=1:X=X+1:GOTO 440
420 IF S=11 THEN DIR=0:X=X-1:GOTO 440
430 GOTO 400
440 POKE 53248,X
450 A=USR(ADR(ROT$),P0+2,4,DIR)
460 FOR D=1 TO 3:NEXT D
470 GOTO 400