Antic's Mode 3, access special character mode (HIDDEN.BAS)

Antic's Mode 3, access special character mode by Karl Wiegers, 32

Description

Antic's Mode 3, access special character mode by Karl Wiegers, 32

From the Antic disk of September 1984 (Vol. 3 No. 5).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 1.5 KB

Dialect
Atari BASIC
Lines
41
Variables
DL, I, MEM, RAMSTART, A, J, OFFSET
BASIC listing (41 lines)
10 REM Reserve 4 pages of RAM for character set
20 MEM=PEEK(106)-4:POKE 106,MEM-1:RAMSTART=256*MEM
30 GRAPHICS 0
40 REM Turn off TV display
50 POKE 559,0
60 REM Find start of display list
70 DL=PEEK(560)+256*PEEK(561)
80 REM Modify display list to ANTIC mode 3
90 POKE DL+3,67
100 FOR I=6 TO 24:POKE DL+I,3:NEXT I
110 POKE DL+25,65
120 POKE DL+26,PEEK(DL+30)
130 POKE DL+27,PEEK(DL+31)
140 REM Load ML routine
150 FOR I=1 TO 35:READ A:POKE 1535+I,A:NEXT I
160 DATA 104,160,255,162,7,177,203,72,136,177,203,200,145,205
170 DATA 136,202,208,246,104,145,205,136,192
180 DATA 255,208,233,198,206,198,204,198,207,208,223,96
190 REM Initialize work variables for character set transfer to RAM
200 POKE 203,0:POKE 204,227
210 POKE 205,0:POKE 206,MEM+3:POKE 207,4
220 REM Call ML routine to move character set
230 A=USR(1536)
240 FOR J=1 TO 10:READ OFFSET:OFFSET=OFFSET*8
250 FOR I=0 TO 7:READ A:POKE RAMSTART+I+OFFSET,A:NEXT I:NEXT J
260 REM comma,semicolon,g,j,p,q,y
270 REM CTRL-.,CTRL-;,Shift-=
280 DATA 12,0,0,0,0,0,24,24,48
290 DATA 27,0,0,24,24,0,24,24,48
300 DATA 103,102,60,0,62,102,102,62,6
310 DATA 106,6,60,6,0,31,6,6,6
320 DATA 112,96,240,0,124,102,102,124,96
330 DATA 113,6,15,0,62,102,102,62,6
340 DATA 121,24,48,0,102,102,102,62,12
350 DATA 96,48,126,0,0,60,102,12,24
360 DATA 123,102,60,0,0,126,12,24,12
370 DATA 124,126,12,0,0,12,28,60,108
380 REM Turn on new character set
390 POKE 756,MEM
400 REM Turn on TV display
410 POKE 559,34