Drawing Fun, Graphics 10 drawing program (DRAWFUN.BAS)

Drawing Fun, Graphics 10 drawing program by Elrhea M. Bigham, 29

Description

Drawing Fun, Graphics 10 drawing program by Elrhea M. Bigham, 29

From the Antic disk of September 1984 (Vol. 3 No. 5).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 3.5 KB

Dialect
Atari BASIC
Lines
59
Variables
C$, CIO$, FILE$, B$, C1$, S(, H, U1, U16, DA, QQ, QQ1, I, U, T, A, AL, SG, X, Y, C, Z, F, E, S, R, Q, B, Y1, J, CMD, STADR, BYTES, ERROR
BASIC listing (59 lines)
10 REM DRAWING FUN
20 REM BY ELRHEA M. BIGHAM
30 REM ANTIC MAGAZINE
40 DIM C$(4),CIO$(7),FILE$(20),B$(17),C1$(30),S(35):C1$="h"♥,A▕=B▕↓A▕h◆◢♣u▘H▕◆AAAAAA":H=6:U1=1:U16=16
50 POKE 16,112:POKE 53774,112:IF DA THEN RETURN :REM DISABLE BREAK KEY
60 GRAPHICS 17:DA=1:H=6:POKE 710,134:POKE 708,198:POKE 709,88:QQ=764:QQ1=255:RESTORE 370:FOR I=1 TO 35:S(I)=U:T=U
70 NEXT I:? #H;"DRAWING INSTRUCTIONS":? #H;"stick to DRAW with   ":? #H;"button changes COLOR":CLOSE #1
80 ? #H;"tab key MOVES color ":? #H;"clear key to CLEAR":? #H:? #H;"i INVISIBLE cursor":? #H:? #H;"e ERASE mode"
90 ? #H:? #H;"c CONTINUE move":? #H:? #H;"f line FILL to RIGHT":? #H;"l to LOAD":? #H:? #H;"s to SAVE"
100 FOR I=U1 TO H:READ A:S(A)=U1:NEXT I:? #H:? #H:? #H;"   PRESS ANY KEY":OPEN #U1,4,U,"K:":GET #U1,I
110 FOR I=U1 TO H:READ A:S(A)=-U1:NEXT I:CLOSE #U1:AL=U:SG=U1
120 GRAPHICS 10:RESTORE 390:FOR I=705 TO 712:READ A:POKE I,A:NEXT I:X=38:Y=100:C=U1:Z=U:COLOR C:I=U:F=U:E=U
130 POKE QQ,QQ1:GOSUB 50:IF T THEN RETURN
140 POKE 77,U:S=PEEK(632):SG=PEEK(644):IF AL AND S=15 THEN S=AL:SG=R
150 IF AL AND S<>15 THEN AL=S:R=SG
160 Q=S(S):H=S(S+20):X=X+Q*((X<79 AND Q=U1) OR (X>U AND Q=-U1)):Y=Y+H*((Y<184 AND H=U1) OR (Y>U AND H=-U1))
170 IF E THEN LOCATE X,Y,C:COLOR U1:PLOT X,Y
180 IF SG=U THEN C=U1+C*(C<9):E=U:COLOR C:IF I=U1 THEN I=U:C=B
190 IF I=U1 THEN PLOT X,Y:COLOR U1:PLOT X,Y:GOTO 220
200 IF F THEN TRAP 200:POSITION X,Y:POKE 765,C:XIO 18,#6,12,0,"S:"
210 PLOT X,Y:COLOR U:PLOT X,Y:IF Z THEN Y1=USR(ADR(C1$))
220 COLOR C:PLOT X,Y:A=PEEK(QQ):IF A=QQ1 THEN 140
230 POKE QQ,QQ1:IF A=44 AND Z=U THEN Z=U1:A=QQ1
240 IF A=44 AND Z THEN Z=U:RESTORE 390:FOR I=705 TO 712:READ J:POKE I,J:NEXT I
250 IF A=13 THEN E=U1:F=U:I=U
260 IF A=0 THEN C$="load":GOTO 410
270 IF A=62 THEN C$="save":GOTO 410
280 IF A=56 AND F=U1 THEN F=U:A=QQ1
290 IF A=56 AND F=U THEN F=U1:E=U:I=U
300 IF A=42 THEN I=U1:E=U:F=U:B=C:C=U
310 IF A=54 OR A=118 THEN 60
320 IF A=18 AND AL THEN A=QQ1:AL=U:R=U1
330 IF A=18 THEN AL=S:R=SG
340 PLOT X,Y:COLOR U:PLOT X,Y:IF Z THEN Y1=USR(ADR(C1$))
350 COLOR C:PLOT X,Y:GOTO 140
360 REM JOYSTICK MOVE DATA
370 DATA 5,6,7,25,29,33,9,10,11,26,30,34
380 REM GRAPHIC 10 COLOR DATA
390 DATA 6,36,70,102,132,166,226,42
400 REM LOADING OR SAVING A DRAWING
410 FILE$="":GOSUB 570:GRAPHICS 2:? #6;"FILE NAME to ";C$;"?":INPUT FILE$
415 IF LEN(FILE$)<3 AND FILE$(1,1)="C" THEN 500
417 IF LEN(FILE$)>U1 THEN 470
420 GRAPHICS 2:POKE 710,130:? #6;"FILE DIRECTORY":TRAP 460:OPEN #U1,6,U,"D:*.PIC":FOR I=U1 TO 9:INPUT #U1,B$
430 IF ASC(B$)<>32 THEN FOR I=U1 TO LEN(B$):? #6;CHR$(ASC(B$(I,I))+128);:NEXT I:GOTO 460
440 IF ASC(B$)=32 THEN B$=B$(2)
450 TRAP 460:? #6;B$:NEXT I
460 CLOSE #U1:? "File to ";C$;:INPUT FILE$:IF LEN(FILE$)<2 THEN 420
470 IF FILE$(1,2)<>"D:" THEN B$=FILE$:FILE$="D:":FILE$(3)=B$
480 A=LEN(FILE$):TRAP 490:IF FILE$(A-3)=".PIC" THEN 500
490 FILE$(A+1)=".PIC"
500 TRAP 60:CLOSE #2:IF C$="save" THEN I=8:CMD=11:POKE 559,0:GOSUB 520:POKE 559,34:GOTO 120
510 CMD=7:T=1:GOSUB 120:I=4:GOSUB 520:GOTO 140
520 OPEN #2,I,128,FILE$
530 J=STADR:GOSUB 560:POKE 868,B:POKE 869,A:J=BYTES:GOSUB 560:POKE 872,B:POKE 873,A
540 POKE 866,CMD:ERROR=USR(ADR(CIO$),32)
550 ERROR=PEEK(867):CLOSE #2:RETURN
560 A=INT(J/256):B=INT(J-A*256):RETURN
570 POKE 764,255:CIO$="hhh*LVd":BYTES=7400:STADR=PEEK(88)+256*PEEK(89):RETURN