Copymate, disk-sector copier (COPYMATE.BAS)

Copymate, disk-sector copier by Mike Palmer, 87

Description

Copymate, disk-sector copier by Mike Palmer, 87

From the Antic disk of September 1984 (Vol. 3 No. 5).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 3.3 KB

Dialect
Atari BASIC
Lines
93
Variables
I, X, BUFF$, A, A$, B$, DSKWRT, S, LO, AH, AL, SEC, BUFFAD, Y, DIR, DCOM, NDRIVE, SOURCE, DESTIN, DDIR, DTYPE, FMT, FMT$, VFY$, DRV$
BASIC listing (93 lines)
10 REM COPYMATE 1.4 CUSTOMIZER
20 REM BY MIKE PALMER
30 REM ANTIC MAGAZINE
40 DIM A$(128),B$(1),FMT$(1),VFY$(1),DRV$(1)
50 OPEN #1,4,0,"E:":POKE 710,148:POKE 712,148:POKE 82,0:POKE 752,1
60 A$="♥":A$(128)="♥":A$(2)=A$
70 DSKWRT=ADR("hLSd"):REM SECTOR I/O ROUTINE
80 PRINT "↰        COPYMATE 1.4 CUSTOMISER "
90 PRINT "↓↓↓↓↓↓↓     INSERT COPYMATE 1.4 BOOT DISK"
100 PRINT "↓  INTO DRIVE #1 - THEN PRESS  RETURN ↰←";
110 INPUT #1,B$
120 REM READ 1ST SECTOR OFF THE DISK
130 BUFFAD=ADR(A$)
140 SEC=1:DCOM=82:DDIR=64
150 GOSUB 790:REM SET UP DISK DCB
160 X=USR(DSKWRT):REM READ SECTOR
170 IF PEEK(771)=1 THEN 210
180 ? "↰↓↓↓    ERROR IN READING FROM DRIVE ONE"
190 ? "↓      CHECK IT OUT -- THEN RE-RUN↰↰↓↓↓↓↓↓↓↓↓↓↓"
200 END
210 REM ASK FOR NEW PARAMETERS
220 ? "↰ENTER REQUIRED DEFAULTS - CURRENT VALUES"
230 ? "↑   ARE SHOWN UNDER THE CURSOR AND MAY"
240 ? " BE ENTERED SIMPLY BY PRESSING  RETURN ↓↓"
250 POKE 752,0
260 TRAP 260
270 ? "↓ NUMBER OF DRIVES ON SYSTEM ? [1-8] :";ASC(A$(13));"←";
280 INPUT #1,NDRIVE
290 IF NDRIVE<1 OR NDRIVE>8 THEN 260
300 IF NDRIVE=1 THEN SOURCE=1:DESTIN=1:GOTO 390
310 TRAP 310
320 ? "↓ SOURCE DISK DRIVE ........ ? [1-";NDRIVE;"] :";ASC(A$(9));"←";
330 INPUT #1,SOURCE
340 IF SOURCE>NDRIVE OR SOURCE<1 THEN 310
350 TRAP 350
360 ? "↓ DESTINATION DISK DRIVE ... ? [1-";NDRIVE;"] :";ASC(A$(10));"←";
370 INPUT #1,DESTIN
380 IF DESTIN>NDRIVE OR DESTIN<1 THEN 350
390 TRAP 390
400 IF ASC(A$(11))=0 THEN FMT$="N"
410 IF ASC(A$(11))=1 THEN FMT$="Y"
420 ? "↓ FORMAT DESTINATION DISK .. ? [Y/N] :";FMT$;"←";
430 INPUT #1,FMT$
440 IF FMT$<>"N" AND FMT$<>"Y" THEN 390
450 TRAP 450
460 IF ASC(A$(12))=80 THEN VFY$="N"
470 IF ASC(A$(12))=87 THEN VFY$="Y"
480 ? "↓ WRITE WITH VERIFICATION .. ? [Y/N] :";VFY$;"←";
490 INPUT #1,VFY$
500 IF VFY$<>"N" AND VFY$<>"Y" THEN 450
510 TRAP 510
520 IF ASC(A$(14))=0 THEN DRV$="A"
530 IF ASC(A$(14))=26 THEN DRV$="P"
540 ? "↓ ATARI OR PERCOM DRIVES ... ? [A/P] :";DRV$;"←";
550 INPUT #1,DRV$
560 IF DRV$<>"A" AND DRV$<>"P" THEN 510
570 REM SET UP NEW VALUES
580 A$(9)=CHR$(SOURCE)
590 A$(10)=CHR$(DESTIN)
600 A$(13)=CHR$(NDRIVE)
610 IF FMT$="N" THEN A$(11)=CHR$(0)
620 IF FMT$="Y" THEN A$(11)=CHR$(1)
630 IF VFY$="N" THEN A$(12)=CHR$(80)
640 IF VFY$="Y" THEN A$(12)=CHR$(87)
650 IF DRV$="A" THEN A$(14)=CHR$(0)
660 IF DRV$="P" THEN A$(14)=CHR$(26)
670 REM WRITE 1ST SECTOR BACK TO DISK
680 SEC=1:DCOM=87:DDIR=128
690 GOSUB 790:REM SET UP DISK DCB
700 X=USR(DSKWRT):REM WRITE SECTOR
710 POKE 752,1
720 IF PEEK(771)=1 THEN 760
730 ? "↰↓↓↓     ERROR IN WRITING TO DRIVE ONE"
740 ? "↓  CHECK IT OUT -- THEN PRESS  RETURN "
750 INPUT #1,B$:GOTO 690
760 ? "↓↓↓  COPYMATE 1.4 CUSTOMIZATION COMPLETE"
770 ? "↓  REMOVE BASIC CART BEFORE RE-BOOTING":? :?
780 END
790 REM DISK DCB SET UP SUBROUTINE
800 POKE 768,49:REM DEVICE = DISK
810 POKE 769,1:REM UNIT = 1
820 POKE 770,DCOM:REM COMMAND
830 POKE 771,DDIR:REM DIRECTION
840 AH=INT(BUFFAD/256)
850 AL=BUFFAD-AH*256
860 POKE 772,AL:REM BUFFER ADDRESS LO
870 POKE 773,AH:REM BUFFER ADDRESS HI
880 POKE 774,7:REM TIMEOUT IN SECS
890 POKE 776,128:REM TRANSFER COUNT LO
900 POKE 777,0:REM TRANSFER COUNT HI
910 POKE 778,SEC:REM SECTOR NUMBER LO
920 POKE 779,0:REM SECTOR NUMBER HI
930 RETURN