Easy Graphic Converter, graphics utility (CONVERT.BAS)
Easy Graphic Converter, graphics utility by Charles Jackson, 57
Description
Easy Graphic Converter, graphics utility by Charles Jackson, 57
From the Antic disk of September 1984 (Vol. 3 No. 5).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 5.9 KB
- Dialect
- Atari BASIC
- Lines
- 138
- Variables
IN$,IN1$,OUT$,OUT1$,COLREG(,TYP1,TYP2,L,TYPE,COUNT,X,M,TOT,Y,LN,R,N,K,HOLD$,T(,Q$,NUM,D,TIM
BASIC listing (138 lines)
10 REM GRAPHICS CONVERTER
20 REM BY CHARLES JACKSON
30 REM ANTIC MAGAZINE
40 FOR N=78 TO 66 STEP -1:POKE 710,N:POKE 712,N:POKE 709,268-N:FOR Y=1 TO 14:NEXT Y:NEXT N
50 DIM IN$(11),IN1$(13),OUT$(11),OUT1$(13),HOLD$(13),Q$(1),COLREG(4)
60 ? "↰ *** GRAPHICS CONVERTER ***":?
70 POKE 710,66:POKE 712,66:POKE 709,202
80 ? "(1) Micro Illustrator"
90 ? " (Tech-Sketch, Koala, "
100 ? " Chalkboard)":?
110 ? "(2) Micro Painter"
120 ? " (Datasoft)":?
130 ? "(3) Moviemaker"
140 ? " (Reston)":?
150 ? "(4) Fun with Art"
160 ? " (Epyx)":?
170 REM NUM = Number of types
180 NUM=4:TIM=6
190 ? :? "Type of source file (1-4) ";:INPUT TYP1:?
200 IF TYP1>NUM THEN 190
210 ? " Filename ";:INPUT IN$:?
220 IN1$=" ":OUT1$=" "
230 IN1$(1,2)="D:":IN1$(3,13)=IN$
240 ? "Type of desired file (1-4) ";:INPUT TYP2:?
250 IF TYP2>NUM THEN 240
260 IF TYP1<>TYP2 THEN 280
270 ? "↰↓↓↓↓▶NEEDLESS CONVERSION":FOR D=1 TO 500:NEXT D:GOTO 60
280 IF TYP2<>1 THEN 340
290 TIM=3.5
300 POKE 709,96:POKE 710,108:POKE 712,108:? "↰↓↓↓↓↓↓↓Micro Illustrator files must be named 'PICTURE'"
310 ? :? "Press 'Y' to name the output file.":INPUT Q$
320 IF Q$<>"Y" THEN 60
330 OUT$="PICTURE":L=7:POKE 710,66:POKE 712,66:POKE 709,202:GOTO 360
340 ? " Destination filename":? " (No ext.)";:INPUT OUT$:L=LEN(OUT$):?
350 IF TYP2=3 AND L>7 THEN 340
360 OUT1$(1,2)="D:":OUT1$(3,L+2)=OUT$
370 IF TYP2<>3 THEN 390
380 OUT1$(L+3,L+6)=".BKG":GOTO 390
390 TYPE=NUM*TYP1+TYP2
400 ? " Please stand by . . ."
410 ? :? "(Approximate conversion"
420 ? " time: ";TIM;" minutes)"
430 REM BRANCH TO CONVERSION ROUTINES
440 ON (TYPE-(NUM+1)) GOSUB 510,560,590,720,0,620,1100,860,770,0,890,1040,920,1070
450 ? " Still working . . ."
460 IF (TYP1=2) OR (TYP2=2) THEN 1350
470 REM DELETE TEMP. FILE
480 OPEN #3,12,0,"D:TEMP"
490 XIO 33,#3,0,0,"D:TEMP":CLOSE #3
500 GOTO 1350
510 REM Micro Illustrator to Micro Painter
520 OPEN #1,4,0,IN1$:OPEN #2,8,0,OUT1$
530 FOR X=1 TO 7680:GET #1,M:PUT #2,M:NEXT X
540 PUT #2,12:PUT #2,40:PUT #2,202:PUT #2,150
550 CLOSE #1:CLOSE #2:RETURN
560 REM Micro Illustrator to Movie Maker
570 HOLD$=OUT1$:OUT1$="D:TEMP":GOSUB 510
580 IN1$=OUT1$:OUT1$=HOLD$:GOTO 620
590 REM Micro Illustrator to Fun With Art
600 HOLD$=OUT1$:OUT1$="D:TEMP":GOSUB 510
610 IN1$=OUT1$:OUT1$=HOLD$:GOTO 1100
620 REM Micro Painter to Movie Maker
630 OPEN #1,4,0,IN1$:OPEN #2,8,0,OUT1$
640 COUNT=0:POKE 710,66
650 TRAP 710
660 FOR X=1 TO 40:GET #1,M:PUT #2,M:COUNT=COUNT+1
670 IF COUNT=3844 THEN 700
680 NEXT X
690 FOR X=1 TO 40:GET #1,M:NEXT X:GOTO 650
700 FOR X=1 TO 30:PUT #2,0:NEXT X:PUT #2,106
710 TRAP 40000:CLOSE #1:CLOSE #2:RETURN
720 REM Micro Painter to Micro Illustrator
730 OPEN #1,4,0,IN1$:OPEN #2,8,0,OUT1$
740 FOR X=1 TO 7680:GET #1,M:PUT #2,M:NEXT X
750 CLOSE #1:CLOSE #2
760 RETURN
770 REM Movie Maker to Micro Painter
780 OPEN #1,4,0,IN1$:OPEN #2,8,0,OUT1$
790 DIM T(40)
800 K=0
810 FOR X=1 TO 96
820 FOR Y=1 TO 40:GET #1,M:PUT #2,M:T(Y)=M:NEXT Y
830 FOR Y=1 TO 40:PUT #2,T(Y):NEXT Y:NEXT X
840 FOR Y=1 TO 4:GET #1,M:PUT #2,M:NEXT Y
850 TRAP 40000:CLOSE #1:CLOSE #2:RETURN
860 REM Movie Maker to Micro Illustrator
870 HOLD$=OUT1$:OUT1$="D:TEMP":GOSUB 770
880 IN1$=OUT1$:OUT1$=HOLD$:GOTO 720
890 REM Movie Maker to Fun with Art
900 HOLD$=OUT1$:OUT1$="D:TEMP":GOSUB 770
910 IN1$=OUT1$:OUT1$=HOLD$:GOTO 1100
920 REM Fun With Art to Micro Painter
930 OPEN #1,4,0,IN1$:OPEN #2,8,0,OUT1$
940 GET #1,M:GET #1,M
950 FOR X=1 TO 4:GET #1,M:COLREG(X)=M:NEXT X
960 FOR X=1 TO 256:GET #1,M:NEXT X
970 FOR X=1 TO 7696
980 GET #1,M
990 IF X>4080 AND X<4097 THEN 1010
1000 PUT #2,M
1010 NEXT X
1020 FOR X=1 TO 4:PUT #2,COLREG(X):NEXT X
1030 CLOSE #1:CLOSE #2:RETURN
1040 REM Fun with Art to Micro Illustrator
1050 HOLD$=OUT1$:OUT1$="D:TEMP":GOSUB 920
1060 IN1$=OUT1$:OUT1$=HOLD$:GOTO 720
1070 REM Fun with Art to Movie Maker
1080 HOLD$=OUT1$:OUT1$="D:TEMP":GOSUB 920
1090 IN1$=OUT1$:OUT1$=HOLD$:GOTO 620
1100 REM Micro Painter to Fun with Art
1110 OPEN #1,4,0,IN1$:OPEN #2,8,0,OUT1$
1120 FOR X=1 TO 262:READ N:PUT #2,N:NEXT X
1130 FOR X=1 TO 7696
1140 IF X>4080 AND X<4097 THEN PUT #2,0:GOTO 1160
1150 GET #1,M:PUT #2,M
1160 NEXT X
1170 PUT #2,0:PUT #2,0
1180 FOR X=1 TO 4:GET #1,M:COLREG(X)=M:NEXT X
1190 CLOSE #1:CLOSE #2:OPEN #2,12,0,OUT1$
1200 PUT #2,254:PUT #2,254
1210 FOR X=1 TO 4:PUT #2,COLREG(X):NEXT X
1220 CLOSE #2
1230 RETURN
1240 DATA 254,254
1250 DATA 1,2,3,4,112,112,112,78,0,80,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14
1260 DATA 14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14
1270 DATA 14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14
1280 DATA 14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14
1290 DATA 14,14,14,14,14,14,14,78,0,96,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14
1300 DATA 14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14
1310 DATA 14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14
1320 DATA 14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,14,65,0,6,104,170
1330 DATA 104,141,1,2,232,208,3,238,1,2,142,0,2,104,170,104,64,169,0,141,0,2,169,0,141,1
1340 DATA 2,169,192,141,14,212,76,95,228,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
1350 ? :? "↰ File: ";OUT1$(3,LEN(OUT1$))
1360 ? "Created and stored."
1370 FOR N=66 TO 148:POKE 710,N:POKE 712,N:POKE 709,54+N:NEXT N:POKE 712,0
1380 END
