Unlocking the 56 Graphics Modes, explore graphics modes (ALLMODES.BAS)

Unlocking the 56 Graphics Modes, explore graphics modes by Paul Chabot, 13

Description

Unlocking the 56 Graphics Modes, explore graphics modes by Paul Chabot, 13

From the Antic disk of September 1984 (Vol. 3 No. 5).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.6 KB

Dialect
Atari BASIC
Lines
83
Variables
K, I, M, DL, W, SA, SH, SL, RAND(
BASIC listing (83 lines)
5 REM ALLMODES
6 REM BY PAUL CHABOT
7 REM ANTIC MAGAZINE
10 GOSUB 200
20 K=PEEK(764):IF K<64 THEN 40
30 FOR I=1536 TO 1575
32 POKE I,PEEK(53770):NEXT I
34 GOTO 20
40 POKE 764,255
50 REM LINKAGE
52 IF K=50 THEN M=2:GOSUB 100:REM ..0
54 IF K=31 THEN M=6:GOSUB 100:REM ..1
56 IF K=30 THEN M=7:GOSUB 100:REM ..2
58 IF K=26 THEN M=8:GOSUB 100:REM ..3
60 IF K=24 THEN M=9:GOSUB 100:REM ..4
62 IF K=29 THEN M=10:GOSUB 100:REM .5
64 IF K=27 THEN M=11:GOSUB 100:REM .6
66 IF K=51 THEN M=13:GOSUB 100:REM .7
68 IF K=53 THEN M=15:GOSUB 100:REM .8
70 IF K=63 THEN M=3:GOSUB 100:REM ..A
72 IF K=21 THEN M=4:GOSUB 100:REM ..B
74 IF K=18 THEN M=5:GOSUB 100:REM ..C
76 IF K=58 THEN M=12:GOSUB 100:REM .D
78 IF K=42 THEN M=14:GOSUB 100:REM .E
80 IF K=62 THEN GOSUB 120:REM ......S
82 IF K=40 THEN GOSUB 140:REM ......R
84 IF K=61 THEN GOSUB 150:REM ......G
90 GOTO 20
100 REM MODE CHANGE
102 POKE DL+3,64+M
104 FOR I=DL+6 TO DL+14
106 FOR W=0 TO 20:NEXT W
108 POKE I,M:NEXT I
110 RETURN
120 REM SCREEN AREA CHANGE
122 ? :? :? :? :POKE 656,0
124 ? "SCREEN AREA NOW BEGINS AT ";SA
126 ? :? "INPUT A NEW BEGIN ADDRESS"
128 INPUT SA
130 SH=INT(SA/256):SL=SA-256*SH
132 POKE DL+4,SL:POKE DL+5,SH
134 GOSUB 250:RETURN
140 REM RESTORE SCREEN
142 SL=PEEK(88):SH=PEEK(89)
143 POKE 623,0
144 SA=SL+256*SH
146 POKE DL+4,SL:POKE DL+5,SH
147 GOSUB 250
148 M=7:GOSUB 100:RETURN
150 REM GTIA MODES
152 I=PEEK(623)+64:POKE 712,48
154 IF I>255 THEN I=I-256
156 IF I>191 THEN POKE 712,8
158 POKE 623,I:RETURN
200 REM INITIALIZE
202 GRAPHICS 2
204 DL=PEEK(560)+256*PEEK(561)
206 SA=PEEK(88)+256*PEEK(89)
210 ? #6;" AAAAAAAAAAAAAAAAAA"
212 ? #6;" l      ****      r"
214 ? #6;" l  ++++++++++++  r"
216 ? #6;" l    allmodes    r"
218 ? #6;" l  ++++++++++++  r"
220 ? #6;" l      ****      r"
222 ? #6;" l       BY       r"
224 ? #6;" l  PAUL  CHABOT  r"
226 ? #6;" l      1983      r"
228 ? #6;" BBBBBBBBBBBBBBBBBB"
230 FOR I=0 TO 15:POKE 1616+I,I
232 POKE 1636+I,I:POKE 1656+I,I
234 POKE 1676+I,I:POKE 1696+I,17*I
236 POKE 1736+I,17*I:POKE 1756+I,I
238 NEXT I
240 POKE 712,48:POKE 704,12*16
242 POKE 705,6*16+6:POKE 706,15*16+4
244 POKE 707,166
250 REM MAIN MENU
252 ? :? :? :? :POKE 656,0:POKE 752,1
254 ? " 0  GR.0   A  Antic3   E  GR.7+"
256 ? " 1  GR.1   B  Antic4   G  GTIA"
258 ? " 2  GR.2   C  Antic5   S  Screen Area"
260 ? "... etc.   D  GR.6+    R  Restore";
270 RETURN