It's Mere Horsplay, handicapping program (HORSPLAY.BAS)

It's Mere Horsplay, handicapping program by Dave Elwood, 20

Description

It's Mere Horsplay, handicapping program by Dave Elwood, 20

From the Antic disk of August 1984 (Vol. 3 No. 4).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 12.5 KB

Dialect
Atari BASIC
Lines
323
Variables
SET$, CHBASE, Z, BYTE, I, CODE, TEMP, DL, INST, X, DLY, BLANK$, TRK$, DAT$, ANS$, TYPE$, GRAS$, H$, ODDS$, FILE$, A$, TEMP$, BL$, DAY$, H(, ES(, WT(, RACE$, SORT(, N, NUM, YN, A, CLASS, FL, GR, HO, TL, START, FP, WINS, TWOS, WONS, CPTS, LNGS, LBS, TOT, PCT, LOOP, TBL, PFLAG, M, J, L, DATA, WAIT
BASIC listing (323 lines)
100 REM HORSEPLAY
102 REM BY DAVE ELWOOD
104 REM ANTIC MAGAZINE
110 REM MAIN TITLE FOR "HORSPLAY"
113 GRAPHICS 0:? "Wait....":POKE 82,0
116 DIM SET$(32+424)
119 CHBASE=(PEEK(106)-8)*256
122 REM SET$=NEW CHARACTER SET
125 FOR Z=1 TO 32:SET$(Z)="♥":NEXT Z
128 SET$(33)="♥rrrrrrr♥◀◀◀rrrr♥◀◀◀rrrr♥◀◀◀ppp◀♥◀◀◀pppp♥◀◀◀rrrr♥ppppppp♥◀◀◀rrrr♥rrrrrrr♥▶@FONGO♥▶♥→♣♣♣ "
131 SET$(121)="♥▶♥x◢◢◢┤♥◀▕brbrr♥♥♥♥♥   ▶♥▶♥♥♥♥♥  ◆♥♥♥♥♥r◀◀◀rrr♥rrrr◀◀◀♥r◀◀◀tvv♥◀▕▕▕◀◀◀♥||pp◀◀◀♥r◀◀◀ppp♥"
134 SET$(209)="pppp◀◀◀♥r◀◀◀rrr♥rr◀◀▘▘▘♥F@C\PPPP@♥♥♥♥♥♥♥▕├♥♥♥♥♥♥b▕B:◣◣◣◣        ♥♥♥♥▶♥▶♥♥▶♥▶♥♥♥♥PPPP\C@F"
137 SET$(297)="♥♥♥♥♥♥♥@♥♥♥♥♥♥├▕◣◣◣◣:B▕b→♥╲♥♥♥♥♥ONGOF@▶♥ ♣♣♣→♥▶♥┤◢◢◢x♥▶♥rbrrb▕◀♥♥♥♥♥♥♥@◆♥♥♥♥▖→▶?♥╲▖→/w▶▶"
140 SET$(385)="♥Xt↰▶▶▶▶♥♥♥♥x|◀▂▶|♥♥♥♥♥♥???→▖╲╲┘▶▶▶▶→┘♥◆◀|xxp|↑┴╱▕├♥♥♥♥♥p◢┤♥@@@♥┴┴8♥♥♥♥♥"
143 REM INSTALL NEW CHARACTER SET
146 FOR BYTE=1 TO 456:POKE CHBASE+BYTE-1,ASC(SET$(BYTE,BYTE)):NEXT BYTE
149 REM POKE IN DLI ROUTINE
152 FOR I=1664 TO 1699:READ CODE:POKE I,CODE:NEXT I
155 DATA 72,169,224,141,9,212,169,146,141,0,2,169,6,141,1,2,104,64
158 DATA 72,169,152,141,9,212,169,128,141,0,2,169,6,141,1,2,104,64
161 REM POKE IN NEW DISPLAY LIST
164 TEMP=PEEK(559):POKE 559,0
167 POKE 560,0:POKE 561,6
170 DL=1536
173 FOR BYTE=0 TO 3:READ INST
176 POKE DL+BYTE,INST:NEXT BYTE
179 POKE DL+4,PEEK(88):POKE DL+5,PEEK(89)
182 FOR BYTE=6 TO 20:READ INST
185 POKE DL+BYTE,INST:NEXT BYTE
188 POKE DL+21,PEEK(560):POKE DL+22,PEEK(561)
191 DATA 112,112,112,71,7,7,7,7,135,6,6,6,6,6,134,7,7,7,65
194 ? CHR$(125)
197 POKE 756,PEEK(106)-8
200 POKE 512,128:POKE 513,6:POKE 54286,192
206 POKE 708,198:POKE 709,48:POKE 712,244:POKE 559,TEMP
212 POSITION 20,0:? #6;"   -.CCCCCCCCC/01"
215 POSITION 0,1:? #6;"   =>┤┐╱╲◢▗◣▝▘?@A"
218 POSITION 20,1:? #6;"   DE●▄▎┬┴▌└␛↑FGA"
221 POSITION 0,2:? #6;"   IJBBBBBBBBBKLA"
224 POSITION 20,2:? #6;"   H2222222222223"
227 POSITION 3,3:? "by dave elwood"
230 ? " *PREDICTING ODDS*      press start"
233 FOR X=1 TO 15 STEP 7
236 POSITION X,6:? #6;"mnopq"
239 POSITION X+20,6:? #6;"rstu"
242 POSITION X,7:? #6;" vwx"
245 NEXT X
248 POKE 711,255:FOR DLY=1 TO 50:NEXT DLY
251 IF PEEK(53279)=6 THEN POKE 82,2:GOTO 263
254 POKE 711,244:FOR DLY=1 TO 50:NEXT DLY
257 GOTO 248
260 REM *** Main Program Here **
263 OPEN #1,12,0,"E:":OPEN #2,4,0,"K:"
266 DIM BLANK$(320):BLANK$=" ":BLANK$(320)=BLANK$:BLANK$(2)=BLANK$
269 DIM TRK$(15),DAT$(15),ANS$(1),TYPE$(1),GRAS$(1),H$(15),ODDS$(4),FILE$(20)
272 DIM A$(120),TEMP$(10),BL$(10),DAY$(9),H(12),ES(12),WT(12),RACE$(2),SORT(12)
275 GRAPHICS 0
278 DL=PEEK(560)+PEEK(561)*256
281 REM ***DLI for Color change***
284 FOR I=1536 TO 1546
287 READ X:POKE I,X:NEXT I
290 DATA 72,169,50,141,10,212,141,24,208,104,64
293 POKE DL+19,130
296 POKE 512,0:POKE 513,6:POKE 54286,192
299 POKE 712,48:POKE 710,52
302 REM ***Modify DL for Title***
305 POKE DL+3,71:POKE DL+6,0:POKE DL+7,6
308 ? CHR$(125):POSITION 6,0
311 TRAP 308:REM Trap for nonnumeric input
314 ? "HORSPLAY"
317 IF N=0 THEN 329
320 ? TRK$;"  ";DAT$;"         RACE ";RACE$
323 ? "The Field:":?
326 GOSUB 770
329 POSITION 14,13:? "MAIN MENU"
332 ? :? "1 HDCP A NEW RACE   5 PRINT THIS RACE"
335 ? "2 GET A SAVED RACE  6 SAVE THIS RACE"
338 ? "3 SCRATCH A HORSE   7 DELETE A FILE"
341 ? "4 SEE DISK FILES    8 QUIT"
344 ? :? "         CHOOSE==>";:GET #2,NUM
347 POSITION 0,14:? BLANK$
350 NUM=VAL(CHR$(NUM))
353 ON NUM GOSUB 362,1028,1076,1055,1100,1003,1067,1112
356 GOTO 293
359 REM ***Handycap a new Race***
362 GRAPHICS 0:POKE 710,196:POKE 712,242
365 POKE 710,196:POKE 712,242
368 POSITION 10,3:? "FOLLOW EACH ANSWER"
371 POSITION 13,4:? "WITH RETURN"
374 FOR DLY=1 TO 200:NEXT DLY
377 ? :? "WHAT TRACK ------- ";:INPUT #1,TRK$
380 ? "DATE ------------- ";:INPUT #1,DAT$
383 TRAP 383
386 POSITION 2,8:? "WHICH RACE ------- ";:INPUT #1,RACE$
389 TRAP 389
392 POSITION 2,9:? "HOW MANY HORSES -- ";:INPUT #1,N
395 IF N>12 THEN 392
398 ? :? "WHAT WAS THE APPROX DATE 30 DAYS AGO"
401 ? "               ===>";:INPUT #1,DAY$:?
404 POSITION 6,15
407 ? "EVERYTHING ABOVE OK?(Y/N)";:GET #2,YN
410 IF YN=ASC("Y") THEN GOTO 419
413 IF YN=ASC("N") THEN GOTO 362
416 GOTO 404
419 TRAP 40000:? CHR$(125)
422 ? "A) Is this race a...."
425 ? :? "   Claiming race    Stakes race"
428 ? :? "   Allowance race   Handicap race"
431 POSITION 5,8:? "Type in the letter ===>";:GET #2,A
434 IF A=ASC("C") THEN CLASS=833:GOTO 449
437 IF A=ASC("A") THEN CLASS=848:GOTO 449
440 IF A=ASC("S") THEN CLASS=890:GOTO 449
443 IF A=ASC("H") THEN CLASS=890:GOTO 449
446 GOTO 431
449 REM
452 POSITION 2,8:? "B) One Mile or more (Y/N)";:GET #2,FL
454 IF FL=ASC("Y") OR FL=ASC("N") THEN 464
461 GOTO 452
464 POSITION 2,10:? "C) Is this a grass race (Y/N)";:GET #2,GR
468 IF GR=ASC("Y") OR GR=ASC("N") THEN 479
473 GOTO 464
479 ? CHR$(125)
482 REM ***store names in pseudo array***
485 ? "D) Type in the horses names":?
488 BL$=" ":BL$(10)=BL$:BL$(2)=BL$
494 FOR HO=1 TO N:? "NO.";HO;"HORSE:";:INPUT #1,TEMP$
500 TL=LEN(TEMP$):IF TL<10 THEN TEMP$(TL+1)=BL$
503 START=(HO-1)*10+1:A$(START)=TEMP$:NEXT HO
512 POSITION 6,21:? "EVERYTHING LOOK OK (Y/N)";:GET #2,YN
515 IF YN=ASC("Y") THEN 527
518 IF YN=ASC("N") THEN 479
521 GOTO 512
524 REM *** Initialize Array ***
527 FOR HO=1 TO N:H(HO)=10:NEXT HO
530 FOR HO=1 TO N:? CHR$(125)
533 START=(HO-1)*10+1
536 ? "Lets Figure ";A$(START,START+9)
539 GOSUB CLASS
542 TRAP 542:? CHR$(125):? "Figuring ";A$(START,START+9)
545 POSITION 3,3:? "2) Has He raced since ";DAY$;" (Y/N)";:GET #2,YN
548 IF YN=ASC("Y") THEN 560
551 IF YN=ASC("N") THEN FP=0:GOTO 569
554 GOTO 542
560 POSITION 6,4:? "Enter Finish position last race"
563 ? "(1,2,3,etc) ===>";:INPUT #1,FP
569 POSITION 3,7:? "3) In the last 6 races"
572 POSITION 6,8:? "at a MAJOR track..."
575 POSITION 6,10:? "How many WINS ";:INPUT WINS
578 POSITION 6,11:? "How many 2NDS ";:INPUT TWOS
581 POSITION 6,13:? "at a MINOR track..."
584 POSITION 6,15:? "How many WINS ";:INPUT WONS
587 POSITION 6,21:? "EVERYTHING LOOK OK (Y/N)";:GET #2,YN
590 IF YN=ASC("Y") THEN 599
593 IF YN=ASC("N") THEN 542
596 GOTO 587
599 IF FP=1 THEN H(HO)=H(HO)+5
602 IF FP=2 THEN H(HO)=H(HO)+7
605 IF FP=3 THEN H(HO)=H(HO)+2
608 IF FP=4 THEN H(HO)=H(HO)+0
611 IF FP=5 THEN H(HO)=H(HO)-1
614 IF FP=6 THEN H(HO)=H(HO)-2
617 IF FP>6 THEN H(HO)=H(HO)-4
620 CPTS=WINS*2+TWOS+WONS
623 IF CPTS>=6 THEN H(HO)=H(HO)+8
626 IF CPTS=5 THEN H(HO)=H(HO)+6
629 IF CPTS=4 THEN H(HO)=H(HO)+4
632 IF CPTS=3 THEN H(HO)=H(HO)+3
635 IF CPTS=2 THEN H(HO)=H(HO)+1
638 IF CPTS=1 THEN H(HO)=H(HO)-2
641 IF CPTS=0 THEN H(HO)=H(HO)-4
645 TRAP 645
653 ? CHR$(125):? "Figuring ";A$(START,START+9)
656 POSITION 2,3:? "4)Find and add the two best first call"
659 POSITION 2,4:? "positions AT THIS DISTANCE OR SHORTER"
662 ? :? :? "Example:   5 4 4 1 PINCAY"
665 ? "          +2 2 1 1 SHOEMKR"
668 ? "          ─── "
671 ? "           7   Enter Here ===>";:INPUT #1,LNGS
674 ES(HO)=LNGS
677 ? :? "5)Enter Todays Weight ===>";:INPUT #1,LBS
680 WT(HO)=LBS
683 IF FL=ASC("Y") THEN GOSUB 917:REM Mile?
686 IF GR=ASC("Y") THEN GOSUB 947:REM Grass?
701 NEXT HO
704 POSITION 6,21:? "Stand by................"
707 TRAP 40000
710 REM *** Transfer ES to SORT Array ***
713 FOR HO=1 TO N:SORT(HO)=ES(HO):NEXT HO
716 GOSUB 974
719 REM *** Adjust for ES rating ***
722 FOR HO=1 TO N:IF ES(HO)<=SORT(3) THEN H(HO)=H(HO)+3:GOTO 728
725 H(HO)=H(HO)-2
728 NEXT HO
731 REM *** Transfer WT to SORT Array ***
734 FOR HO=1 TO N:SORT(HO)=WT(HO):NEXT HO
737 GOSUB 974:REM Sort SORT(HO)
740 REM *** Adjust for WT rating ***
743 FOR HO=1 TO N:IF WT(HO)>=SORT(N-2) THEN H(HO)=H(HO)+4:GOTO 749
746 H(HO)=H(HO)-3
749 NEXT HO
752 REM ***Minumum value=1***
755 FOR HO=1 TO N:IF H(HO)<=0 THEN H(HO)=1:NEXT HO
764 RETURN
767 REM ***Figure and Display ODDS***
770 TOT=0
773 FOR HO=1 TO N
776 TOT=TOT+H(HO):NEXT HO
779 NUM=0.18:TOT=TOT*0.79:REM Less 21% Take
782 FOR HO=1 TO N
785 START=(HO-1)*10+1
788 PCT=0:PCT=H(HO)/TOT
794 IF PCT=0 THEN ODDS$="OUT":GOTO 815:REM Scratch
797 REM ***If odds are higher then 9-2(NUM) then figure exact***
800 IF PCT<NUM THEN ODDS$=STR$(INT(1/PCT-1)):GOTO 815
803 REM ***If lower then 9-2 use Table***
806 FOR LOOP=1 TO 17:READ TBL,ODDS$
809 IF PCT>TBL THEN GOTO 815
812 NEXT LOOP
815 IF PFLAG=1 THEN ? #7;A$(START,START+9);" ------ ";ODDS$:GOTO 824
818 IF HO>6 THEN POSITION 21,HO-3:? A$(START,START+9);" -- ";ODDS$:GOTO 824
821 ? A$(START,START+9);" -- ";ODDS$
824 RESTORE 827:RESTORE 830:NEXT HO:CLOSE #7:PFLAG=0:RETURN
827 DATA .85,1-5,.71,2-5,.67,1-2,.62,3-5,.55,4-5,.5,EVEN,.45,6-5,.41,7-5,.4,3-2,.38,8-5,.35,9-5
830 DATA .33,2,.28,5-2,.25,3,.22,7-2,.2,4,.18,9-2
832 REM
833 POSITION 2,3:? "1)Has He ever finished 1st or 2nd in"
836 POSITION 2,4:? "this class or higher (Y/N)";:GET #2,YN
839 IF YN=ASC("Y") THEN H(HO)=H(HO)+4:RETURN
842 IF YN=ASC("N") THEN H(HO)=H(HO)-3:RETURN
845 GOTO 833
848 POSITION 2,3:? "1)Has He ever raced in a Stakes or"
851 POSITION 2,4:? "  Handicap race? (Y/N)";:GET #2,YN
854 IF YN=ASC("Y") THEN 863
857 IF YN=ASC("N") THEN 875
860 GOTO 848
863 POSITION 2,6:? "  Has He run in a claimer since? (Y/N)";:GET #2,YN
866 IF YN=ASC("Y") THEN H(HO)=H(HO)-4:RETURN
869 IF YN=ASC("N") THEN H(HO)=H(HO)+7:RETURN
872 GOTO 863
875 POSITION 2,8:? "  Has He run only Allowance or"
878 POSITION 2,9:? "  Non Claiming Maiden Races (Y/N)?";:GET #2,YN
881 IF YN=ASC("Y") THEN RETURN
884 IF YN=ASC("N") THEN H(HO)=H(HO)-4:RETURN
887 GOTO 875
890 POSITION 2,3:? "1)Has He ever raced in a Stakes or"
893 POSITION 2,4:? "Handicap race? (Y/N)";:GET #2,YN
896 IF YN=ASC("Y") THEN 905
899 IF YN=ASC("N") THEN H(HO)=H(HO)-4:RETURN
902 GOTO 890
905 POSITION 2,6:? "Did He Win? (Y/N)";:GET #2,YN
908 IF YN=ASC("Y") THEN H(HO)=H(HO)+6:RETURN
911 IF YN=ASC("N") THEN RETURN
914 GOTO 905
917 POSITION 2,14:? "6)Was his last race a Mile or more?"
920 POSITION 2,15:? "(Y/N)";:GET #2,YN
923 IF YN=ASC("Y") THEN H(HO)=H(HO)+3:RETURN
926 IF YN=ASC("N") THEN 932
929 GOTO 917
932 POSITION 2,16:? "Any Race at a Mile or more? (Y/N)";:GET #2,YN
935 IF YN=ASC("Y") THEN H(HO)=H(HO)+1:RETURN
938 IF YN=ASC("N") THEN RETURN
941 GOTO 932
947 POSITION 2,18:? "7)Was his last race on the Turf?"
950 POSITION 2,19:? "(Y/N)";:GET #2,YN
953 IF YN=ASC("Y") THEN H(HO)=H(HO)+3:RETURN
956 IF YN=ASC("N") THEN 962
959 GOTO 947
962 POSITION 2,20:? "Any Race at on the Turf? (Y/N)";:GET #2,YN
965 IF YN=ASC("Y") THEN H(HO)=H(HO)+1:RETURN
968 IF YN=ASC("N") THEN RETURN
971 GOTO 962
974 REM *** Sort Routine ***
977 N=HO-1:M=N
980 M=INT(M/2):IF M=0 THEN RETURN
983 FOR J=1 TO N-M:HO=J
986 L=HO+M
989 IF SORT(HO)<=SORT(L) THEN 995
992 X=SORT(HO):SORT(HO)=SORT(L):SORT(L)=X:HO=HO-M:IF HO>=1 THEN 986
995 NEXT J
998 GOTO 980
1001 REM Save a race to Disk
1003 TRAP 1023
1004 IF N=0 THEN POSITION 0,16:? "No Field!":? CHR$(253):RETURN
1007 POSITION 0,16:? "Saving Race ";RACE$
1010 FILE$="D1:":FILE$(4)="RACE":FILE$(8)=RACE$
1013 OPEN #5,8,0,FILE$
1016 ? #5;TRK$;CHR$(155);DAT$;CHR$(155);RACE$;CHR$(155);A$;CHR$(155);N
1019 FOR HO=1 TO N:? #5;H(HO):NEXT HO
1022 CLOSE #5:RETURN
1023 CLOSE #5:? "Disk full or Write Protected":? CHR$(253):FOR DLY=1 TO 150:NEXT DLY:RETURN
1025 REM Get a race from Disk
1028 POSITION 0,16:? "Which Race Number ==>";:INPUT RACE$
1031 FILE$="D1:":FILE$(4)="RACE":FILE$(8)=RACE$
1034 TRAP 1049
1037 OPEN #5,4,0,FILE$
1040 INPUT #5;TRK$,DAT$,RACE$,A$,N
1043 FOR HO=1 TO N:INPUT #5;DATA:H(HO)=DATA:NEXT HO
1046 CLOSE #5:RETURN
1049 ? "No Race NO. ";RACE$;" ";"on Disk"
1052 ? CHR$(253):FOR DLY=1 TO 100:NEXT DLY:GOTO 1046
1054 REM *** Read Disk Files ***
1055 GRAPHICS 0:OPEN #7,6,0,"D:*.*"
1058 INPUT #7;FILE$:? FILE$
1061 IF FILE$(5,8)="FREE" THEN CLOSE #7:? :? "   Hit RETURN ";:GET #2,WAIT:RETURN
1064 GOTO 1058
1066 REM *** Delete a File ***
1067 POSITION 0,14:? "Which Race do you wish to delete? ";:INPUT RACE$
1070 FILE$="D1:":FILE$(4)="RACE":FILE$(8)=RACE$
1073 XIO 33,#7,0,0,FILE$:RETURN
1076 REM Scratches
1079 IF N=0 THEN POSITION 0,16:? "No Field!":? CHR$(253):RETURN
1082 POSITION 0,16:? "Type in the Horses name";:INPUT TEMP$
1085 TL=LEN(TEMP$)
1088 FOR HO=1 TO N
1091 START=(HO-1)*10+1
1094 IF TEMP$=A$(START,START-1+TL) THEN A$(START,START+9)="SCRATCHED ":H(HO)=0:RETURN
1097 NEXT HO:? CHR$(253):? "None by that Name (Spelling?)":FOR DLY=1 TO 150:NEXT DLY:RETURN
1099 REM *** Print a Race ***
1100 IF N=0 THEN POSITION 0,16:? "No Field!":? CHR$(253):RETURN
1103 OPEN #7,8,0,"P:":POSITION 0,16:? "Position the Paper Then Hit RETURN";:GET #2,WAIT
1106 PFLAG=1:PRINT #7;TRK$;"  ";DAT$;"  RACE:";RACE$:? #7
1109 GOSUB 770:RETURN
1112 GRAPHICS 0:CLOSE #1:CLOSE #2:END