Cross-reference your BASIC variables (CROSSREF.BAS)
Cross-reference your BASIC variables by Bill Brown, 71
Description
Cross-reference your BASIC variables by Bill Brown, 71
From the Antic disk of August 1984 (Vol. 3 No. 4).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 3.1 KB
- Dialect
- Atari BASIC
- Lines
- 91
- Variables
LABEL$,VNPTR(,VNEND(,SOURCE$,TARGET$,VNTBL$,VNTL,PREF(,NV,ORDER(,TEMP,NREF,VREF(,LREF(,I,C,VNTP,VNTD,J,NUMLINE,OFFLINE,OFFSTATE,PASS,PASSES,SORTED,IJ
BASIC listing (91 lines)
100 REM VARIABLE CROSS-REFERENCE
101 REM BY BILL BROWN
102 REM ANTIC MAGAZINE
105 GRAPHICS 0:PRINT "ATARI BASIC CROSS-REFERENCE UTILITY"
110 DIM LABEL$(128),VNPTR(128),VNEND(128),SOURCE$(14),TARGET$(14)
120 PRINT :PRINT "ENTER SOURCE FILE";:INPUT SOURCE$
130 PRINT :PRINT "ENTER TARGET FILE";:INPUT TARGET$
135 POKE 755,0
140 OPEN #1,4,0,SOURCE$
150 GOSUB 1000
160 DIM VNTBL$(VNTL)
170 GOSUB 2000
180 DIM PREF(NV),ORDER(NV)
190 TEMP=(FRE(0)-1024)/12:NREF=NV
200 DIM VREF(TEMP),LREF(TEMP)
210 FOR I=1 TO NV:PREF(I)=I:ORDER(I)=I:VREF(I)=0:NEXT I
220 GOSUB 3000:GOSUB 4000
230 CLOSE #1
240 GOSUB 5000:GOSUB 6000
245 POKE 755,2
250 END
1000 REM (GET ZERO-PAGE POINTERS)
1010 GET #1,C:TEMP=C:GET #1,C
1015 IF TEMP<>0 OR C<>0 THEN PRINT "NOT A TOKENIZED FILE":END
1020 GET #1,C:TEMP=C:GET #1,C:VNTP=TEMP+256*C
1030 GET #1,C:TEMP=C:GET #1,C:VNTD=TEMP+256*C
1040 VNTL=VNTD-VNTP+1
1050 FOR I=1 TO 8:GET #1,C:NEXT I
1060 RETURN
2000 REM (GET VARIABLE NAMES)
2010 NV=0:VNTBL$=""
2020 LABEL$=""
2030 GET #1,C
2040 LABEL$(LEN(LABEL$)+1)=CHR$(C-128*(C>127))
2050 IF C<128 AND C<>0 THEN GOTO 2030
2060 IF C<>0 THEN NV=NV+1:VNPTR(NV)=LEN(VNTBL$)+1:VNEND(NV)=VNPTR(NV)+LEN(LABEL$)-1
2065 IF C<>0 THEN VNTBL$(VNPTR(NV))=LABEL$:GOTO 2020
2070 RETURN
3000 REM (BYPASS VARIABLE VALUES)
3010 FOR I=1 TO NV
3020 FOR J=1 TO 8
3030 GET #1,C
3040 NEXT J
3050 NEXT I
3060 RETURN
4000 REM (SCAN TOKENIZED FILE)
4010 GET #1,C:TEMP=C:GET #1,C:NUMLINE=TEMP+256*C:IF NUMLINE=32768 THEN GOTO 4075
4015 POSITION 0,9:PRINT "PROCESSING LINE ";NUMLINE
4020 GET #1,C:I=3:OFFLINE=C
4030 GET #1,C:I=I+1:OFFSTATE=C
4040 GET #1,C:I=I+1
4041 IF C=0 OR C=1 THEN FOR J=I+1 TO OFFLINE:GET #1,C:NEXT J:GOTO 4010
4042 IF C=14 THEN FOR J=1 TO 6:GET #1,C:I=I+1:NEXT J:GOTO 4050
4043 IF C=15 THEN GET #1,C:I=I+1:IF C>0 THEN TEMP=C:FOR J=1 TO TEMP:GET #1,C:I=I+1:NEXT J:GOTO 4050
4044 IF C>127 THEN TEMP=C-127:NREF=NREF+1:VREF(PREF(TEMP))=NREF:PREF(TEMP)=NREF:VREF(NREF)=0:LREF(NREF)=NUMLINE
4050 IF I<OFFSTATE THEN GOTO 4040
4060 IF I<OFFLINE THEN GOTO 4030
4070 GOTO 4010
4075 PRINT :PRINT "PROCESSING COMPLETE . . ."
4080 RETURN
5000 REM (SORT NAMES)
5010 PASS=0:J=NV:PASSES=INT(1.4427*LOG(J))
5020 PASS=PASS+1:J=INT(J/2)
5025 POSITION 0,13:PRINT "SORTING: PASS ";PASS;" OF ";PASSES;" PASSES"
5030 SORTED=1
5040 FOR I=1 TO NV-J:IJ=I+J
5050 IF VNTBL$(VNPTR(I),VNEND(I))<VNTBL$(VNPTR(IJ),VNEND(IJ)) THEN GOTO 5060
5051 TEMP=VNPTR(I):VNPTR(I)=VNPTR(IJ):VNPTR(IJ)=TEMP
5052 TEMP=VNEND(I):VNEND(I)=VNEND(IJ):VNEND(IJ)=TEMP
5053 TEMP=ORDER(I):ORDER(I)=ORDER(IJ):ORDER(IJ)=TEMP
5054 SORTED=0
5060 NEXT I
5070 IF SORTED=0 THEN GOTO 5030
5080 IF J>1 THEN GOTO 5020
5085 PRINT :PRINT "SORT COMPLETED . . ."
5090 RETURN
6000 REM (WRITE CROSS-REFERENCES)
6005 PRINT :PRINT "WRITING FILE . . ."
6010 OPEN #1,8,0,TARGET$:POKE 201,7
6015 PRINT #1;"CROSS-REFERENCES FOR ";SOURCE$:PRINT #1;NV;" VARIABLES, ";NREF-NV;" REFERENCES":PRINT #1
6020 FOR I=1 TO NV
6030 PRINT #1:PRINT #1;VNTBL$(VNPTR(I),VNEND(I));
6040 TEMP=0:J=VREF(ORDER(I)):IF J=0 THEN PRINT #1:GOTO 6090
6050 IF TEMP=4*INT(TEMP/4) THEN PRINT #1:PRINT #1;" ";
6060 PRINT #1;LREF(J),:TEMP=TEMP+1
6070 J=VREF(J):IF J<>0 THEN GOTO 6050
6080 PRINT #1
6090 NEXT I
6100 CLOSE #1
6105 PRINT :PRINT :POSITION 0,21
6110 RETURN
