BASIC-A Variable Approach, variable debugging tool (VARISORT.BAS)
BASIC-A Variable Approach, variable debugging tool by Jerry White, 58
Description
BASIC-A Variable Approach, variable debugging tool by Jerry White, 58
From the Antic disk of June 1984 (Vol. 3 No. 2).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 1.3 KB
- Dialect
- Atari BASIC
- Lines
- 22
- Variables
A$,B$,C$,T,L1,REC,L2,ME
BASIC listing (22 lines)
0 REM VARISORT
1 REM BY JERRY WHITE
2 REM ANTIC MAGAZINE
100 DIM A$(4797),B$(39),C$(39):A$=" ":A$(4797)=" ":A$(2)=A$:B$="":C$="":GOTO 210
110 T=INT(T/3)+1:FOR L1=1 TO REC-T:FOR L2=L1 TO 1 STEP -T
120 IF A$(L2*39-38,L2*39)<=A$((L2+T)*39-38,(L2+T)*39) THEN 160
130 C$=A$(L2*39-38,L2*39):A$(L2*39-38,L2*39)=A$((L2+T)*39-38,(L2+T)*39)
140 A$((L2+T)*39-38,(L2+T)*39)=C$
150 NEXT L2
160 POKE 709,L1*2:NEXT L1
170 IF T>1 THEN POKE 53279,0:GOTO 110
180 POKE 709,10:GOSUB 270:? :? "TYPE HEADING FOR PRINTED LIST:":INPUT B$
190 TRAP 240:LPRINT B$:LPRINT :TRAP 40000:GOSUB 270
200 FOR ME=1 TO REC:LPRINT A$(ME*39-38,ME*39):NEXT ME:LPRINT :LPRINT REC;" VARIABLES":POKE 82,2
201 ? :? "BASIC":? "IS";:END
210 REC=0:OPEN #1,4,0,"D:VARIABLE.DAT":GRAPHICS 18:POSITION 7,4:? #6;"READING"
220 TRAP 230:INPUT #1,B$:REC=REC+1:POSITION 9,6:? #6;REC:A$(REC*39-38,REC*39)=B$:B$="":GOTO 220
230 T=REC:GRAPHICS 18:POSITION 7,4:? #6;"sorting":GOTO 110
240 ? CHR$(253):? " CHECK PRINTER, PRESS START WHEN READY";
250 IF PEEK(53279)<>6 THEN 250
260 GOTO 190
270 GRAPHICS 0:POKE 710,0:POKE 82,0:RETURN
