Convert Synassembler to run on XL OS without Translater (DEREXL.BAS)

Convert Synassembler to run on XL OS without Translater, by Matthew Ratcliff, 38

Description

Convert Synassembler to run on XL OS without Translater, by Matthew Ratcliff, 38

From the Antic disk of June 1984 (Vol. 3 No. 2).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.4 KB

Dialect
Atari BASIC
Lines
64
Variables
B$, F$, A$, A, I, B
BASIC listing (64 lines)
5 REM OLD TO NEW OS
6 REM BY MATTHEW RATCLIFF
7 REM ANTIC MAGAZINE
10 DIM B$(FRE(0)-500),F$(20),A$(20)
20 GRAPHICS 0
30 GOSUB 1000
40 GRAPHICS 0:? :? "READING ";F$
50 TRAP 100
60 GET #2,A:B$(LEN(B$)+1)=CHR$(A):GOTO 60
100 CLOSE #2:IF PEEK(195)=136 THEN GOTO 200
110 ? "↰NOT END OF FILE ";PEEK(195)
120 END
200 ? "* END OF FILE *":A=0:? "Total length =";LEN(B$);" BYTES"
210 ? "NOW SEARCHING FOR BAD CALLS"
220 FOR I=1 TO LEN(B$)-2
230 IF B$(I,I+2)=" $v" THEN B$(I,I+2)=" 0r":? "OUTCHR FOUND AT BYTE#";I:A=A+1
235 IF B$(I,I+2)=" >v" THEN B$(I,I+2)=" Jr":? "GETCHR FOUND AT BYTE#";I:A=A+1
240 NEXT I
250 ? "↰FOUND & MADE ";A;" CHANGES":IF A=0 THEN ? "NO CHANGES, NEEDS SOME OTHER FIX":END
260 ? "PRESS RETURN KEY WHEN NEW DISK"
270 ? "IS READY ";:INPUT A$
280 ? "New file to write to"
290 ? "(press RETURN only if ";F$;")":INPUT A$:IF LEN(A$)=0 THEN 310
300 F$=A$:GOSUB 1510
310 TRAP 260:OPEN #1,8,0,F$:? "Writing file ";F$;"....."
320 FOR I=1 TO LEN(B$):PUT #1,ASC(B$(I,I)):NEXT I
330 CLOSE #1
340 ? "↰ALL DONE"
350 END
1000 ? "OLD ATARI OS TO  NEW 'XL OS  'XLATOR"
1010 ? "* WARNING: THIS PROGRAM  MIGHT  *"
1020 ? "* WORK, BUT IS NOT A SURE FIX   *"
1030 ? "IT WILL READ ANY UNPROTECTED BINARY"
1040 ? "DOS FILE AND REPLACE ALL OLD OS"
1050 ? "CALLS TO THE PUT-CHARACTER AND GET-"
1060 ? "CHARACTER ROUTINES TO THE NEW ROUINES"
1070 ? "IN THE 'XL OPERATING SYSTEM."
1080 ? "  OLD OS    BECOMES  IN NEW 'XL OS "
1090 ? "JSR $F6A4 > JSR $F2B0 OUT PUT CHAR"
1100 ? "JSR $F63E > JSR $F24A GET KEYBD CHAR"
1110 ? ""
1120 ? "Definitely works on the SYNASSEMBLER."
1130 ? "I have not modified any other progs"
1140 ? "with this,but may work. If you have"
1150 ? "binary program that scrolls & locks"
1160 ? "up when should print to GR.0 screen"
1170 ? "or does the same when keybd input"
1180 ? "expected, then this fix should work."
1190 ? ""
1200 ? "PRESS  RETURN  to continue";:INPUT A$
1210 GRAPHICS 0:? :? "PUT DISK WITH FILE TO TRANSLATE"
1220 ? "In DRIVE #1 and press  RETURN ";:INPUT A$
1230 OPEN #2,6,0,"D1:*.*"
1240 TRAP 1260
1250 INPUT #2,A$:? A$:GOTO 1250
1260 CLOSE #2
1270 ? "Type filename to 'xlate and"
1280 ? "press  RETURN  ";:GOSUB 1500
1290 TRAP 1300:OPEN #2,4,0,F$:RETURN
1300 ? "I/O ERROR ";PEEK(195):CLOSE #2:GOTO 1270
1500 TRAP 1500:INPUT F$
1510 IF LEN(F$)<3 THEN ? "↰INVALID FILE NAME":GOTO 1500
1520 IF F$(2,2)=":" OR F$(3,3)=":" THEN RETURN
1530 A$=F$:F$(1,3)="D1:":F$(4)=A$:RETURN