Update Disks With Note and Point, BASIC disk tutorial (UPDATE.BAS)

Update Disks With Note and Point, BASIC disk tutorial by Jerry White, 82

Description

Update Disks With Note and Point, BASIC disk tutorial by Jerry White, 82

From the Antic disk of April 1984 (Vol. 3 No. 1).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.5 KB

Dialect
Atari BASIC
Lines
58
Variables
RECS, SEC, BYT, REC$, SEC(, BYT(, RNUM, LAST$, FIRST$, AREA$, EXCH$, PNUM$, WORK$, USER$, INLEN
BASIC listing (58 lines)
100 REM NOTE & POINT DISK UPDATE
110 REM BY JERRY WHITE
115 REM ANTIC MAGAZINE
120 REM This program demonstrates
130 REM random access disk updating
140 REM using NOTE and POINT.
160 GOTO 610
180 REM READ TELEPHON.DAT AND CREATE
190 REM SECTOR/BYTE LOCATION ARRAYS
210 RECS=RECS+1:NOTE #1,SEC,BYT
220 INPUT #1,REC$:? :? "RECORD ";RECS;
230 ? " SECTOR ";SEC;" BYTE ";BYT:? REC$
240 SEC(RECS)=SEC:BYT(RECS)=BYT:GOTO 210
250 RECS=RECS-1:POKE 752,0
270 REM UPDATE LOOP
290 TRAP 290:? :? "  ENTER RECORD NUMBER TO UPDATE OR"
300 ? "  TYPE 0 AND RETURN TO QUIT";:INPUT RNUM
310 RNUM=INT(RNUM):IF  NOT RNUM THEN 590
320 IF RNUM<1 OR RNUM>RECS THEN ? CHR$(125):? "  ENTER A NUMBER FROM 1 TO ";RECS:GOTO 290
330 POINT #1,SEC(RNUM),BYT(RNUM):INPUT #1,REC$
340 LAST$=REC$(1,12):FIRST$=REC$(13,24)
350 AREA$=REC$(25,27):EXCH$=REC$(28,30)
360 PNUM$=REC$(31,34):? CHR$(125)
370 ? "ENTER UPDATED INFORMATION OR JUST"
380 ? "PRESS RETURN TO LEAVE ITEM UNCHANGED"
390 WORK$=" ":WORK$(34)=" ":WORK$(2)=WORK$
400 ? :? "LAST NAME: ";LAST$:INPUT USER$
410 INLEN=LEN(USER$):IF  NOT INLEN THEN WORK$(1,12)=REC$(1,12):GOTO 430
420 WORK$(1,INLEN)=USER$
430 ? :? "FIRST NAME: ";FIRST$:INPUT USER$
440 INLEN=LEN(USER$):IF  NOT INLEN THEN WORK$(13,24)=REC$(13,24):GOTO 460
450 WORK$(13,12+INLEN)=USER$
460 ? :? "AREA CODE: ";AREA$:INPUT USER$
470 INLEN=LEN(USER$):IF  NOT INLEN THEN WORK$(25,27)=REC$(25,27):GOTO 490
480 WORK$(25,24+INLEN)=USER$
490 ? :? "EXCHANGE: ";EXCH$:INPUT USER$
500 INLEN=LEN(USER$):IF  NOT INLEN THEN WORK$(28,30)=REC$(28,30):GOTO 520
510 WORK$(28,27+INLEN)=USER$
520 ? :? "NUMBER: ";PNUM$:INPUT USER$
530 INLEN=LEN(USER$):IF  NOT INLEN THEN WORK$(31,34)=REC$(31,34):GOTO 550
540 WORK$(31,30+INLEN)=USER$
550 POINT #1,SEC(RNUM),BYT(RNUM)
560 PRINT #1;WORK$
570 CLOSE #1:OPEN #1,12,0,"D:TELEPHON.DAT"
580 GOTO 290
590 GRAPHICS 0:? :? "BASIC":? "IS";:CLOSE #1:END
610 REM PROGRAM INITIALIZATION
630 DIM LAST$(12),FIRST$(12),AREA$(3),EXCH$(3),PNUM$(4),REC$(34),WORK$(34)
640 DIM SEC(500),BYT(500),USER$(12)
650 GRAPHICS 0:POKE 82,2:POKE 83,39:POKE 752,1:POKE 710,160
660 REM DISABLE BREAK KEY
670 POKE 16,64:POKE 53774,112
680 ? :? " TELEPHON.DAT RANDOM ACCESS UPDATE"
690 ? :? "   INSERT TELEPHON.DAT DISK THEN"
700 ? :? "      PRESS START WHEN READY":?
710 POKE 755,2:IF PEEK(53279)<>6 THEN POKE 755,3:GOTO 710
720 TRAP 650:CLOSE #1:OPEN #1,12,0,"D:TELEPHON.DAT"
730 RECS=0:? CHR$(125):TRAP 250:GOTO 210