Memory Window, look in RAM (MEMWINDO.BAS)

Memory Window, look in RAM by Dave Mentley, 62

Description

Memory Window, look in RAM by Dave Mentley, 62

From the Antic disk of April 1984 (Vol. 3 No. 1).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 1.2 KB

Dialect
Atari BASIC
Lines
26
Variables
A, B, DLST5, DLST6, SCRLO, SCRHI, MEM, MEMHI, MEMLO, X
BASIC listing (26 lines)
10 REM MEMORY WINDOW
20 REM BY DAVE MENTLEY, BASED ON A
30 REM PROGRAM BY MIKE MOREY
40 REM ANTIC MAGAZINE APRIL 1984
70 GRAPHICS 0:TRAP 270:POKE 16,64:POKE 53774,64:POKE 82,0:POKE 83,30
80 POKE 752,1:POKE 559,33
90 FOR A=1536 TO 1563:READ B:POKE A,B:NEXT A
100 DLST5=1540:DLST6=1541
110 SCRLO=PEEK(88):SCRHI=PEEK(89)
120 POKE DLST5,SCRLO:POKE DLST6,SCRHI
130 POKE 1552,SCRLO:POKE 1553,SCRHI
140 MEM=SCRHI*256+SCRLO
150 POKE 560,0:POKE 561,6
160 ? CHR$(125):? "        current memory=":? MEM;" TO ";MEM+255
170 ? "        PAGE= ";INT(MEM/256)
180 IF STRIG(0)=0 OR PEEK(764)=34 THEN MEM=0:POKE 764,0
190 IF STICK(0)=14 OR PEEK(764)=55 THEN MEM=MEM+256:POKE 764,0
200 IF STICK(0)=13 OR PEEK(764)=54 THEN MEM=MEM-256:POKE 764,0
210 IF STICK(0)=7 OR PEEK(764)=14 THEN MEM=MEM+1:POKE 764,0
220 IF STICK(0)=11 OR PEEK(764)=15 THEN MEM=MEM-1:POKE 764,0
230 IF MEM<0 OR MEM>65280 THEN MEM=65280
240 MEMHI=INT(MEM/256):MEMLO=MEM-256*MEMHI
250 POKE DLST5,MEMLO:POKE DLST6,MEMHI
260 GOTO 160
270 RUN
280 DATA 112,112,112,66,0,0,2,2,2,2,2,2,2,0,0,71,0,0,0,2,7,7,7,2,6,65,0,6