Talk to Your Peripherals, DOS functions from BASIC (DISKXIO.LST)

Talk to Your Peripherals, DOS functions from BASIC by William W. Hough, 18

Description

Talk to Your Peripherals, DOS functions from BASIC by William W. Hough, 18

From the Antic disk of April 1984 (Vol. 3 No. 1).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

BASIC listing · 1.1 KB

Text
29700 ? CHR$(125):IF SECOND THEN 29720
29710 DIM FILE$(27),CHFILE$(27),ANS$(1),TXT$(20):SECOND=1
29720 CLOSE #1:OPEN #1,6,0,"D:*.*":TRAP 29740
29730 INPUT #1,TXT$:? TXT$:GOTO 29730
29740 CLOSE #1:TXT$="":TRAP 40000
29750 POKE 702,64:? :? "Do you want to change the disk ";
29760 INPUT ANS$:IF ANS$<>"Y" THEN TRAP 40000:RETURN 
29770 GOTO 29790
29780 GOSUB 29950:GOTO 29760
29790 ? :? "LOCK, UNLOCK, RENAME, ERASE or FORMAT"
29800 INPUT ANS$:IF ANS$="L" THEN CMD=35:GOTO 29860
29810 IF ANS$="U" THEN CMD=36:GOTO 29860
29820 IF ANS$="R" THEN CMD=32:? :? "Enter OLDNAME,NEWNAME":GOTO 29870
29830 IF ANS$="E" THEN CMD=33:GOTO 29860
29840 IF ANS$="F" THEN CMD=254:CHFILE$="D:":GOTO 29880
29850 GOSUB 29950:GOTO 29800
29860 ? :? "Enter FILENAME ";
29870 FILE$="":INPUT FILE$:CHFILE$="D:":CHFILE$(3)=FILE$:IF FILE$="" THEN GOSUB 29950:GOTO 29870
29880 IF ANS$>"F" THEN 29930
29890 ? :? "Do you really mean it ";
29900 INPUT ANS$:IF ANS$="Y" THEN 29930
29910 GOTO 29700
29920 GOSUB 29950:GOTO 29900
29930 TRAP 29940:XIO CMD,#1,0,0,CHFILE$:GOTO 29700
29940 GOSUB 29950:GOTO 29700
29950 POKE 712,68:? CHR$(253):POKE 712,0:RETURN