Poker Solitaire (POKER.BAS)
Poker Solitaire, game by Jerry White, 68
Description
Poker Solitaire, game by Jerry White, 68
From the Antic disk of March 1984 (Vol. 2 No. 12).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 10.2 KB
- Dialect
- Atari BASIC
- Lines
- 231
- Variables
GAME,I,N3,PLR,N4,SCORE(,O,N40,ME,N2,N16,C,N13,CUR,JIF,JW,N14,P,N10,WAIT,BLINK,N255,K,KEY,X,N5,Y,N7,N11,TP,BS,L1$,L2$,L3$,L4$,N6,N8,N9,N12,N15,N17,N18,N19,N20,N21,N100,N45,N50,TIME,CARD,N25,CARD$,HAND$,BL$,S1$,N23,LKEY,N400,N26,DFLG,B5$,PN(,HN(,PS(,HS(,N490,N22,N24,N250,N,N35,CN(,CS(,N5000,N75,J,N31,JIFFY,N60,NA$,YOU,SC$,LS,PX,PY,PS,Q,N52,L(,XX,S,V,S$,N1360,C$,N1490,SP$,S2$,N200,Z,BUTN,CV,NO(,ST,FH,N1000,N30,NA,PN$,LPN,PAD,CV(
BASIC listing (231 lines)
10 REM ANTIC MAGAZINE MARCH 1984
11 REM POKER SOLITAIRE
12 REM BY JERRY WHITE
28 GOSUB 19000:FOR GAME=I TO N3:FOR PLR=I TO N4:SCORE(PLR,GAME)=O:NEXT PLR:NEXT GAME:GOTO 2000
31 GOSUB N40:GOTO 2000
34 FOR ME=O TO N3:SOUND ME,O,ME,N2:NEXT ME
35 FOR ME=O TO N3:SOUND ME,O,O,O:NEXT ME:RETURN
40 GRAPHICS O:POKE N16,64:POKE 53774,112:POKE 82,N2:POKE 83,39:? :POSITION N2,O
41 C=INT(PEEK(53770)/N16):SETCOLOR I,C,N13:SETCOLOR N2,C,O:SETCOLOR N4,C,O:POKE CUR,I:RETURN
45 JIF=I:FOR JW=N14 TO O STEP -N2:SOUND O,P,N10,JW:SOUND I,P+I,N10,JW:GOSUB WAIT:NEXT JW:RETURN
50 JIF=N3:FOR BLINK=I TO N3:POKE 755,N3:GOSUB WAIT:POKE 755,N2:GOSUB WAIT:NEXT BLINK:RETURN
60 GOSUB 34:POKE 764,N255:GOSUB 34:CLOSE #I:OPEN #I,N4,K,"K:":GET #I,KEY:KEY=KEY-48:CLOSE #I:RETURN
70 X=N5:Y=N7:POSITION X,Y:POKE CUR,O:? " ";:RETURN
75 POKE CUR,I:POSITION N11,N4:? "TOTAL POINTS= ";TP:RETURN
90 P=O:POKE 82,N2:POKE 83,39:GOSUB N40:IF BS>O THEN POSITION N10,N2:? "SCORE TO BEAT= ";BS;
100 POSITION N11,O:? " POKER SOLITAIRE "
105 L1$="┌─────┬─────┬─────┬─────┬─────┐":L2$="| | | | | |"
110 L3$="├─────┼─────┼─────┼─────┼─────┤":L4$="└─────┴─────┴─────┴─────┴─────┘"
120 POSITION N4,N6:? L1$:POSITION N4,N7:? L2$:POSITION N4,N8:? L2$:POSITION N4,N9:? L3$
125 POSITION N4,N10:? L2$:POSITION N4,N11:? L2$:POSITION N4,N12:? L3$:POSITION N4,N13:? L2$
130 POSITION N4,N14:? L2$:POSITION N4,N15:? L3$:POSITION N4,N16:? L2$:POSITION N4,N17:? L2$
135 POSITION N4,N18:? L3$:POSITION N4,N19:? L2$:POSITION N4,N20:? L2$:POSITION N4,N21:? L4$
140 P=N100:GOSUB N45:GOSUB N50
160 IF TIME=I THEN GOSUB 2300
220 FOR CARD=I TO N25:CARD$=HAND$(N4*CARD-N3,N4*CARD):POSITION N10,N4:? BL$;BL$:POKE 77,O
240 POSITION N14,N4:? "CARD #";CARD;" ";CARD$(I,N2);:IF CARD$(N2,N2)<>S1$ THEN ? S1$;
250 ? CARD$(N4,N4);:POSITION N3,N23:? " TRIGGER OR SPACE TO PLACE CARD ";
260 X=N5:Y=N7:POSITION X,Y:POKE CUR,O:? " ";:GOSUB N50
300 POKE LKEY,N255
310 IF PEEK(LKEY)=N14 AND Y>N7 THEN Y=Y-N3:POKE LKEY,N255:GOTO N400
320 IF STICK(O)=N14 AND Y>N7 THEN Y=Y-N3:GOTO N400
330 IF PEEK(LKEY)=N15 AND Y<N18 THEN Y=Y+N3:POKE LKEY,N255:GOTO N400
340 IF STICK(O)=N13 AND Y<N18 THEN Y=Y+N3:GOTO N400
350 IF PEEK(LKEY)=N6 AND X>N5 THEN X=X-N6:POKE LKEY,N255:GOTO N400
360 IF STICK(O)=N11 AND X>N5 THEN X=X-N6:GOTO N400
370 IF PEEK(LKEY)=N7 AND X<N26 THEN X=X+N6:POKE LKEY,N255:GOTO N400
380 IF STICK(O)=N7 AND X<N26 THEN X=X+N6:GOTO N400
385 IF NOT STRIG(O) THEN GOSUB 30006:GOTO 388
386 IF PEEK(LKEY)=33 THEN 388
387 GOTO 310
388 IF NOT PEEK(93) THEN POKE CUR,I:? CARD$(I,N2);:X=X+N3:Y=Y+I:POSITION X,Y:? CARD$(N4,N4);:GOTO 450
389 POKE DFLG,O:POKE CUR,I:? CHR$(253):POKE DFLG,I:GOTO 260
390 GOTO 310
400 POSITION X,Y:? " ";:GOSUB 34
410 JIF=N20:GOSUB WAIT:GOTO 385
450 POKE CUR,I:POSITION N3,N23:? BL$;BL$;BL$;B5$;:IF Y>N8 THEN 466
461 IF X=N8 THEN PN(I)=HN(CARD):PS(I)=HS(CARD):GOTO N490
462 IF X=N14 THEN PN(N2)=HN(CARD):PS(N2)=HS(CARD):GOTO N490
463 IF X=N20 THEN PN(N3)=HN(CARD):PS(N3)=HS(CARD):GOTO N490
464 IF X=N26 THEN PN(N4)=HN(CARD):PS(N4)=HS(CARD):GOTO N490
465 PN(N5)=HN(CARD):PS(N5)=HS(CARD):GOTO N490
466 IF Y>N11 THEN 472
467 IF X=N8 THEN PN(N6)=HN(CARD):PS(N6)=HS(CARD):GOTO N490
468 IF X=N14 THEN PN(N7)=HN(CARD):PS(N7)=HS(CARD):GOTO N490
469 IF X=N20 THEN PN(N8)=HN(CARD):PS(N8)=HS(CARD):GOTO N490
470 IF X=N26 THEN PN(N9)=HN(CARD):PS(N9)=HS(CARD):GOTO N490
471 PN(N10)=HN(CARD):PS(N10)=HS(CARD):GOTO N490
472 IF Y>N14 THEN 478
473 IF X=N8 THEN PN(N11)=HN(CARD):PS(11)=HS(CARD):GOTO N490
474 IF X=N14 THEN PN(N12)=HN(CARD):PS(N12)=HS(CARD):GOTO N490
475 IF X=N20 THEN PN(N13)=HN(CARD):PS(N13)=HS(CARD):GOTO N490
476 IF X=N26 THEN PN(N14)=HN(CARD):PS(N14)=HS(CARD):GOTO N490
477 PN(N15)=HN(CARD):PS(N15)=HS(CARD):GOTO N490
478 IF Y>N17 THEN 485
479 IF X=N8 THEN PN(N16)=HN(CARD):PS(N16)=HS(CARD):GOTO N490
480 IF X=N14 THEN PN(N17)=HN(CARD):PS(N17)=HS(CARD):GOTO N490
481 IF X=N20 THEN PN(N18)=HN(CARD):PS(N18)=HS(CARD):GOTO N490
482 IF X=N26 THEN PN(N19)=HN(CARD):PS(N19)=HS(CARD):GOTO N490
483 PN(N20)=HN(CARD):PS(N20)=HS(CARD):GOTO N490
485 IF X=N8 THEN PN(N21)=HN(CARD):PS(N21)=HS(CARD):GOTO N490
486 IF X=N14 THEN PN(N22)=HN(CARD):PS(N22)=HS(CARD):GOTO N490
487 IF X=N20 THEN PN(N23)=HN(CARD):PS(N23)=HS(CARD):GOTO N490
488 IF X=N26 THEN PN(N24)=HN(CARD):PS(N24)=HS(CARD):GOTO N490
489 PN(N25)=HN(CARD):PS(N25)=HS(CARD):GOTO N490
490 GOSUB N50:P=N250-(N8*CARD):GOSUB N45:GOSUB 70:NEXT CARD
500 P=O:TP=O:POKE DFLG,I:IF TIME=O THEN 505
502 GOSUB 2400:POKE CUR,I:POSITION N11,O:? "TIME= ";N;" SECONDS "
505 POSITION N3,N7:? "→";:POSITION N35,N7:? "←";:GOSUB N50
510 FOR ME=I TO N5:CN(ME)=PN(ME):CS(ME)=PS(ME):NEXT ME:GOSUB N5000:GOSUB N75
515 POSITION N3,N7:? " ";:POSITION N35,N7:? P;:P=O:GOSUB N50:POSITION N3,N10:? "→";:POSITION N35,N10:? "←";
520 FOR ME=N6 TO N10:CN(ME-N5)=PN(ME):CS(ME-N5)=PS(ME):NEXT ME:GOSUB N5000:GOSUB N75
525 POSITION N3,N10:? " ";:POSITION N35,N10:? P;:P=O:GOSUB N50:POSITION N3,N13:? "→";:POSITION N35,N13:? "←";
530 FOR ME=N11 TO N15:CN(ME-N10)=PN(ME):CS(ME-N10)=PS(ME):NEXT ME:GOSUB N5000:GOSUB N75
535 POSITION N3,N13:? " ";:POSITION N35,N13:? P;:P=O:GOSUB N50:POSITION N3,N16:? "→";:POSITION N35,N16:? "←";
540 FOR ME=N16 TO N20:CN(ME-N15)=PN(ME):CS(ME-N15)=PS(ME):NEXT ME:GOSUB N5000:GOSUB N75
545 POSITION N3,N16:? " ";:POSITION N35,N16:? P;:P=O:GOSUB N50:POSITION N3,N19:? "→";:POSITION N35,N19:? "←";
550 FOR ME=N21 TO N25:CN(ME-N20)=PN(ME):CS(ME-N20)=PS(ME):NEXT ME:GOSUB N5000:GOSUB N75
555 POSITION N3,N19:? " ";:POSITION N35,N19:? P;:P=O:GOSUB N50:POSITION N7,N5:? "↓";:POSITION N7,N22:? "↑";
560 J=O:FOR ME=I TO N21 STEP N5:J=J+I:CN(J)=PN(ME):CS(J)=PS(ME):NEXT ME:GOSUB N5000:GOSUB N75
565 POSITION N7,N5:? " ";:POSITION N6,N22:? P;" ";:P=O:GOSUB N50:POSITION N13,N5:? "↓";:POSITION N13,N22:? "↑";
570 J=O:FOR ME=N2 TO N22 STEP N5:J=J+I:CN(J)=PN(ME):CS(J)=PS(ME):NEXT ME:GOSUB N5000:GOSUB N75
575 POSITION N13,N5:? " ";:POSITION N12,N22:? P;" ";:P=O:GOSUB N50:POSITION N19,N5:? "↓";:POSITION N19,N22:? "↑";
580 J=O:FOR ME=N3 TO N23 STEP N5:J=J+I:CN(J)=PN(ME):CS(J)=PS(ME):NEXT ME:GOSUB N5000:GOSUB N75
585 POSITION N19,N5:? " ";:POSITION N18,N22:? P;" ";:P=O:GOSUB N50:POSITION N25,N5:? "↓";:POSITION N25,N22:? "↑";
590 J=O:FOR ME=N4 TO N24 STEP N5:J=J+I:CN(J)=PN(ME):CS(J)=PS(ME):NEXT ME:GOSUB N5000:GOSUB N75
595 POSITION N25,N5:? " ";:POSITION N25,N22:? P;" ";:P=O:GOSUB N50:POSITION N31,N5:? "↓";:POSITION N31,N22:? "↑";
600 J=O:FOR ME=N5 TO N25 STEP N5:J=J+I:CN(J)=PN(ME):CS(J)=PS(ME):NEXT ME:GOSUB N5000:GOSUB N75
605 POSITION N31,N5:? " ";:POSITION N31,N22:? P;" ";:P=O:GOSUB N50:IF TIME=O THEN 680
615 POSITION N11,O:? " SOLITAIRE POKER "
620 POSITION N11,N4:? BL$;BL$;:POSITION N10,N2:? " POINTS SCORED= ";TP;B5$;
622 JIFFY=N60:GOSUB WAIT:POSITION N11,N3:? "MINUS TIME PENALTY";:? BL$;
632 GOSUB WAIT:TP=TP-N:POSITION N11,N4:? " TOTAL POINTS= ";TP;BL$;:IF TP>BS THEN BS=TP
650 GOTO 690
680 IF TP>BS THEN BS=TP
690 POSITION N4,N23:? " TRIGGER OR SPACE TO CONTINUE ";
692 IF NOT STRIG(O) THEN SCORE(PLR,GAME)=TP:GOSUB 30006:GOTO 696
693 IF PEEK(LKEY)=33 THEN SCORE(PLR,GAME)=TP:POKE LKEY,N255:GOTO 696
694 GOTO 692
696 TP=O:P=N250:GOSUB N45:NEXT PLR:GOTO 800
800 GOSUB N40:? :? ," S C O R E S ":POSITION N7,N3:? NA$(I,N8):IF KEY>I THEN POSITION N15,N3:? NA$(N11,N18)
804 IF KEY>N2 THEN POSITION N23,N3:? NA$(N21,28)
805 IF KEY>N3 THEN POSITION N31,N3:? NA$(N31,38)
810 POSITION I,N4:? "PLAYER (1) (2) (3) (4) ":POSITION I,N7:? "GAME1":POSITION I,N10:? "GAME2"
814 POSITION I,N13:? "GAME3":POSITION I,N17:? "TOTAL":FOR ME=I TO N3:FOR YOU=I TO N4
825 IF NOT SCORE(YOU,ME) THEN SC$=" ":LS=N3:GOTO 840
830 SC$=STR$(SCORE(YOU,ME)):LS=LEN(SC$)
840 PX=(YOU*N8)+N4:PX=PX-LS:PY=(ME*N3)+N4:POSITION PX,PY:? SC$;:NEXT YOU:NEXT ME:PS=O:FOR ME=I TO N4
862 FOR YOU=I TO N3:PS=PS+SCORE(ME,YOU):NEXT YOU:IF NOT PS THEN SC$=" ":LS=N3:GOTO 872
870 SC$=STR$(PS):LS=LEN(SC$):PS=O
872 PX=(ME*N8)+N4:PX=PX-LS:POSITION PX,N17:? SC$:NEXT ME
880 POSITION N4,N20:? " TRIGGER OR SPACE TO CONTINUE ";:GOSUB N50:P=N255:GOSUB N45
882 IF NOT STRIG(O) THEN GOSUB 30006:GOTO 900
883 IF PEEK(LKEY)=33 THEN POKE LKEY,N255:GOTO 900
884 GOTO 882
900 NEXT GAME:JIF=N60:? :? "BASIC":? "IS";:END
1000 FOR Q=O TO N52:L(Q)=Q:NEXT Q:FOR PY=N16 TO N22:POSITION N17,PY:? " ";:NEXT PY
1002 POSITION N18,N18:? "CARD";:HAND$="":FOR C=I TO N25:POSITION N19,N20:? C;
1200 Q=INT(PEEK(53770)/5):XX=L(Q):GOSUB 10700:IF XX<O THEN 1200
1240 L(Q)=-I:S=INT(XX/N13):V=XX-N13*S:IF S>O THEN 1290
1270 S$="♣":GOTO N1360
1290 IF S>I THEN 1320
1300 S$="◆":GOTO N1360
1320 IF S>N2 THEN 1350
1330 S$="♥":GOTO N1360
1350 S$="♠":GOSUB 10720
1360 IF V>N8 THEN 1390
1370 C$=STR$(V+N2):GOTO N1490
1390 IF V>N9 THEN 1420
1400 C$="J":GOTO N1490
1420 IF V>N10 THEN 1450
1430 C$="Q":GOTO N1490
1450 IF V>N11 THEN 1480
1460 C$="K":GOTO N1490
1480 C$="A"
1490 IF LEN(C$)=I THEN SP$=S2$
1491 GOSUB 34:IF LEN(C$)=N2 THEN SP$=S1$
1495 HAND$(LEN(HAND$)+I)=C$:HAND$(LEN(HAND$)+I)=SP$:HAND$(LEN(HAND$)+I)=S$:HN(C)=V:HS(C)=S:NEXT C:RETURN
2000 FOR ME=I TO N3:P=N100:GOSUB N45:P=N200:GOSUB N45:NEXT ME
2020 GRAPHICS N2:GOSUB 30010
2040 ? #N6:? #N6:? #N6;" use time penalty?":? #N6:? #N6:? #N6;" Y OR N"
2060 GOSUB N60:IF KEY=41 THEN TIME=I:GOTO 2500
2080 IF KEY=30 THEN TIME=O:GOTO 2500
2100 GOTO 2060
2300 FOR Z=N18 TO N20:POKE Z,O:NEXT Z:RETURN
2400 N=O:FOR Z=N18 TO N20:N=N*256+PEEK(Z):NEXT Z:N=INT(N/N60):RETURN
2500 GRAPHICS N17:GOSUB 30010
2510 ? #N6:? #N6;" HAND VALUES":? #N6:? #N6:? #N6;"1000 straight flush":? #N6:? #N6;" 750 four of a kind"
2540 ? #N6:? #N6;" 500 full house":? #N6:? #N6;" 300 flush"
2560 ? #N6:? #N6;" 200 straight":? #N6:? #N6;" 100 three of a kind"
2580 ? #N6;" 50 two pair":? #N6:? #N6;" 20 one pair"
2600 POSITION N5,N22:? #N6;"press START":IF PEEK(BUTN)=N6 THEN 3000
2640 POSITION N5,N22:? #N6;"PRESS start":GOTO 2600
3000 GOSUB N40:GOSUB 34:GOTO 10000
5000 FOR CV=O TO N12:NO(CV)=O:NEXT CV:POKE CUR,I:POSITION N10,N23:? " CALCULATING ";
5100 FOR C=I TO N5:FOR CV=O TO N12:IF CN(C)=CV THEN NO(CV)=NO(CV)+I
5140 NEXT CV:NEXT C:FOR CV=O TO N12:IF NO(CV)<N2 THEN 5300
5240 IF NO(CV)=N2 THEN P=P+N20:ST=N9
5260 IF NO(CV)=N3 THEN P=P+N100:ST=N9:FH=CV
5280 IF NO(CV)=N4 THEN P=P+750:ST=N9
5300 IF ST=N9 THEN 5400
5310 IF NO(CV)=O AND ST<>O AND ST<>N5 THEN ST=N9
5320 IF NO(CV)=I THEN ST=ST+I
5400 NEXT CV:IF NO(O)=I AND NO(I)=I AND NO(N2)=I AND NO(N3)=I AND NO(N12)=I THEN ST=N5
5420 IF ST=N5 THEN P=P+N200:GOSUB 9000
5500 IF P=120 THEN P=500:GOTO 5800
5600 IF P=N1000 THEN 5800
5700 GOSUB 9000
5800 POKE CUR,I:POSITION N10,N23:? " CALCULATING ";:IF P=N40 THEN P=N50
5900 IF NOT P THEN FOR JW=N15 TO O STEP -I:SOUND O,13,N4,JW:NEXT JW:GOTO 5990
5910 JIF=I:IF P<500 THEN FOR JW=N15 TO O STEP -I:SOUND O,N200-P/N2,N10,JW:GOSUB WAIT:NEXT JW:GOTO 5990
5920 FOR JW=N200 TO O STEP -I:SOUND O,JW,N10,N10:SOUND I,JW+I,N10,N10:NEXT JW:GOSUB 35
5990 TP=TP+P:ST=O:RETURN
9000 FOR ME=I TO N4:IF CS(ME)<>CS(ME+I) THEN 9200
9020 NEXT ME:IF P=N200 THEN P=N1000:RETURN
9100 P=300:RETURN
9200 POP :RETURN
10000 GOSUB N40:POKE CUR,O:? :? "HOW MANY PLAYERS (1-4)?";:GOSUB N60
10010 IF KEY<I OR KEY>N4 THEN 10000
10011 ? KEY:?
10012 ? :? :? " TYPE NAMES OF 7 LETTERS OR LESS ":? :JIF=N30:GOSUB WAIT:FOR NA=I TO KEY
10016 ? :? "TYPE THE NAME OF PLAYER ";NA;:POKE 764,N255:INPUT PN$
10018 IF LEN(PN$)>N7 OR PN$="" THEN P=N255:GOSUB N45:PN$="":GOTO 10016
10020 NA$(LEN(NA$)+I)=PN$:LPN=LEN(PN$):FOR PAD=(NA*N10)-(N10-LPN) TO NA*N10-I:NA$(LEN(NA$)+I)=" ":NEXT PAD:NEXT NA
10050 FOR GAME=I TO N3:FOR PLR=I TO KEY:GOSUB N40:HAND$="":POKE CUR,I:? :? :? " ┌♥◆♠♣♥┐"
10120 ? " ┼─────┼":? " |╱╲ ╱╲|":? " ▌ ♥ ♥▌":? " ▌ | ▌"
10170 ? " | ┴ |":? " | ╲▂╱ |"
10180 ? " └─┬─┬─┘":? " ┌────┘ └────┐"
10210 ? " | ╲♣╱ |":? " | | | |"
10230 ? " I'M DEALING TO ";NA$(PLR*N10-N9,PLR*N10-N3):GOSUB N1000
10250 FOR PY=N16 TO N22:POSITION N17,PY:? " ";:NEXT PY
10300 POSITION N15,N18:? " GOOD LUCK ":POSITION N18,N5:? " ─ ◆";
10500 FOR ME=I TO N20:GOSUB 10750:GOSUB 10770:NEXT ME:POSITION N18,N5:? "♥ ♥ ";
10520 FOR ME=N250 TO O STEP -N10:SOUND O,ME,N10,N8:NEXT ME:SOUND O,O,O,O:GOTO 90
10700 POSITION N18,N5:? " ♥ ♥";:RETURN
10720 POSITION N18,N5:? "◆ ◆ ";:RETURN
10750 POSITION N20,N11:? "♣":POSITION N20,N11:? "X":RETURN
10770 POSITION N20,N11:? "X":POSITION N20,N11:? "♣":RETURN
19000 N6=6:GRAPHICS 2:POKE 752,1:? "↰";:GOSUB 30010
19010 ? #N6:? #N6:? #N6;" poker":? #N6;" solitaire"
19015 ? #N6:? #N6;" (C) 1983"
19020 ? #N6:? #N6;" by jerry white"
20000 READ I,N2,N3,N4,N5,N6,N7,N8,N9,N10,N11,N12,N13,N14,N15,N16,N17,N18,N19,N20
20010 READ N21,N22,N23,N24,N25,N26,N31,N35,N40,N45,N50,N52,N60,N75,N100,N200,N250
20020 READ N255,N400,N490,N1000,N1360,N1490,N5000,CUR,LKEY,DFLG,BUTN,WAIT
20100 DATA 1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20
20110 DATA 21,22,23,24,25,26,31,35,40,45,50,52,60,75,100,200,250
20120 DATA 255,400,490,1000,1360,1490,5000,752,764,766,53279,30000
21000 DIM L1$(N40),L2$(N40),L3$(N40),L4$(N40),L(N52),HAND$(N100)
21010 DIM S1$(I),S2$(N2),C$(N2),S$(I),SP$(N2),CARD$(N4),NO(N12),NA$(N40)
21020 DIM HN(N26),HS(N26),PN(N26),PS(N26),CN(N5),CS(N5),CV(N12),SCORE(N4,N3),SC$(N4),PN$(N10)
21030 SP$="":S1$=" ":S2$=" ":HAND$="":C$="":NA$="":PN$=""
21040 DIM BL$(N10),B5$(N5):BL$=" ":B5$=" ":SC$=" "
21050 FOR GAME=I TO N3:FOR PLR=I TO N4:SCORE(PLR,GAME)=O:NEXT PLR:NEXT GAME
22000 JIF=N100:GOSUB WAIT:RETURN
30000 POKE 540,JIF
30002 IF PEEK(540) THEN 30002
30004 RETURN
30006 IF NOT STRIG(O) THEN 30006
30008 RETURN
30010 POKE 708,29:POKE 709,158:POKE 710,146:POKE 711,15:POKE 712,146
30012 POKE 16,64:POKE 53774,112:POKE 82,2:POKE 83,39:RETURN
