GTIA Rainbow, graphics demo (GTIARAIN.BAS)
GTIA Rainbow, graphics demo by Mike Wilding, 114
Description
GTIA Rainbow, graphics demo by Mike Wilding, 114
From the Antic disk of March 1984 (Vol. 2 No. 12).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 1.4 KB
- Dialect
- Atari BASIC
- Lines
- 29
- Variables
A,DA,DL,B
BASIC listing (29 lines)
5 REM ANTIC MAGAZINE MARCH 1984
6 REM COLOR 256
7 REM BY WILDTHING
10 REM > ENTER MACHINE CODE ON PAGE 6
20 RESTORE :FOR A=0 TO 30:READ DA:POKE 1536+A,DA:NEXT A
30 DATA 72,138,72,238,32,6,175,32,6,189,100,6,141,10,212,141,26,208,224,16,208,5,169,0,141,32,6,104,170,104,64
40 REM > USE GR.9 AND ZERO COLOUR
50 GRAPHICS 9:POKE 712,0
60 REM > PLOT 16 COLOURS ON SCREEN
70 FOR A=1 TO 15:COLOR A:POKE 765,A
80 PLOT A*5+4,191:DRAWTO A*5+4,1:DRAWTO A*5,1:POSITION A*5,191:XIO 18,#6,0,0,"S:":NEXT A
90 REM > DRAW LINES TO MASK DLI's
100 COLOR 15:FOR A=0 TO 16:READ DA:PLOT 0,DA:DRAWTO 79,DA:PLOT 0,DA+1:DRAWTO 79,DA+1:NEXT A:PLOT 0,1:DRAWTO 0,191
110 DATA 1,12,24,36,48,60,72,84,96,108,120,132,144,156,168,180,190
120 REM > CLEAR DLI TABLE ON PAGE 6
130 FOR A=1637 TO 1653:POKE A,0:NEXT A
140 REM > PLACE INTERUPTS IN DL
150 DL=PEEK(560)+256*PEEK(561)
160 FOR A=0 TO 15:READ DA:POKE DL+DA,143:NEXT A
170 DATA 6,16,28,41,53,65,77,89,102,114,126,138,150,162,174,186
180 REM > VBLANK ROUTINE TO ZERO TABLE
190 FOR A=1576 TO 1583:READ DA:POKE A,DA:NEXT A:DATA 169,0,141,32,6,76,209,231
200 REM > START INTERUPT
210 POKE 546,40:POKE 547,6:POKE 512,0:POKE 513,6
220 POKE 54286,192
230 REM > FILL DLI TABLE IN SLOW TIME
240 FOR A=1 TO 15:POKE 1636+A,A*16:FOR B=0 TO 30:NEXT B:NEXT A
250 REM > ENDLESS LOOP TO SAVE SCREEN
260 GOTO 260
