Flash Count, language teaching (FLASHCNT.BAS)

Flash Count, language teaching by James Adamson, 24

Description

Flash Count, language teaching by James Adamson, 24

From the Antic disk of March 1984 (Vol. 2 No. 12).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 4.4 KB

Dialect
Atari BASIC
Lines
115
Variables
C$, B$, NOW, TIMEGONE, W, WGR, R, D, V, TI, RANK, Z, A, A1, B, B1, OP, T, RE, C, C1, S, DE
BASIC listing (115 lines)
1 REM FLASHCOUNT
2 REM by James Adamson
3 REM ANTIC MAGAZINE  MARCH 1984
4 REM Requires 16K RAM
10 DIM C$(20),B$(10)
20 GOTO 840
30 NOW=INT(((PEEK(18)*65536)+(PEEK(19)*256)+PEEK(20))/60)
40 TIMEGONE=180-NOW:RETURN
50 POKE 18,0:POKE 19,0:POKE 20,0:TIMEGONE=180:RETURN
60 SOUND 0,121,10,14:? "WRONG ANSWER! TRY AGAIN!"
70 W=W+1
80 POSITION 10,9:? #6;"wrong= ";W
90 POSITION 3,7:? #6;"TIMELEFT= ";TIMEGONE
100 SOUND 0,0,0,0:FOR WGR=1 TO 130:NEXT WGR:? :?
110 RETURN
120 SOUND 0,96,10,8:SOUND 1,81,10,8
130 R=R+1:IF TIMEGONE<0 THEN GOTO 310
140 ? "CORRECT INPUT":FOR D=1 TO 150:NEXT D
150 SOUND 0,0,0,0:SOUND 1,0,0,0
160 RETURN
170 POKE 710,14:IF V=0 THEN B$="SERO"
180 IF V=1 THEN B$="UNO"
190 IF V=2 THEN B$="DOS"
200 IF V=3 THEN B$="TRES"
210 IF V=4 THEN B$="CUATRO"
220 IF V=5 THEN B$="CINCO"
230 IF V=6 THEN B$="SEIS"
240 IF V=7 THEN B$="SIETE"
250 IF V=8 THEN B$="OCHO"
260 IF V=9 THEN B$="NUEVE"
270 IF V=10 THEN B$="DIEZ"
280 IF V=11 THEN B$="ONCE"
290 IF V=12 THEN B$="DOCE"
300 RETURN
310 C$="NOVICE"
320 IF R=0 OR TI<20 THEN 370
330 RANK=INT(100*W/TI)
340 IF RANK<26 THEN C$="AVERAGE"
350 IF RANK<16 THEN C$="MUY BIEN"
360 IF RANK<9 THEN C$="ESPANOL MATH WHIZ"
370 GRAPHICS 2:POKE 53774,112:POKE 16,64
380 POSITION 2,2:? #6;"YOUR RANK IS...":Z=Z+4:IF Z>243 THEN Z=29
390 SOUND 0,Z,10,14
400 POSITION 2,4:? #6;C$:POSITION 2,6:? #6;"TOTAL RIGHT= ";R:POSITION 2,8:? #6;"TOTAL WRONG= ";W
410 POKE 708,INT(256*RND(1))
420 ? "PRESS START TO BEGIN!":IF PEEK(53279)=6 THEN 840
430 GOTO 380
440 END
450 GOSUB 50
460 A=INT(13*RND(1)):A1=A
470 B=INT(13*RND(1)):B1=B
480 TI=TI+1
490 IF OP<3 THEN 610
500 IF OP=3 THEN 580
510 IF B=0 THEN B=1
520 IF A=0 THEN A=1
530 IF A<B THEN T=B:B=A:A=T
540 IF INT(A/B)=A/B THEN 610
550 RE=A-INT(A/B)*B
560 A=A-RE
570 GOTO 610
580 IF A>B THEN 610
590 T=B
600 B=A:A=T
610 V=A:GOSUB 170
620 GRAPHICS 2:POKE 710,14:POKE 16,64:POKE 53774,64
630 POSITION 1,0:? #6;"espanol flashcards"
640 POSITION 6,2:? #6;B$
650 POSITION 4,5:? #6;"__________"
660 POSITION 10,9:? #6;"wrong= ";W
670 POSITION 0,9:? #6;"right= ";R
680 POSITION 3,7:? #6;"TIMELEFT= ";TIMEGONE
690 V=B:GOSUB 170
700 ON OP GOTO 710,760,740,780
710 POSITION 5,4:? #6;"+ ";B$
720 C=A+B
730 GOTO 800
740 POSITION 5,4:? #6;"- ";B$
750 C=A-B:GOTO 800
760 POSITION 5,4:? #6;"* ";B$
770 C=A*B:GOTO 800
780 POSITION 5,4:? #6;"/ ";B$
790 C=A/B
800 TRAP 800:POKE 764,255:POKE 702,64:POKE 694,0:? " INPUT YOUR ANSWER NOW ???";:INPUT C1:? "↰"
810 IF C1<>C THEN GOSUB 60:GOSUB 30:GOSUB 2000:GOTO 800
820 GOSUB 30:GOSUB 120
830 GOTO 460
840 GRAPHICS 1+16:POKE 710,14:POKE 708,121:S=50:POKE 16,64:POKE 53774,64
850 TI=0:R=0:W=0
860 POSITION 1,0:? #6;"espanol FLASHCARDS"
870 SOUND 0,162,10,8:SOUND 1,108,10,6:SOUND 2,128,10,6
880 FOR Z=1 TO S:NEXT Z
890 POSITION 1,3:? #6;"by JAMES ADAMSON"
900 POSITION 1,6:? #6;"(c) 1983 by ANTIC"
910 SOUND 0,182,10,6:SOUND 1,182,10,6:SOUND 2,144,10,6
920 FOR Z=1 TO S:NEXT Z
930 POSITION 3,9:? #6;"---press---"
940 POSITION 3,12:? #6;"(a) for +"
950 POSITION 3,14:? #6;"(s) for -"
960 SOUND 0,243,10,6:SOUND 1,96,10,6:SOUND 2,162,10,6
970 FOR Z=1 TO S:NEXT Z
980 S=INT(121*RND(1))
990 FOR T=0 TO 3:SOUND T,0,0,0:NEXT T
1000 POSITION 3,16:? #6;"(m) for *"
1010 POSITION 3,18:? #6;"(d) for /"
1020 DE=PEEK(764)
1030 IF DE=63 THEN OP=1:GOTO 450
1040 IF DE=37 THEN OP=2:GOTO 450
1050 IF DE=62 THEN OP=3:GOTO 450
1060 IF DE=58 THEN OP=4:GOTO 450
1070 POKE 708,INT(255*RND(1))
1080 GOTO 860
2000 IF C1=200 THEN POSITION 14,2:? #6;"(";A;")"
2010 IF C1=400 THEN POSITION 14,4:? #6;"(";B;")"
2020 RETURN