Diskread, view and edit disk sectors (DISKREAD.BAS)
Diskread, view and edit disk sectors by Martin Rex, 65
Description
Diskread, view and edit disk sectors by Martin Rex, 65
From the Antic disk of March 1984 (Vol. 2 No. 12).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 5.1 KB
- Dialect
- Atari BASIC
- Lines
- 92
- Variables
NES,EOF,CALL$,BUF$,H$,AC$,N$,X$,E$,A$,NUM,V,ER,X,NE,NE1,Z,H,A,Y,GH,W,P,WZ,X2,Y2,X1,Y1,P2,D,I,D1
BASIC listing (92 lines)
1 REM ANTIC MAGAZINE MARCH 1984
2 REM DISKREAD
3 REM BY MARTIN REX
4 REM WEST GERMANY
9 GOSUB 5000:NES=1:EOF=0:GRAPHICS 0
10 DIM CALL$(5),BUF$(129),H$(3),AC$(10),N$(100),X$(3),E$(30),A$(10)
20 ? " Diskpage"
25 ? :? " Place source disk in drive 1."
30 BUF$(1)="":BUF$(129)="":BUF$(2)=BUF$
35 TRAP 60
60 ? "SECTOR to be listed (1-720)";:INPUT NUM:IF NUM<1 OR NUM>720 THEN 60
90 GOSUB 4500:POKE 779,INT(NUM/256):POKE 778,NUM-INT(NUM/256)*256:POKE 769,1:POKE 770,82:V=USR(ADR(CALL$))
100 BUF$(129)=" ":ER=PEEK(771):IF ER<>1 THEN GOSUB 4020:GOTO 300
200 ? "↰ DRIVE:D0 SECTOR:";NUM
210 X=USR(1536,ADR(BUF$))
220 NE=ASC(BUF$(126,126)):NE1=ASC(BUF$(127,127)):NE=NE-128*(NE>127):NE=NE-64*(NE>63)
230 NE=NE-32*(NE>31):NE=NE-16*(NE>15):NE=NE-8*(NE>7):NE=NE-4*(NE>3)
240 NES=NE*256+NE1
250 IF NES=0 THEN EOF=1
260 ? "NEXT SECTOR:";NES:GOTO 300
270 POSITION 21,18:? "FOLLOWING SEC. F"
275 POSITION 2,19:? " NEXT SEC. . N NEW SEC. ..... S"
280 ? " BASIC ..... B EDIT SEC. .... E"
290 ? " HARDCOPY .. H WRITE NEW SEC. W":? "↑":RETURN
300 GOSUB 270:OPEN #1,4,0,"K:":GET #1,Z:CLOSE #1
310 IF Z=ASC("F") THEN NUM=NUM+1:GOTO 90
320 IF Z=ASC("S") THEN EOF=0:GOTO 30
330 IF Z=ASC("B") THEN GRAPHICS 0:END
340 IF Z=ASC("H") THEN GOSUB 1000
350 IF Z=ASC("E") THEN 2000
360 IF Z=ASC("W") THEN 4000
370 IF Z=ASC("N") THEN 6000
380 REM
390 GOTO 300
700 H=INT(A/16):H$=CHR$(48+H):IF H>9 THEN H$=CHR$(55+H)
710 H=A-H*16:H$(2)=CHR$(48+H):IF H>9 THEN H$(2)=CHR$(55+H)
720 RETURN
1000 LPRINT " DRIVE:D0 SECTOR:";NUM:LPRINT
1005 N$(1)=CHR$(32):N$(100)=CHR$(32):N$(2)=N$
1010 FOR Y=0 TO 15:A=Y*8:GOSUB 700:N$=H$
1020 FOR X=0 TO 7:A=ASC(BUF$(X+Y*8+1,X+Y*8+1)):GH=A:GOSUB 700:N$(X*3+7)=H$
1030 GH=GH-128*(GH>127):IF GH<32 THEN GH=32
1040 IF GH>124 THEN GH=32
1050 AC$(X+1)=CHR$(GH):NEXT X:N$(36)=AC$:LPRINT N$:NEXT Y:LPRINT :LPRINT :RETURN
2000 X=7:Y=3:OPEN #1,4,0,"K:"
2010 GOSUB 2500
2020 GET #1,W:IF W=155 THEN CLOSE #1:POKE P,WZ:GOTO 200
2030 IF W=28 THEN POKE P,WZ:Y=Y-1*(Y>3):GOTO 2010
2040 IF W=29 THEN POKE P,WZ:Y=Y+1*(Y<18):GOTO 2010
2050 IF W=30 OR W=31 THEN GOSUB 2110:GOTO 2010
2060 IF W<48 OR W>70 THEN 2020
2061 IF W>57 AND W<65 THEN 2020
2070 X$=CHR$(W):POKE P,W-32:X2=X:Y2=Y:X=X+1:GOSUB 2500
2080 GET #1,W:IF W<48 OR W>70 THEN 2080
2081 IF W>57 AND W<65 THEN 2080
2090 X$(2)=CHR$(W):POKE P,W-32:X=X+2:IF X>28 THEN X=7:Y=Y+1:IF Y>18 THEN Y=3:X=7
2100 X1=(X2-7)/3:Y1=Y2-3:P2=Y1*8+X1+1:H$=X$:GOSUB 3000:BUF$(P2,P2)=CHR$(D):? X1:? "↑↑":GOTO 2010
2110 IF W=30 THEN POKE P,WZ:X=X-3:IF X<7 THEN X=28:Y=Y-1:IF Y<3 THEN Y=18:X=28:RETURN
2120 IF W=31 THEN POKE P,WZ:X=X+3:IF X>28 THEN X=7:Y=Y+1:IF Y>18 THEN Y=3:X=7
2130 RETURN
2500 P=PEEK(88)+256*PEEK(89)+(Y-1)*40+X:WZ=PEEK(P):POKE P,WZ+128*(WZ<128):RETURN
3000 I=1:GOSUB 3010:D=D1*16:I=2:GOSUB 3010:D=D+D1:RETURN
3010 D1=ASC(H$(I,I))-48:IF D1>9 THEN D1=D1-7
3020 RETURN
4000 ? " ↑":REM 31 spaces before up arrow
4002 ? "WRITE NEW SECTOR ";NUM;" (Y/N)";:INPUT A$:? "↑↑":IF A$="" THEN 300
4004 IF A$(1,1)<>"Y" THEN 300
4005 GOSUB 4500:POKE 769,1:POKE 770,87:V=USR(ADR(CALL$)):ER=PEEK(771):IF ER=1 THEN 90
4010 GOSUB 4020:GOTO 300
4020 E$="":IF ER=128 THEN E$="BREAK key abort"
4030 IF ER=138 THEN E$="Device timeout"
4040 IF ER=139 THEN E$="Device malfunctions"
4050 IF ER=140 THEN E$="Serial bus input framing"
4060 IF ER=142 THEN E$="Data frame overrun"
4070 IF ER=143 THEN E$="Data frame checksum"
4080 IF ER=144 THEN E$="Disk write-protected"
4090 IF ER=160 THEN E$="Drive number unknown"
4100 IF ER=163 THEN E$="Unrecoverable system"
4105 REM 34 spaces before up arrow on next line
4110 ? "ERROR -";ER;" ";E$;"↑":FOR I=1 TO 300:NEXT I:? " ↑":RETURN
4500 CALL$="h S":CALL$(4)=CHR$(228):CALL$(5)=CHR$(96)
4510 V=ADR(BUF$):POKE 773,INT(V/256):POKE 772,V-INT(V/256)*256:RETURN
5000 GRAPHICS 18:POSITION 4,4:? #6;"PLEASE WAIT !":POKE 712,216
5005 RESTORE 5010:FOR I=0 TO 141:READ A:POKE 1536+I,A:NEXT I:RESTORE :RETURN
5010 DATA 104,104,133,204,104,133,203,32,113,6,162,0,138,32,123,6,160,2,32,118,6,136,208,250,160,0,177,203,32
5020 DATA 123,6,200,192,8,208,246,160,0,177,203,201,127,176,2,105,128,201,252,176,4,201,159,176,2,169,160,32
5030 DATA 97,6,200,192,8,208,230,165,203,24,105,8,144,2,230,204,133,203,32,113,6,138,24,105,8,170,201,128,208
5040 DATA 181,96,24,105,48,201,58,144,2,105,6,133,209,138,72,152,72,165,209,32,164,246,104,168,104,170,96,169
5050 DATA 155,76,97,6,169,32,76,97,6,72,41,240,74,74,74,74,32,88,6,104,41,15,32,88,6,76,118,6
5090 REM 17 spaces before up arrow on next line
6000 IF EOF=1 THEN ? "END OF FILE !":FOR I=1 TO 300:NEXT I:? " ↑":GOTO 300
6010 NUM=NES:GOTO 90
