Atari's Cinderella, OS tutorial (CINDER2.BAS)

Atari's Cinderella, OS tutorial by Fred Pinho, 18

Description

Atari's Cinderella, OS tutorial by Fred Pinho, 18

From the Antic disk of March 1984 (Vol. 2 No. 12).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.5 KB

Dialect
Atari BASIC
Lines
40
Variables
Z, X, Y, T$, LAST, DL, START, STARTHI, STARTLO, L, LHI, LLO, G, C
BASIC listing (40 lines)
3000 GRAPHICS 5:RESTORE 3040
3010 COLOR 1:FOR Z=0 TO 5:READ X,Y:PLOT X,Y:READ X,Y:DRAWTO X,Y:NEXT Z:PLOT 29,12:PLOT 29,27:PLOT 28,12:PLOT 28,27
3020 COLOR 2:FOR Z=0 TO 5:READ X,Y:PLOT X,Y:READ X,Y:DRAWTO X,Y:NEXT Z
3030 COLOR 3:FOR Z=0 TO 7:READ X,Y:PLOT X,Y:READ X,Y:DRAWTO X,Y:NEXT Z:PLOT 59,12:PLOT 66,12:PLOT 59,27
3035 PLOT 66,27:COLOR 1:PLOT 0,0:DRAWTO 79,0:DRAWTO 79,39:DRAWTO 0,39:DRAWTO 0,0:SETCOLOR 0,5,6
3040 DATA 20,12,20,27,21,11,21,28,22,10,28,10,22,11,29,11,22,28,29,28,22,29,28,29
3050 DATA 39,10,46,10,39,11,46,11,39,28,46,28,39,29,46,29,42,12,42,27,43,12,43,27
3060 DATA 60,10,65,10,59,11,66,11,60,29,65,29,59,28,66,28,57,12,57,27,58,12,58,27,67,12,67,27,68,12,68,27
31000 REM **SCREEN SAVE ROUTINE**
31010 DIM T$(1)
31020 ? "DO YOU WISH TO:":? "  SAVE A SCREEN (TYPE S)":? "  LOAD A SCREEN (TYPE L)":INPUT T$
31030 IF T$<>"S" AND T$<>"L" THEN 31020
31040 IF T$="L" THEN 31190
31050 OPEN #4,8,0,"D:SCREEN1.DAT":REM OPEN IOCB #4
31060 LAST=PEEK(106)*256-160:REM END OF SCREEN DATA. TEXT WINDOW(160 BYTES) IS EXCLUDED
31070 DL=PEEK(560)+256*PEEK(561):START=PEEK(DL+4)+256*PEEK(DL+5):STARTHI=INT(START/256):STARTLO=START-256*STARTHI
31080 REM START OF SCREEN DATA
31090 L=(LAST-START)+1:LHI=INT(L/256):LLO=L-256*LHI:REM LENGTH OF SCREEN DATA
31100 G=PEEK(87):PUT #4,G:REM GRAPHICS MODE
31110 FOR X=0 TO 4:PUT #4,PEEK(708+X):NEXT X:REM SAVE COLOR REGISTERS
31120 POKE 898,11:REM COMMAND FOR PUT BINARY RECORD
31130 POKE 900,STARTLO:POKE 901,STARTHI:REM  ADDRESS OF START OF DATA TO BE SAVED
31140 POKE 904,LLO:POKE 905,LHI:REM LENGTH OF DATA TO BE SAVED
31150 X=USR(ADR("hhh*LVd"),4*16):REM CALL CIO
31160 CLOSE #4:REM CLOSE IOCB #4
31170 ? "SCREEN SAVED!":END
31180 REM **SCREEN RETRIEVE ROUTINE**
31190 REM SET UP CORRECT GRAPHICS MODE FIRST
31200 OPEN #4,4,0,"D:SCREEN1.DAT"
31210 GET #4,G:IF G<>PEEK(87) THEN ? "GRAPHICS MODE MISMATCH!":CLOSE #4:END
31220 FOR X=0 TO 4:GET #4,C:POKE 708+X,C:NEXT X:REM COLOR REGISTERS
31230 LAST=PEEK(106)*256-160:REM END OF SCREEN DATA. TEXT WINDOW(160 BYTES) IS EXCLUDED
31240 DL=PEEK(560)+256*PEEK(561):START=PEEK(DL+4)+256*PEEK(DL+5):STARTHI=INT(START/256):STARTLO=START-256*STARTHI
31250 L=(LAST-START)+1:LHI=INT(L/256):LLO=L-256*LHI
31260 POKE 898,7:REM COMMAND TO GET BINARY RECORD
31270 POKE 900,STARTLO:POKE 901,STARTHI
31280 POKE 904,LLO:POKE 905,LHI
31290 X=USR(ADR("hhh*LVd"),4*16):REM CALL CIO
31300 CLOSE #4:? "SCREEN LOADED!"
31310 END