Telephone directory (TELEPHON.BAS)

Telephone directory, by Jerry White, 54

Description

Telephone directory, by Jerry White, 54

From the Antic disk of February 1984 (Vol. 2 No. 11).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 4.4 KB

Dialect
Atari BASIC
Lines
146
Variables
RECLEN, I, RLM1, CLEAR, V, TOTAL, MENU, ME, L, STRPOS, LV, ARRAY$, WORK$, DING, O, DEV$, REC$, LAST$, INLEN, CHOICE$, BLANK$, PAPER, LINE$, ARRAY, FIRST$, AREA$, EXCH$, PNUM$, TABLEN, CHOICE, VOLUME
BASIC listing (146 lines)
1 REM * TELEPHONE DIRECTORY *
2 REM *   BY JERRY WHITE    *
3 REM *   ANTIC MAGAZINE    *
4 REM *   FEBUARY, 1984     *
100 RECLEN=34:I=1:RLM1=RECLEN-I:GOTO 10030
1000 REM
1010 REM SORT ROUTINE
1020 REM
1030 GOSUB CLEAR:? :? "SORTING";:V=TOTAL:IF V<2 THEN GOTO MENU
1040 V=INT(V/3)+I:FOR ME=I TO TOTAL-V:? ".";:FOR L=ME TO I STEP -V:STRPOS=L*RECLEN:LV=(L+V)*RECLEN
1050 IF ARRAY$(STRPOS-RLM1,STRPOS)<=ARRAY$(LV-RLM1,LV) THEN POP :GOTO 1080
1060 WORK$=ARRAY$(STRPOS-RLM1,STRPOS):ARRAY$(STRPOS-RLM1,STRPOS)=ARRAY$(LV-RLM1,LV)
1070 ARRAY$(LV-RLM1,LV)=WORK$:NEXT L
1080 NEXT ME:IF V>I THEN 1040
1090 GOSUB DING:GOTO MENU
2000 REM
2010 REM READ DATA ROUTINE
2020 REM
2030 GOSUB CLEAR:? :? "READ DATA:":GOSUB 16000
2040 CLOSE #I:OPEN #I,4,O,DEV$:TOTAL=O
2050 INPUT #I,REC$:TOTAL=TOTAL+I:? "RECORD #";TOTAL
2060 STRPOS=TOTAL*RECLEN-RLM1:ARRAY$(STRPOS,STRPOS+RLM1)=REC$:? REC$:? :GOTO 2050
3000 REM
3010 REM WRITE DATA ROUTINE
3020 REM
3030 GOSUB CLEAR:IF  NOT TOTAL THEN ? :? "I HAVE NO DATA TO WRITE":GOTO 15000
3040 ? :? "WRITE DATA:":GOSUB 16000
3050 CLOSE #I:OPEN #I,8,O,DEV$
3060 FOR ME=I TO TOTAL:? "RECORD #";ME
3070 STRPOS=ME*RECLEN-RLM1:REC$=ARRAY$(STRPOS,STRPOS+RLM1)
3080 ? REC$:? #I;REC$:NEXT ME
3100 CLOSE #I:GOTO 15000
4000 REM
4010 REM ALTER DATA ROUTINE
4020 REM
4030 GOSUB CLEAR:? :? "ALTER DATA:"
4040 IF  NOT TOTAL THEN ? :? "I HAVE NO DATA TO ALTER":GOTO 15000
4050 ? :? "ENTER LAST NAME FOR SEARCH";:INPUT LAST$
4060 INLEN=LEN(LAST$):IF  NOT INLEN THEN 4050
4070 ? :? "SEARCHING";
4080 FOR ME=I TO TOTAL:STRPOS=ME*RECLEN-RLM1:? ".";
4090 IF LAST$=ARRAY$(STRPOS,STRPOS+INLEN-I) THEN 4110
4100 NEXT ME:? :? :? LAST$;" NOT FOUND":GOTO 15000
4110 ? :? :? ARRAY$(STRPOS,STRPOS+RLM1)
4120 ? :? "IS THIS THE RECORD TO BE ALTERED (Y/N)";:INPUT CHOICE$
4130 IF CHOICE$="N" THEN 4100
4140 IF CHOICE$="Y" THEN ARRAY$(STRPOS,STRPOS+RLM1)=BLANK$:GOTO 6050
4150 GOTO 4110
5000 REM
5010 REM PRINT DATA ROUTINE
5020 REM
5030 GOSUB CLEAR:IF  NOT TOTAL THEN ? :? "I HAVE NO DATA TO PRINT":GOTO 15000
5040 ? :? "PRINT DATA:":PAPER=O
5050 ? :? "TYPE S FOR SCREEN DISPLAY ONLY"
5060 ? "TYPE P TO USE SCREEN AND PRINTER";:INPUT CHOICE$
5070 IF CHOICE$="S" THEN 5100
5080 IF CHOICE$="P" THEN PAPER=I:GOTO 5100
5090 GOTO 5050
5100 GOSUB CLEAR:? :LINE$(25,25)=" ":LINE$(29,29)="-":LINE$(33,33)="-"
5110 FOR ME=I TO TOTAL
5120 STRPOS=ME*RECLEN-RLM1:REC$=ARRAY$(STRPOS,STRPOS+RLM1)
5130 LINE$(I,24)=REC$(I,24)
5140 LINE$(26,28)=REC$(25,27)
5150 LINE$(30,32)=REC$(28,30)
5160 LINE$(34,37)=REC$(31,34)
5170 ? LINE$:IF PAPER THEN LPRINT LINE$
5180 NEXT ME
5200 GOTO 15000
6000 REM
6010 REM ENTER NEW DATA ROUTINE
6020 REM
6030 GOSUB CLEAR:TOTAL=TOTAL+I:STRPOS=TOTAL*RECLEN-RLM1
6035 IF TOTAL>ARRAY THEN TOTAL=TOTAL-I:? :? "NO ADDITIONAL RECORDS AVAILABLE":GOTO 15000
6040 ? :? "ENTER NEW DATA:"
6050 ? :? "LAST NAME:";:INPUT LAST$
6052 INLEN=LEN(LAST$):IF  NOT INLEN THEN 6050
6054 ARRAY$(STRPOS,STRPOS+INLEN-I)=LAST$
6060 ? :? "FIRST NAME:";:INPUT FIRST$
6062 INLEN=LEN(FIRST$):IF  NOT INLEN THEN 6060
6064 ARRAY$(STRPOS+12,STRPOS+INLEN+11)=FIRST$
6070 ? :? "AREA CODE:";:INPUT AREA$
6072 INLEN=LEN(AREA$):IF  NOT INLEN THEN 6070
6074 ARRAY$(STRPOS+24,STRPOS+INLEN+23)=AREA$
6080 ? :? "EXCHANGE:";:INPUT EXCH$
6082 INLEN=LEN(EXCH$):IF  NOT INLEN THEN 6080
6084 ARRAY$(STRPOS+27,STRPOS+INLEN+26)=EXCH$
6090 ? :? "NUMBER:";:INPUT PNUM$
6092 INLEN=LEN(PNUM$):IF  NOT INLEN THEN 6090
6094 ARRAY$(STRPOS+30,STRPOS+INLEN+29)=PNUM$
6100 GOSUB DING:GOTO MENU
7000 REM
7010 REM EXIT TO BASIC
7020 REM
7030 GOSUB CLEAR:? :? "BASIC":? "IS";:END
10000 REM
10010 REM PROGRAM INITIALIZATION
10020 REM
10030 DIM LAST$(12),FIRST$(12),AREA$(3),EXCH$(3),PNUM$(4),BLANK$(RECLEN)
10040 DIM REC$(RECLEN),WORK$(RECLEN),DEV$(14),CHOICE$(I),LINE$(38)
10050 ARRAY=INT(FRE(O)/RECLEN)-2:DIM ARRAY$(ARRAY*RECLEN)
10060 ARRAY$=" ":ARRAY$(ARRAY*RECLEN)=" ":ARRAY$(2)=ARRAY$:BLANK$=ARRAY$(I,RECLEN)
10070 CLEAR=14000:MENU=12030:LET TABLEN=201:DING=17000
11000 GOSUB CLEAR
11010 POKE 82,I:POKE 83,39
11020 ? :? "TYPE C FOR CASSETTE OR D FOR DISK";:INPUT CHOICE$
11030 IF CHOICE$="C" THEN DEV$="C:":GOTO 12000
11040 IF CHOICE$="D" THEN DEV$="D:TELEPHON.DAT":GOTO 12000
11050 GOTO 11020
12000 REM
12010 REM MENU ROUTINE
12020 REM
12030 GOSUB CLEAR:SETCOLOR 2,12,O:SETCOLOR 4,12,4
12040 POKE TABLEN,7
12050 POKE 752,I:? :? ,"ANTIC TELEPHONE DIRECTORY"
12060 POKE TABLEN,9
12070 ? :? ,"RECORDS IN MEMORY=";TOTAL
12080 ? ,"RECORDS AVAILABLE=";ARRAY-TOTAL
12090 POKE TABLEN,15
12100 ? :? ,"M E N U"
12110 POKE TABLEN,10
12120 ? :? ,"(1) ENTER NEW DATA"
12130 ? :? ,"(2) READ IN DATA"
12140 ? :? ,"(3) SAVE DATA"
12150 ? :? ,"(4) ALTER DATA"
12160 ? :? ,"(5) SORT DATA"
12170 ? :? ,"(6) PRINT DATA"
12180 ? :? ,"(7) EXIT TO BASIC"
12190 TRAP 12190:POSITION 10,22:? CHR$(156):CHOICE=O:POKE 752,O
12200 POKE 764,255:POSITION 10,22:GOSUB DING:? "ENTER YOUR CHOICE";:INPUT CHOICE$
12210 CHOICE=VAL(CHOICE$):IF CHOICE<I OR CHOICE>7 THEN 12190
12220 TRAP 20000:ON CHOICE GOTO 6030,2030,3030,4030,1030,5030,7030
13000 REM
13010 REM MISC. SUBROUTINES
13020 REM
14000 GRAPHICS O:SETCOLOR 2,CHOICE,O:SETCOLOR 4,CHOICE,4:SETCOLOR I,O,13
14010 RETURN
15000 ? :? "PRESS START FOR MENU":POKE 53279,O:GOSUB DING
15010 IF PEEK(53279)<>6 THEN 15010
15020 GOTO MENU
16000 ? :? "PRESS START WHEN I/O DEVICE IS READY":POKE 53279,O:GOSUB DING
16010 IF PEEK(53279)<>6 THEN 16010
16020 GOSUB CLEAR:RETURN
17000 FOR VOLUME=15 TO O STEP -I:SOUND O,CHOICE,2,VOLUME:NEXT VOLUME
17010 RETURN
20000 IF PEEK(195)=136 THEN CLOSE #I:GOTO 15000
20010 ? :? "ERROR ";PEEK(195);" AT LINE ";PEEK(186)+256*PEEK(187):GOTO 15000