Follow That Stock, portfolio spreadsheet (STOCK.BAS)
Follow That Stock, portfolio spreadsheet by Eric Verheiden, 31
Description
Follow That Stock, portfolio spreadsheet by Eric Verheiden, 31
From the Antic disk of February 1984 (Vol. 2 No. 11).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 6.5 KB
- Dialect
- Atari BASIC
- Lines
- 178
- Variables
SYM$,ISYM$,ISTR$,INP$,S$,A$,SHAR(,SYMB$,COSTSH(,TCOST(,PRICESH(,CURRVAL(,YIELD(,DIV(,INCOME(,CHANGE(,NREC,IREC,I,X,GSHR,GCOS,GVAL,GINC,K,JOLD,J,GDEL,GYIE
BASIC listing (178 lines)
10 REM ** STOCK PORTFOLIO **
15 REM * SPREAD SHEET *
20 REM * BY ERIC VERHEIDEN *
25 REM * ANTIC MAGAZINE *
30 REM * FEBUARY, 1984 *
35 REM *********************
40 DIM SYM$(6),ISYM$(6),ISTR$(1),INP$(90),S$(10),A$(256)
50 DIM SHAR(200),SYMB$(1200),COSTSH(200),TCOST(200)
60 DIM PRICESH(200),CURRVAL(200),YIELD(200),DIV(200),INCOME(200),CHANGE(200)
70 GOSUB 1530
80 PRINT "UPDATE OLD FILE OR CREATE NEW FILE";:INPUT ISTR$
90 IF ISTR$="C" THEN NREC=0:GOTO 300
100 IF ISTR$<>"U" THEN 80
110 TRAP 290:NREC=-1
120 OPEN #3,4,0,"D:STOCK.DAT"
130 INPUT #3;INP$:IF INP$="" THEN 290
140 NREC=NREC+1
150 IF NREC=0 THEN 130
160 GOSUB 170:GO TO 130
170 S$=INP$(1,5):SHAR(NREC)=VAL(S$)
180 SYMB$(6*NREC-5)=INP$(7,12)
190 S$=INP$(14,20):COSTSH(NREC)=VAL(S$)
200 S$=INP$(33,40):PRICESH(NREC)=VAL(S$)
210 S$=INP$(58,63):DIV(NREC)=VAL(S$)
220 TCOST(NREC)=SHAR(NREC)*COSTSH(NREC)
230 CURRVAL(NREC)=SHAR(NREC)*PRICESH(NREC)
240 YIELD(NREC)=100*DIV(NREC)/PRICESH(NREC)
250 INCOME(NREC)=SHAR(NREC)*DIV(NREC)
260 CHANGE(NREC)=0:IF COSTSH(NREC)=0 THEN 280
270 CHANGE(NREC)=100*(PRICESH(NREC)-COSTSH(NREC))/COSTSH(NREC)
280 RETURN
290 CLOSE #3:IF NREC<0 THEN PRINT "FILE NOT FOUND":GO TO 80
300 PRINT "ADD, CHANGE, LIST, PRINT OR SAVE";:INPUT ISTR$
310 IF ISTR$="P" THEN 950
320 IF ISTR$="L" THEN 970
330 IF ISTR$="S" THEN 990
340 IREC=NREC+1:IF IREC>200 THEN PRINT "TOO MANY RECORDS":STOP
350 IF ISTR$="A" THEN 790
360 IF ISTR$<>"C" THEN 300
370 PRINT "STOCK TO CHANGE";:INPUT ISYM$
380 IF LEN(ISYM$)>0 THEN IF ASC(ISYM$(1))=32 THEN ISYM$(1)=ISYM$(2):GO TO 380
390 IF LEN(ISYM$)<6 THEN ISYM$(LEN(ISYM$)+1)=" ":GO TO 390
400 IREC=0
410 IREC=IREC+1:IF IREC>NREC THEN PRINT "STOCK NOT FOUND":GO TO 300
420 SYM$=SYMB$(6*IREC-5,6*IREC)
430 IF SYM$<>ISYM$ THEN 410
440 PRINT SHAR(IREC);" SHARES ";SYM$
450 S$=STR$(COSTSH(IREC)):GOSUB 1460:PRINT "COST PER SHARE $";S$
460 S$=STR$(TCOST(IREC)):GOSUB 1460:PRINT "TOTAL COST $";S$
470 S$=STR$(PRICESH(IREC)):GOSUB 1460:PRINT "CURRENT PRICE PER SHARE $";S$
480 S$=STR$(CURRVAL(IREC)):GOSUB 1460:PRINT "CURRENT VALUE $";S$
490 S$=STR$(YIELD(IREC)):GOSUB 1460:PRINT "CURRENT YIELD ";S$;"%"
500 S$=STR$(DIV(IREC)):GOSUB 1460:PRINT "DIVIDEND PER SHARE $";S$
510 S$=STR$(INCOME(IREC)):GOSUB 1460:PRINT "INCOME $";S$
520 S$=STR$(CHANGE(IREC)):GOSUB 1460:PRINT "NET CHANGE ";S$;"%"
530 TRAP 300:PRINT "DELETE OR MODIFY ENTRY";:INPUT ISTR$
540 IF ISTR$="M" THEN 640
550 IF ISTR$<>"D" THEN 530
560 IF IREC=NREC THEN 630
570 SYMB$(6*IREC-5)=SYMB$(6*IREC+1)
580 FOR I=IREC TO NREC-1
590 SHAR(I)=SHAR(I+1):COSTSH(I)=COSTSH(I+1)
600 TCOST(I)=TCOST(I+1):PRICESH(I)=PRICESH(I+1)
610 CURRVAL(I)=CURRVAL(I+1):YIELD(I)=YIELD(I+1)
620 DIV(I)=DIV(I+1):INCOME(I)=INCOME(I+1):CHANGE(I)=CHANGE(I+1):NEXT I
630 NREC=NREC-1:GO TO 300
640 NREC=NREC+1
650 PRINT "NEW SYMBOL";:SYMB$(6*NREC-5)=SYMB$(6*IREC-5,6*IREC):INPUT SYM$
660 IF LEN(SYM$)>0 THEN IF ASC(SYM$(1))=32 THEN SYM$(1)=SYM$(2):GO TO 660
670 IF LEN(SYM$)=0 THEN 700
680 IF LEN(SYM$)<6 THEN SYM$(LEN(SYM$)+1)=" ":GOTO 680
690 SYMB$(6*NREC-5)=SYM$
700 PRINT "NEW SHARES";:SHAR(NREC)=SHAR(IREC):INPUT INP$
710 IF LEN(INP$)>0 THEN SHAR(NREC)=VAL(INP$)
720 PRINT "NEW COST";:COSTSH(NREC)=COSTSH(IREC):INPUT INP$
730 IF LEN(INP$)>0 THEN COSTSH(NREC)=VAL(INP$)
740 PRINT "NEW CURRENT PRICE";:PRICESH(NREC)=PRICESH(IREC):INPUT INP$
750 IF LEN(INP$)>0 THEN PRICESH(NREC)=VAL(INP$)
760 PRINT "NEW DIVIDEND";:DIV(NREC)=DIV(IREC):INPUT INP$
770 IF LEN(INP$)>0 THEN DIV(NREC)=VAL(INP$)
780 GOSUB 220:GO TO 560
790 NREC=NREC+1:IREC=NREC
800 PRINT "SYMBOL";:INPUT SYM$
810 IF LEN(SYM$)>0 THEN IF ASC(SYM$(1))=32 THEN SYM$(1)=SYM$(2):GO TO 810
820 IF LEN(SYM$)<6 THEN SYM$(LEN(SYM$)+1)=" ":GOTO 820
830 SYMB$(6*IREC-5)=SYM$
840 PRINT "SHARES";:INPUT X:SHAR(IREC)=X
850 PRINT "COST";:INPUT X:COSTSH(IREC)=X
860 PRINT "CURRENT PRICE";:INPUT X:PRICESH(IREC)=X
870 PRINT "DIVIDEND";:INPUT X:DIV(IREC)=X
880 TCOST(IREC)=SHAR(IREC)*COSTSH(IREC)
890 CURRVAL(IREC)=SHAR(IREC)*PRICESH(IREC)
900 YIELD(IREC)=100*DIV(IREC)/PRICESH(IREC)
910 INCOME(IREC)=SHAR(IREC)*DIV(IREC)
920 CHANGE(IREC)=0:IF COSTSH(IREC)=0 THEN 940
930 CHANGE(IREC)=100*(PRICESH(IREC)-COSTSH(IREC))/COSTSH(IREC)
940 GO TO 300
950 CLOSE #3:OPEN #3,8,0,"P:"
960 GOTO 1000
970 CLOSE #3:OPEN #3,8,0,"E:"
980 GO TO 1000
990 CLOSE #3:OPEN #3,8,0,"D:STOCK.DAT"
1000 PRINT #3;" #SHR SYMBOL COST/SH TOTAL COST PRICE/SH ";
1010 PRINT #3;"CURR VALUE %CHG DIV/SH INCOME YIELD"
1020 IF NREC=0 THEN 300
1030 X=USR(ADR(A$),ADR(SYMB$),NREC,6)
1040 GSHR=0:GCOS=0:GVAL=0:GINC=0:FOR K=1 TO NREC
1050 IREC=PEEK(X+K-1)+1
1060 S$=STR$(SHAR(IREC)):GSHR=GSHR+SHAR(IREC):INP$(1)=" "
1070 INP$(6-LEN(S$))=S$:INP$(6)=" "
1080 INP$(7)=SYMB$(6*IREC-5,6*IREC)
1090 S$=STR$(COSTSH(IREC)):JOLD=10
1100 J=17:GOSUB 1440
1110 S$=STR$(TCOST(IREC)):GCOS=GCOS+TCOST(IREC)
1120 J=29:GOSUB 1450
1130 S$=STR$(PRICESH(IREC))
1140 J=36:GOSUB 1440
1150 S$=STR$(CURRVAL(IREC)):GVAL=GVAL+CURRVAL(IREC)
1160 J=48:GOSUB 1450
1170 J=CHANGE(IREC):S$=STR$(J+SGN(J)/2):GOSUB 1460
1180 S$(I)="%":INP$(51)=" ":INP$(57-LEN(S$))=S$:JOLD=54
1190 S$=STR$(DIV(IREC))
1200 J=60:GOSUB 1440
1210 S$=STR$(INCOME(IREC)):GINC=GINC+INCOME(IREC)
1220 J=71:GOSUB 1450
1230 S$=STR$(YIELD(IREC))
1240 J=77:GOSUB 1440:INP$(80)="%"
1250 PRINT #3;INP$:NEXT K
1260 PRINT #3:PRINT #3;"GRAND TOTAL SHARES ";GSHR
1270 S$=STR$(GCOS):GOSUB 1430:PRINT #3;"GRAND TOTAL COST $";S$
1280 S$=STR$(GVAL):GOSUB 1430:PRINT #3;"GRAND TOTAL VALUE $";S$
1290 S$=STR$(GINC):GOSUB 1430:PRINT #3;"GRAND TOTAL INCOME $";S$
1300 GDEL=100*(GVAL-GCOS)/GCOS
1310 S$=STR$(GDEL):GOSUB 1460:PRINT #3;"AVERAGE INCREASE ";S$;"%"
1320 GYIE=100*GINC/GVAL
1330 S$=STR$(GYIE):GOSUB 1460:PRINT #3;"AVERAGE YIELD ";S$;"%"
1340 GYIE=100*GINC/GCOS
1350 S$=STR$(GYIE):GOSUB 1460:PRINT #3;"INCOME/COST ";S$;"%"
1360 GYIE=GINC/12
1370 S$=STR$(GYIE):GOSUB 1430:PRINT #3;"INCOME PER MONTH $";S$
1380 GYIE=GINC/52
1390 S$=STR$(GYIE):GOSUB 1430:PRINT #3;"INCOME PER WEEK $";S$
1400 GYIE=GINC/2080
1410 S$=STR$(GYIE):GOSUB 1430:PRINT #3;"INCOME PER HOUR $";S$
1420 CLOSE #3:GO TO 300
1430 GOSUB 1460:S$=S$(1,I+2):RETURN
1440 GOSUB 1450:JOLD=JOLD+1:RETURN
1450 GOSUB 1460:INP$(JOLD+3)=" ":INP$(J+1-I)=S$:JOLD=J:RETURN
1460 IF VAL(S$)<0.01 THEN S$="0.00"
1465 FOR I=1 TO 10:IF I>LEN(S$) THEN S$(I)=".":GO TO 1490
1470 IF ASC(S$(I))=46 THEN 1490
1480 NEXT I:GO TO 1510
1490 IF LEN(S$)=I THEN S$(I+1)="00"
1500 IF LEN(S$)=I+1 THEN S$(I+2)="0"
1510 IF LEN(S$)>I+3 THEN S$=S$(1,I+3)
1520 RETURN
1530 DATA 104,104,133,244,104,133,243,104
1540 DATA 104,133,242,104,104,133,216,133
1550 DATA 215,198,215,166,89,202,134,213
1560 DATA 202,134,231,202,134,225,160,0
1570 DATA 132,212,132,230,132,224,132,214
1580 DATA 152,145,212,200,208,250,24,102
1590 DATA 214,160,0,152,72,36,214,16
1600 DATA 3,24,113,224,170,104,145,224
1610 DATA 138,200,208,240,162,0,138,168
1620 DATA 177,212,72,133,217,169,0,133
1630 DATA 219,160,7,10,38,219,6,217
1640 DATA 144,7,24,101,216,144,2,230
1650 DATA 219,136,16,239,24,101,243,133
1660 DATA 218,165,219,101,244,133,219,164
1670 DATA 215,177,218,168,177,224,72,24
1680 DATA 105,1,145,224,104,168,104,145
1690 DATA 230,232,228,242,144,192,36,214
1700 DATA 16,165,165,213,166,231,134,213
1710 DATA 133,231,198,215,16,152,96
1720 FOR I=1 TO 151
1730 READ X:A$(I)=CHR$(X):NEXT I
1740 RETURN
