Money Matters, interest calculation program (MONEYMAT.BAS)

Money Matters, interest calculation program by Warwick Wakeman, 37

Description

Money Matters, interest calculation program by Warwick Wakeman, 37

From the Antic disk of February 1984 (Vol. 2 No. 11).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 7.4 KB

Dialect
Atari BASIC
Lines
229
Variables
X, OA, I, N, T, FW, D, FV, PW, AR, RP, P, J, BO, R, A, OV, DV, Z, Y
BASIC listing (229 lines)
1 REM *** MONEY MATTERS ****
2 REM * BY WARWICK WAKEMAN *
3 REM *   ANTIC MAGAZINE   *
4 REM *   FEBUARY, 1984    *
5 REM **********************
8 GRAPHICS 1+16:SETCOLOR 2,4,4
9 POSITION 6,5:? #6;"FINANCIAL"
10 POSITION 4,7:? #6;"CALCULATION$"
15 POSITION 9,12:? #6;"BY"
20 POSITION 6,14:? #6;"WARWICK!"
25 FOR X=1 TO 75 STEP 0.05:NEXT X:?
30 GRAPHICS 0:SETCOLOR 2,4,4:? :? :?
35 PRINT "THIS PROGRAM WILL COMPUTE FINANCIAL"
40 PRINT "  CALCULATIONS FOR INVESTMENT AND"
45 ? "            BORROWING"
50 ? :? :? "CHOOSE:":?
55 ? " 1. WHAT WILL MY INVESTMENT BE WORTH?"
60 ? " 2. VALUE OF REGULAR SAVINGS"
65 ? " 3. ANNUITY OR PENSION INCOME"
70 ? " 4. HOW MUCH DO I OWE ON MY LOAN?"
75 ? " 5. GROWTH OF INTEREST BEARING INVEST"
80 ? " 6. DEVALUATION OF THE $ BY INFLATION"
85 ? " 7. FURTHER DETAIL ON 1. THROUGH 7."
90 TRAP 50:INPUT X
95 ON X GOTO 100,300,500,700,900,1100,2000
100 GRAPHICS 0:SETCOLOR 2,13,6:? :?
105 ? "   FUTURE WORTH OF AN INVESTMENT"
110 ?
115 ? "ORIGINAL INVESTMENT           $";
120 TRAP 115:INPUT OA
125 ? "INTEREST RATE                 %";
130 TRAP 125:INPUT I
135 ? "COMPOUNDING PERIODS PER YEAR  #";
140 TRAP 135:INPUT N
145 ? "TOTAL YEARS                   #";
150 TRAP 145:INPUT T
155 I=I/N*0.01
160 FW=OA*(1+I)^(N*T)
165 ?
170 ? "FUTURE WORTH = $";
175 ? INT(FW*100+0.6)*0.01
180 ? "AT END OF ";T;" YEARS"
185 ?
190 GOSUB 3000
195 GOTO 110
300 GRAPHICS 0:SETCOLOR 2,2,4:? :?
305 ? "FUTURE VALUE OF REGULAR SAVINGS"
310 ?
315 ? "AMOUNT EACH DEPOSIT          $";
320 TRAP 315:INPUT D
325 ? "INTEREST RATE                %";
330 TRAP 325:INPUT I
335 ? "DEPOSITS PER YEAR            #";
340 TRAP 335:INPUT N
345 ? "NUMBER OF YEARS TO SAVE      #";
350 TRAP 345:INPUT T
355 I=I/N*0.01
360 FV=D*((1+I)^(N*T)-1)/I
365 ?
370 ? "FUTURE VALUE = $";
375 ? INT(FV*100+0.6)*0.01
380 ? "AT END OF ";T;" YEARS"
385 ?
390 GOSUB 3000
395 GOTO 310
500 GRAPHICS 0:SETCOLOR 2,5,4:? :?
505 ? "AMOUNT REQ'D FOR ANNUITY OR PENSION"
510 ?
515 ? "AMOUNT OF PLANNED WITHDRAWALS $";
520 TRAP 515:INPUT PW
525 ? "EXPECTED INTEREST RATE        %";
530 TRAP 525:INPUT I
535 ? "PLANNED WITHDRAWALS PER YEAR  #";
540 TRAP 535:INPUT N
545 ? "NUMBER OF YEARS TO MATURITY   #";
550 TRAP 545:INPUT T
555 I=I*0.01
560 AR=PW*N/I*(1-1/((1+I/N)^(N*T)))
565 ?
570 ? "MINIMUM INVESTMENT REQ'D = $";
575 ? INT(100*AR+0.6)*0.01
580 ? "FOR ";N*T;"  WITHDRAWALS IN ";T;" YEARS"
585 ?
590 GOSUB 3000
595 GOTO 510
700 GRAPHICS 0:SETCOLOR 2,1,3:? :?
705 ? "      BALANCE OWING ON A LOAN"
710 ?
715 ? "REGULAR PAYMENT               $";
720 TRAP 715:INPUT RP
725 ? "ORIGINAL AMOUNT BORROWED      $";
730 TRAP 725:INPUT P
735 ? "NUMBER OF PAYMENTS PER YEAR   #";
740 TRAP 735:INPUT N
745 ? "ANNUAL INTEREST RATE          %";
750 TRAP 745:INPUT I
755 ? "TOTAL NUMBER OF PAYMENTS MADE #";
760 TRAP 755:INPUT T
765 I=I/100
770 J=I/N
775 BO=P*(1+J)^T-RP*((1+J)^T-(1+J))/J-(1*RP)
780 ?
785 ? "BALANCE OWING = $";
790 ? INT(BO*100+0.6)*0.01
795 ? "AFTER ";T;" PAYMENTS"
800 ?
805 GOSUB 3000
810 GOTO 710
900 GRAPHICS 0:SETCOLOR 2,3,2:? :?
905 ? "      GROWTH OF MONEY"
910 ?
915 ?
920 ? "INITIAL AMOUNT         $";
925 TRAP 920:INPUT P
930 ? "INTEREST RATE          %";
935 TRAP 930:INPUT R
940 LET N=1
945 LET A=P*(1+R/100)^N
950 ?
955 ? "YEAR   = #";N
960 ?
965 ? "AMOUNT = $";A
970 LET N=N+1
975 ?
980 ? "FOR ADDITIONAL YEARS, HIT 1"
985 ? "TO CONTINUE PROGRAM, HIT 2"
990 TRAP 980:INPUT X
995 IF X=1 THEN 945
1000 IF X=2 THEN GOSUB 3000
1005 GOTO 915
1100 GRAPHICS 0:SETCOLOR 2,14,2:? :?
1105 ?
1110 ? " $ DEVALUATION AT RATE OF INFLATION"
1115 ?
1120 ? "ORIGINAL VALUE              $";
1125 TRAP 1120:INPUT OV
1130 ? "INFLATION RATE              %";
1135 TRAP 1130:INPUT I
1140 ? "YEARS                       #";
1145 TRAP 1140:INPUT T
1150 ?
1155 DV=INT(100*OV*(1-I/100)^T+0.6)*0.01
1160 ? "DEVALUATION = $";DV
1165 ? "AT END OF ";T;" YEARS"
1170 ? :?
1175 ? "FOR ADDITIONAL YEARS, HIT 1"
1180 ? "TO CONTINUE PROGRAM, HIT 2"
1185 TRAP 1175:INPUT X
1190 IF X=1 THEN 1210
1195 IF X=2 THEN GOSUB 3000
1200 GOTO 1120
1205 ? :?
1210 ? "ENTER NUMBER OF ADDITIONAL YEARS - ";
1215 TRAP 1210:INPUT N
1220 ? "ENTER INFLATION RATE FOR ADDITIONAL YEARS - %";
1225 TRAP 1220:INPUT I
1230 DV=INT(100*DV*(1-I/100)^N+0.6)*0.01
1235 LET T=T+N
1240 ? :?
1245 ? "DEVALUATION OF $";OV;" = $";DV
1250 ? "AT END OF ";T;" YEARS"
1255 ?
1260 GOTO 1175
2000 GRAPHICS 0:SETCOLOR 2,10,1:? :?
2005 ? "  THIS PART OF THE PROGRAM WILL         GIVE FURTHER DETAILS ON THE VARIOUS   CALCULATIONS":? :?
2010 ? "CHOOSE:"
2015 ? " 1. WHAT WILL MY INVESTMENT BE WORTH?"
2020 ? " 2. VALUE OF REGULAR SAVINGS"
2025 ? " 3. ANNUITY OR PENSION INCOME"
2030 ? " 4. HOW MUCH DO I OWE ON MY LOAN?"
2035 ? " 5. GROWTH OF INTEREST BEARING INVEST"
2040 ? " 6. DEVALUATION OF THE $ BY INFLATION"
2045 ? " 7. BACK TO MAIN MENU"
2050 TRAP 2005:INPUT Z
2055 ON Z GOTO 2100,2140,2170,2205,2235,2260,30
2100 GRAPHICS 0:COLOR 1:SETCOLOR 2,13,6
2105 ? :? "    FUTURE WORTH OF AN INVESTMENT":?
2110 ? " This function will compute the worth of an investment at a specified futuretime. The original investmen";
2115 ? "t can be asavings account, a term deposit, bondsor a retirement fund."
2120 ? :? " It may also be used to estimate the  future value of an antique or a piece of real estate. ";
2125 ? " Just enter what you  estimate the appreciation rate is in  place of the INTEREST RATE."
2130 GOSUB 3100
2135 GOTO 100
2140 GRAPHICS 0:COLOR 1:SETCOLOR 2,2,4:? :?
2145 ? :? "   FUTURE VALUE OF REGULAR SAVINGS"
2150 ? "This function will compute the future value of regular equal amounts deposited in an interest ";
2155 ? "bearing investment  such as a savings account, insurance  policy or retirement savings plan."
2160 GOSUB 3100
2165 GOTO 300
2170 GRAPHICS 0:COLOR 1:SETCOLOR 2,5,4:? :?
2175 ? :? " MINIMUM ANNUITY INVESTMENT REQUIRED"
2180 ? "This function will compute the amount required to provide regular income    over a specified period of";
2185 ? " time such  as pension payments.  It can also be  used to determine the amount required to provide";
2190 ? " living expenses while attending college or university."
2195 GOSUB 3100
2200 GOTO 500
2205 GRAPHICS 0:COLOR 1:SETCOLOR 2,1,3:? :?
2210 ? :? "    BALANCE REMAINING ON A LOAN"
2215 ? "This function will compute the balanceowing on a loan after a specified number of payments such as a";
2220 ? " bank loan or a mortgage."
2225 GOSUB 3100
2230 GOTO 700
2235 GRAPHICS 0:COLOR 1:SETCOLOR 2,3,2:? :?
2240 ? :? "    GROWTH RATE OF MONEY"
2245 ? "This function will show how money     grows year by year when placed in an  interest bearing investment."
2250 GOSUB 3100
2255 GOTO 900
2260 GRAPHICS 0:COLOR 1:SETCOLOR 2,14,2:? :?
2265 ? :? "  $ DEVALUATION AT RATE OF INFLATION"
2270 ? "This function will compute the effect on inflation on the doller.  It can   also be used to calculate ";
2275 ? "depreciationon a piece of equipment.  Just enter  the depreciation rate in place of the INFLATION RATE."
2280 GOSUB 3100
2285 GOTO 1100
3000 ? :? :? "CHOOSE:"
3005 ? "1. CONTINUE WITH THIS FUNCTION?"
3010 ? "2. FURTHER DATA ON CALCULATIONS?"
3015 ? "3. BACK TO MAIN MENU?"
3020 TRAP 3000:INPUT Y
3025 IF Y=1 THEN RETURN
3030 IF Y=2 THEN 2000
3035 IF Y=3 THEN 30
3100 ? :? "CHOOSE:"
3105 ? "1. TO USE THIS FUNCTION"
3110 ? "2. FURTHER DATA ON CALCULATIONS"
3115 ? "3. BACK TO MAIN MENU"
3120 TRAP 3040:INPUT A
3125 IF A=1 THEN RETURN
3130 IF A=2 THEN 2000
3135 IF A=3 THEN 30